Résolu XL pour MAC =SI(SOMMEPROD.....

pilou010

XLDnaute Nouveau
Bonjour à tous,
Je souhaite remplir un tableau en fonction de critères se trouvant dans un autre tableau. J'ai tenté une bidouille avec =SI(SOMMEPROD mais je ne maitrise pas la formule et je ne sais pas si c'est la bonne formule donc je n'arrive pas au résultat.
Est-ce que quelqu'un ici aurait la gentillesse de jeter un coup d’œil sur mon souci ?
En PJ un classeur pour exemple
Merci
 
Ce fil a été résolu! Aller à la solution…

Fichiers joints

sylvanu

XLDnaute Barbatruc
Supporter XLD
Bonjour Pilou,
Somme.Si.Ens semble plus approprié pour votre problématique:
VB:
=SOMME.SI.ENS($E$3:$E$100;$B$3:$B$100;"1 "&$G3&" "&H$2)
 

Fichiers joints

job75

XLDnaute Barbatruc
Bonjour pilou010, sylvanu,

Puisque les dates de Tableau1 sont toutes le 1er de chaque mois formule en H3 :
Code:
=SIERREUR(RECHERCHEV(DATEVAL($G3&H$2);Tableau1;4;0);"")
A+
 

Fichiers joints

job75

XLDnaute Barbatruc
Maintenant si les dates de Tableau1 sont quelconques on utilisera en H3 :
Code:
=SOMMEPROD((ANNEE(INDEX(Tableau1;;1))=--H$2)*(MOIS(INDEX(Tableau1;;1))=MOIS("1/"&$G3));INDEX(Tableau1;;4))
 

Fichiers joints

job75

XLDnaute Barbatruc
Une formule plus simple dans ce fichier (3) :
Code:
=SOMMEPROD((INDEX(Tableau1;;1)-JOUR(INDEX(Tableau1;;1))+1=DATEVAL($G3&H$2))*INDEX(Tableau1;;4))
 

Fichiers joints

pilou010

XLDnaute Nouveau
Oui R@chid cela fonctionne avec un TCD j'en ai fait un mais je n'y avais pas pensé...

job75, comment faire pour que soit pris en compte que les sommes du crédit si il y a "Loyer" dans la colonne "action" ?
En effet j'ai d'autres revenus qui ne sont pas des loyers.
Merci
 

job75

XLDnaute Barbatruc
job75, comment faire pour que soit pris en compte que les sommes du crédit si il y a "Loyer" dans la colonne "action" ?
Il y a des espaces superflus en colonne "Action", fichier (4) avec SUPPRESPACE :
Code:
=SOMMEPROD((INDEX(Tableau1;;1)-JOUR(INDEX(Tableau1;;1))+1=DATEVAL($G3&H$2))*(SUPPRESPACE(INDEX(Tableau1;;2))="Loyer");INDEX(Tableau1;;4))
Salut R@chid.
 
Ce message a été identifié comme étant une solution!

Fichiers joints

Créez un compte ou connectez vous pour répondre

Vous devez être membre afin de pouvoir répondre ici

Créer un compte

Créez un compte Excel Downloads. C'est simple!

Connexion

Vous avez déjà un compte? Connectez vous ici.

Haut Bas