XL 2010 SOS formule excel

[bossman_16]

Bonjours,
j'ai besoin de votre aide sur un sujet a mon avis je ne sais ci ses réalisable, mon fichier contiens une liste de montant de facture que je vérifie les virement au prés de la banque,
il m'arrive de recevoir un virement pour le totale de deux ou trois facture dont j'arrive pas a détermine le détail par apport a ma liste de créance, alors j'ai eu une idée et de faire un tableau qui contient une liste des créance avec les numéros des factures, et de l'autre côté j'ai crée une colonne nommé virement, mon souhait ci c possible et de pouvoir saisir le montant de virement dans la colonne E4, et quand je Click sur le bouton (vérification) les montants dans la cellule (B4 aux B17) qui correspondant au totale du montant de virement prenne une couleur différente pour que je puise les identifier.
ci joint mon fichier excel.
merci de votre aide je vous remercie tous.

 

[job75]

Bonjour bossman_16,

Faites une recherche sur ce forum avec les mots clés lettrage ou rapprochement.

A+

 

[job75]

Pour ce qui est de l'exemple de votre fichier voyez cette macro :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim cible, i As Variant, tablo, ub&, j&, k&
If FilterMode Then ShowAllData 'si la feuille est filtrée
With Range("A4:B" & Range("A" & Rows.Count).End(xlUp).Row - 1)
    If .Row < 4 Then Exit Sub
    If Intersect(Target, [E4]) Is Nothing Then Exit Sub
    .Columns(2).Interior.ColorIndex = xlNone 'RAZ
    cible = [E4]
    If Not IsNumeric(CStr(cible)) Then Exit Sub
    tablo = .Value 'matrice, plus rapide
    ub = UBound(tablo)
    '---1 2 ou 3 factures rapprochées---
    For i = 1 To ub
        If tablo(i, 2) = cible Then .Cells(i, 2).Interior.Color = vbGreen: Exit Sub
        For j = i + 1 To ub
            If tablo(i, 2) + tablo(j, 2) = cible Then Union(.Cells(i, 2), .Cells(j, 2)).Interior.Color = vbGreen: Exit Sub
            For k = j + 1 To ub
                If tablo(i, 2) + tablo(j, 2) + tablo(k, 2) = cible Then Union(.Cells(i, 2), .Cells(j, 2), .Cells(k, 2)).Interior.Color = vbGreen: Exit Sub
    Next k, j, i
End With
End Sub

Elle se déclenche quand on modifie la cellule E4.

 

[bossman_16]

un grand merci mon frère, vous venez de soulager mon stress de travail.

 

[bossman_16]

re mon frère, comment je fait pour a voir 4 résultats au lieux de trois , merci infiniment.