Somme chiffres et lettres

[jedjed]

Bonjour à tous,

Je me suis permis d'envoyer un message tout à l'heure mais n'ai pas obtenu de réponse. J'ai donc essayé de clarifier ma demande.

je dois pour un planing effectuer des sommes de lettres et chiffres mélangés mais sans tenir compte des lettres.

12s + RP + 13S + 11S + 1 = 37
Comment arriver à ce résultat ?


Merci d'avance

Jérôme

 

[Tibo]

Re : Somme chiffres et lettres

Bonjour,

Il ne sert à rien de créer un nouveau fil si tu n'as pas obtenu de réponse sur le précédent . Il fallait rester sur l'ancien :

https://www.excel-downloads.com/threads/planing-jai-besoin-daide-pour-une-formule.127278/

en supposant que tes codes numériques fassent toujours 2 caractères (ce qui semble être le cas sur le fichier joint sur ton autre post)

en B15, un essai avec une formule matricielle :

=SOMME(SI(ESTNUM(GAUCHE(B5:B11;2)*1);GAUCHE(B5:B11;2)*1))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier ensuite vers la droite

@+

 

[jedjed]

Re : Somme chiffres et lettres

Apparemment la formule ne fonctionne pas.

Tu aurais une autre idée

a+
Merci

 

[Tibo]

Re : Somme chiffres et lettres

re,

Sous réserve qu'il s'agisse du même fichier que celui de ton autre post, ça fonctionne chez moi.

Ne pas oublier, comme je l'avais signalé, qu'il s'agit d'une formule matricielle qui demande à être validée par CTRL + MAJ + ENTREE

Voir le fichier joint

@+

 

[jedjed]

Re : Somme chiffres et lettres

Ca marche merci

Jérôme

 

[Tibo]

Re : Somme chiffres et lettres

Salut cher voisin,

Pour tenir compte de ton message en MP, une autre formule, basée sur le fait que tes codes peuvent être constitués d'un, deux ou trois chiffres suivis d'une lettre :

en B15, toujours en matricielle :

=SOMME(SI(ESTNUM(GAUCHE(B5:B11;NBCAR(B5:B11)-1)*1);
GAUCHE(B5:B11;NBCAR(B5:B11)-1)*1))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers la droite

@+

 

[jedjed]

Re : Somme chiffres et lettres

Apparamment ca ne marche pas.
Je t'envoie ce que je dois ajouter,
Encore Merci de ton aide

 

[job75]

Re : Somme chiffres et lettres

Bonjour jedjed, Tibo, le forum,

Pour éviter une fatigue inutile à Tibo en cette heure matinale je complète sa formule.

En C9, formule matricielle (validation par Ctrl+Maj+Entrée) :

=SOMME(SI(ESTNUM(GAUCHE(C3:C8;NBCAR(C3:C8)-[COLOR="Red"]ESTERR(DROITE(C3:C8)*1)[/COLOR])*1);GAUCHE(C3:C8;NBCAR(C3:C8)-[COLOR="Red"]ESTERR(DROITE(C3:C8)*1)[/COLOR])*1))

Edit : cela marche si un nombre existe dans la cellule ou s'il est suivi d'une seule lettre.

A+

 

[JHA]

Re : Somme chiffres et lettres

Bonjour Job75,

Chapeau pour cette formule, elle n'était pas facile à trouver, je la garde précieusement.

JHA

 

[Tibo]

Re : Somme chiffres et lettres

Bonjour à tous,

et merci à Job d'avoir préservé ma grasse matinée

Sur le même principe que la formule de Job, une variante :

=SOMME(SI(ESTNUM(GAUCHE(C3:C9;NBCAR(C3:C9)-ESTTEXTE(C3:C9))*1);
GAUCHE(C3:C9;NBCAR(C3:C9)-ESTTEXTE(C3:C9))*1))

Toujours matricielle, donc CTRL + MAJ +ENTREE

@+

 

[job75]

Re : Somme chiffres et lettres

Re,

Mais oui, très juste Tibo, quand une cellule contient un nombre, normalement elle n'est pas du texte.

Tu as toujours le dernier mot

A+

 

[Tibo]

Re : Somme chiffres et lettres

re,

Et c'est pas fini, on peut encore simplifier.

Le principe ; si la cellule commence par un chiffre, elle doit être prise en compte. On peut donc simplifier le test :

=SOMME(SI(ESTNUM(GAUCHE(C3:C9)*1);GAUCHE(C3:C9;NBCAR(C3:C9)-ESTTEXTE(C3:C9))*1))

Bon, j'arrête là

@+