Someprod

[nap]

Bonjour au Forum,

Je veux appliquer la formule Someprod (déjà en place sur d'autres fichiers) mais le résultat n'est pas bon.
Au lieu de filtrer, elle me ressort l'ensemble des occurrences.
Je ne comprends pas car j'utilise cette formule par ailleurs et elle fonctionne bien.

Quelqu'un a t'il une idée ?

 

[Tibo]

Re : Someprod

Bonjour,

Une tentative de correction :

=SOMMEPROD(($H$2:$H$500=2)*ESTNUM($I$2:$I$500)*($I$2:$I$500>"1/1/2010"*1))

Tes cellules "vides" contiennent en fait une chaîne de 10 espaces ?

Je te laisse tester

@+

 

[nap]

Re : Someprod

Super, la formule fonctionne.
Pour que je comprenne, ESTNUM apporte quoi ?

 

[tototiti2008]

Re : Someprod

Bonjour nap,

à tester :

=SOMMEPROD(($H$2:$H$24=2)*($I$2:$I$24>DATEVAL("01/01/2010"))*(SUPPRESPACE($I$2:$I$24)<>""))

Edit : Bonjour Tibo
10 espaces ne sont pas numériques, ESTNUM ne compte que les dates, pas les espaces

 

[nap]

Re : Someprod

Bonjour le forum,

Ne vous moquer pas, je n'arrive pas à faire l'inverse à savoir trouver le nombre d'occurrences pour lesquelles la zone de date est vide


Merci de votre aide

 

[tototiti2008]

Re : Someprod

Bonjour nap,

à tester

=SOMMEPROD((SUPPRESPACE(I4:I24)="")*1)

 

[nap]

Re : Someprod

Merci encore une fois le résultat est parfait comme votre formule

Et bon WE

 

[nap]

Re : Someprod

Bonjour,

Je me repenche sur la formule mais cette fois ci, je veux sélectionner le nombre d'occurrences ayant "2" et "3" après avoir changer l'un des "2" de la colonne H en "3". Etrangement si je fais
=SOMMEPROD(($H$2:$H$500=2)*($H$2:$H$500=3)*ESTNUM($I$2:$I$500)*($I$2:$I$500>"1/1/2010"*1)), le résultat est zéro alors que je devrais encore trouver 16.
J'ai "encore" raté quelque chose.

Merci de votre aide

 

[mth]

Re : Someprod

Bonjour à tous

Essaie en remplaçant le * (qui veut dire ET) par un + (qui veut dire OU)

=SOMMEPROD((($H$2:$H$500=2)+($H$2:$H$500=3))*ESTNUM( $I$2:$I$500)*($I$2:$I$500>"1/1/2010"*1))

Bon après-midi,

mth

 

[tototiti2008]

Re : Someprod

Bonjour nap,

le "*" représente un ET
Tu n'as aucune cellule qui contient en même temps 2 ET 3
Pour un OU il faut un "+", par l'intermédiaire de la fonction SIGNE

=SOMMEPROD(SIGNE(($H$2:$H$500=2)+($H$2:$H$500=3))*ESTNUM( $I$2:$I$500)*($I$2:$I$500>"1/1/2010"*1))

Edit : Bonjour Mireille, en effet SIGNE ne sert à rien ici

 

[nap]

Re : Someprod

Super et merci encore