Supprimer des lignes qui contiennent un mot précis

[champagne012]

Bonjour,

J'ai tableau excel sur deux colonnes.

La première A est le code postal
La deuxième B est le nom de la commune

Ma question est comment (à l'aide d'une macro ?)supprimer uniquement les lignes qui en colonne B contiennent le terme "cedex". (ex Paris Cedex).

Merci à vous! j'ai bien vu quelques codes sur le net mais je ne comprends pas tout!

 

[aspe]

Re : Supprimer des lignes qui contiennent un mot précis

Bonjour,

Sub Macro1()
'
' Macro1 Macro
'
Range("A1:B1").Select ' sélection ligne
Selection.AutoFilter ' pose d'un filtre
ActiveSheet.Range("$A$1:$B$31").AutoFilter Field:=2, Criteria1:="*Cedex" ' contient "cedex"
Rows("3:65000").Select
Selection.Delete Shift:=xlUp ' supprime la sélection
ActiveSheet.Range("$A$1:$B$4").AutoFilter Field:=2
Range("B9").Select
ActiveWindow.SmallScroll Down:=-12
End Sub

Fait avec l'enregistreur de macro...

 

[champagne012]

Re : Supprimer des lignes qui contiennent un mot précis

Ca a marché nickel!

Merci beaucoup pour cette réponse rapide!

 

[VDAVID]

Re : Supprimer des lignes qui contiennent un mot précis

Bonjour Champagne012, Aspe,

Autre approche:

Sub Suppression()

    Dim i As Integer
    Dim Ws As Worksheet
    
    Set Ws = Sheets("Feuil2")
    
    With Ws
    For i = .Range("B65536").End(xlUp).Row To 1 Step -1
        
        If .Range("B" & i).Value Like "*" & "CEDEX" & "*" Then .Rows(i).Delete
        
    Next i
    End With
    
    
End Sub

 

[job75]

Re : Supprimer des lignes qui contiennent un mot précis

Bonjour à tous,

Sub SupprimerCedex()
[B:B].Replace "*cedex*", "" 'la casse est ignorée
On Error Resume Next
[B:B].SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

A+

 

[job75]

Re : Supprimer des lignes qui contiennent un mot précis

Re,

La macro précédente supprime toutes les lignes dont la cellule en colonne B est vide.

Si l'on veut les conserver :

Sub SupprimerCedex()
[B:B].Replace "*cedex*", "#N/A" 'la casse est ignorée
On Error Resume Next
[B:B].SpecialCells(xlCellTypeConstants, 16).EntireRow.Delete
End Sub

A+