Suppression de ficher en automatique

[gildas lechat]

Bonjour le forum,

J'aimerai mettre en place une suppression automatique de fichier dans un grand nombre de classeur (une centaine de classeurs) . Tout les fichiers ne commencant pas par "a" sont à supprimer.
Vous trouverez ci joint l'architecture de rangement des dossier er fichier.

Si vous pouvez me tuyoter sur la facon de réaliser cette macro.
Merci beaucoup
Gildas

 

[mromain]

Re : Suppression de ficher en automatique

Bonjour gildas lechat,


voici un essai :

Sub SupprimerFichiers()
'déclaration des fariables
Dim myFso As Object, dossierPrindipal As Object, sousDossier As Object, fichier As Object
Dim pathDossierPrindipal As String

    'définir le chemin du dossier principal ("Dossier Rapport de microsection")
    pathDossierPrindipal = "C:\Dossier Rapport de microsection"
    
    'récupérer le dossier
    Set myFso = CreateObject("Scripting.FileSystemObject")
    Set dossierPrindipal = myFso.GetFolder(pathDossierPrindipal)
    
    'boucler sur tous ses sous-dossier
    For Each sousDossier In dossierPrindipal.SubFolders
        'boucler sur tous les fichier du sous-dossier
        For Each fichier In sousDossier.Files
            'si le fichier ne commance pas par "a-" et ne fini pas par ".xls"
            If Not fichier.Name Like "a-*.xls" Then
                myFso.DeleteFile (fichier.Path)
            End If
        Next fichier
    Next sousDossier
End Sub

a+

 

[gildas lechat]

Re : Suppression de ficher en automatique

Bonjour mromain,

Yes, tu me simplifie la vie, ça fonctionne correctement
merci beaucoup
@+
Gildas