Somme d'une même cellule sur plusieurs feuilles = #N/A

[Stellaire]

Bonjour à tous,

Je m'arrache les cheveux sur quelque chose qui me parait extrêmement basique mais dont malgré des heures de recherches sur le net je ne trouve pas la réponse.

J'ai un classeur contenant 6 feuilles nommés "1", "2", "3", "4", "5" et ""Sem A"
Dans la cellule C3 de la feuille Sem A je veux faire la somme des cellules C3 des 5 autres feuilles (Sem A étant le cumul hebdomadaire des 5 jours travaillés précédents).

En mettant
=SOMME('1:5'!C3)
J'ai le message d'erreur #N/A

En mettant
=SOMME.SI('1:5'!C3;"<>"&"#N/A")
J'ai le message d'erreur #VALEUR!

Dans les feuilles 1 à 5 les cellules C3 se remplissent automatiquement avec une formule RECHERCHEV qui reporte évidemment #N/A tant que je n'ai pas ajouté les ajouté les données nécessaires à la recherche.

En bref : Tout fonctionne parfaitement quand toutes les feuilles sont remplies entièrement, mais dès qu'il manque la moindre donnée il n'affiche plus rien.

J'ai mis un fichier d'exemple en pièce jointe.

Merci d'avance de votre aide.

 

[Tibo]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

Bonjour,

Le plus simple est de traiter le problème au niveau de tes feuilles 1 2 3 4 5

Remplace ta formule RECHERCHEV par celle-ci :

=SI(ESTNA(RECHERCHEV('Liste TC'!A2;$B$25:$X$40;17;FAUX));0;RECHERCHEV('Liste TC'!A2;$B$25:$X$40;17;FAUX))

Ainsi, la somme multi-feuilles ne posera plus de problème.

Je te laisse adapter.

@+

 

[Stellaire]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

Pour le C3 ca fonctionne parfaitement, Merci beaucoup.

Par contre le problème arrive maintenant pour les autres cellules. Dans le cas des sommes ajouter 0 ne change rien, mais dans le cas des moyennes ça fait tout baisser radicalement.

Toujours dans mon fichier d'exemple les cellules D3 et E3 sont des moyennes. Il faudrait que les résultats #N/A ne soient juste pas comptabilisés.

 

[Stellaire]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

MOYENNE.SI, SOMME.SI et NB.SI ne fonctionnent pas non plus. Je suis complétement coincé pour faire des moyennes sur plusieurs feuilles sans comptabiliser les #N/A ou les 0.

 

[Tibo]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

re,

Je pense que la solution va se trouver dans une formule matricielle 3D.

Tu peux en avoir un aperçu sur le site de Jacques Boisgontier :

Formation Excel VBA JB

dans la rubrique SOMMEPROD, sous-rubrique Matriciel 3D

Je regarde également de mon côté.

@+

 

[Stellaire]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

J'y suis arrivé.
Encore une fois merci pour ton conseil, la solution était effectivement dans ton lien.

=SOMMEPROD(SOMME.SI(INDIRECT(NomsFeuilles&"!D3");">0";INDIRECT(NomsFeuilles&"!D3")))/SOMMEPROD(NB.SI(INDIRECT(NomsFeuilles&"!D3");">0"))

 

[BOISGONTIER]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

Bonsoir,

J'étais arrivé à

=SOMMEPROD(SOMME.SI(INDIRECT(LIGNE(1:5)&"!D3");"<>#N/A")/SOMMEPROD(NB.SI(INDIRECT(LIGNE(1:5)&"!D3");">0")))

ou

=SOMMEPROD(SOMME.SI(INDIRECT(LIGNE(1:5)&"!D3");">0")/SOMMEPROD(NB.SI(INDIRECT(LIGNE(1:5)&"!D3");">0")))

ou

=MOYENNE(SI(NON(ESTNA(N(INDIRECT(LIGNE(1:5)&"!D3"))));SI(N(INDIRECT(LIGNE(1:5)&"!D3"))>0;N(INDIRECT(LIGNE(1:5)&"!D3")))))
Valider avec maj+ctrl+entrée

Exemple + complexe : Moyenne des nombres compris entre 5 et 20 sans les #N/A

=MOYENNE(SI(NON(ESTNA(N(INDIRECT(LIGNE(1:5)&"!B5"))));SI((N(INDIRECT(LIGNE(1:5)&"!B5"))>5)*(N(INDIRECT(LIGNE(1:5)&"!B5"))<20);N(INDIRECT(LIGNE(1:5)&"!B5")))))
Valider avec maj+ctrl+entrée

http://boisgontierjacques.free.fr/fichiers/Matriciel/Moyenne3DSansNANi0.xls

JB

 

[Stellaire]

Re : Somme d'une même cellule sur plusieurs feuilles = #N/A

J'y ai passé l'intégralité de mon WE (le classeur final est un gros machin qui pèse 2MO a vide, juste avec les formules dont le but est d'ingérer les données brutes venant de plusieurs autres sources pour tout me ressortir sous des formats exploitables... Le genre de machin qui va me faire gagner 40min de boulot chiant par jour).

Tout fonctionnait grâce a vos conseils.

J'arrive au boulot, je le lance et... plus rien ne marche.

Mon tableau était bourré de NB.SI.ENS et MOYENNE.SI qui ne sont pas compatible avec excel 2003 que nous utilisons au boulot... J'en avais les larmes aux yeux.

Mais bon quelques heures de plus passées a tout modifier et, enfin, il semble fonctionner ! (enfin... on verra demain au boulot)

Merci pour vos réponses, je n'y serais pas arrivé sans vous.