simplification d' une formule SOMMEPROD

[almas]

bonjour le forum

j 'ai besoin d 'un petit conseil car j 'ai pas trouvé la solution

j'ai une formule SOMMEPROD à 2 conditions (type et mois) que j 'additionne à chaque type que je veux rajouter.

Cela me fait une formule à rallonge car j 'ai plus de 10 types à additionner .

je voulais savoir si il y avais un moyen de simplifier la formule

j 'ai essayer avec une liste de type mais sans sucés ^^

la formule de base:
SOMMEPROD(($A$2:$A$5=F2)*($C$2:$C$5=$D8)*($B$2:$B$5))

la formule ou j’additionne les type en rouge:
SOMMEPROD(($A$2:$A$5=F2)*($C$2:$C$5=$D8)*($B$2:$B$5))+SOMMEPROD(($A$2:$A$5=F5)*($C$2:$C$5=$D8)*($B$2:$B$5))+SOMMEPROD(($A$2:$A$5=F7)*($C$2:$C$5=$D8)*($B$2:$B$5))


je vous joint un petit fichiers test pour mieux comprendre

 

[CISCO]

Re : simplification d' une formule SOMMEPROD

Bonjour

Peut être avec

SOMMEPROD((($A$2:$A$8=F2)+($A$2:$A$8=F5)+($A$2:$A$8=F7))*($C$2:$C$8=$D8)*($B$2:$B$8))

@ plus

Si tu n'avais pas deux C dans la colonne A, on pourrait faire autrement, en ne prenant en compte que les lignes paires.

 

[djidji59430]

Re : simplification d' une formule SOMMEPROD

Bonjour,
on peut mettre en facteur commun :

=SOMMEPROD((($C$2:$C$8=$D8)*($B$2:$B$8))*(($A$2:$A$8=F2)+($A$2:$A$8=F5)+($A$2:$A$8=F7)))

edit : bonjour Cisco, je ne t'avais pas vu !

 

[GerardCalc]

Re : simplification d' une formule SOMMEPROD

Bonjour,

Ou encore :

=SOMMEPROD(($A$2:$A$8={"A"."D"."F"})*($C$2:$C$8=$D8)*($B$2:$B$8))

A+

 

[almas]

Re : simplification d' une formule SOMMEPROD

merci à tous pour ces simplifications j 'ai appris plein de choses😛!!!

pour ce cas la je vais prendre la solution de GerardCalc car je peut avoir 10 a 12 types différents et donc les lister dans la formule va la rendre bien plus simple et surtout lisible

merci encore a tous!

 

[GerardCalc]

Re : simplification d' une formule SOMMEPROD

merci à tous pour ces simplifications j 'ai appris plein de choses😛!!!

pour ce cas la je vais prendre la solution de GerardCalc car je peut avoir 10 a 12 types différents et donc les lister dans la formule va la rendre bien plus simple et surtout lisible

merci encore a tous!

Tu n'est pas obligé de les lister dans la formule, tu peux aussi utiliser une plage de cellule contenant les critères.

=SOMMEPROD(($A$2:$A$8=F1:H1)*($C$2:$C$8=$D8)*($B$2:$B$8))

avec F1:H1 contenant les critères.
La seule restriction est que les critères doivent être en ligne.
Si tu les as en colonne, par exemple F1:F3, il faut alors utiliser TRANSPOSE :

=SOMME(($A$2:$A$8=TRANSPOSE(F1:F3))*($C$2:$C$8=$D8)*($B$2:$B$8))

mais cette fois ci, la formule doit être validée en matricielle (Ctrl+Maj+Entrée) pour que le TRANSPOSE soit pris en compte. Et comme c'est en matriciel, on peut remplacer SOMMEPROD par SOMME.

A+

 

[JHA]

Re : simplification d' une formule SOMMEPROD

Bonjour à tous,

si tu as une version supérieure à "2003"

=SOMMEPROD(SOMME.SI.ENS($B$2:$B$8;$A$2:$A$8;liste;$C$2:$C$8;$D8))

JHA