si..si..si me donne "FAUX" et me laisse perplexe...

[kllmoon]

Premièrement, bonjour à vous tous, ça fait un bail que je ne suis pas venu par ici et je suis heureux de voir le forum encore actif!

Mon problème est concernant une formule assez complexe qui me donne un résultat "FAUX" et que je ne comprend pas pourquoi!

Voici la dite formule :

=SI(ESTVIDE(F23);"";SI(DATEDIF(F23;F1;"y")=0;SI(DATEDIF(F23;F1;"ym")=0;DATEDIF(F23;F1;"md")&" jours"; SI(DATEDIF(F23;F1;"y")=0;DATEDIF(F23;F1;"ym")&" mois "&DATEDIF(F23;F1;"md")&"  jours";DATEDIF(F23;F1;"y")&" an "&DATEDIF(F23;F1;"ym")&" mois "&DATEDIF(F23;F1;"md")&" jours"))))

En F1 j'ai la valeur aujourd'hui() et en f23 une date antérieure. Si cette date est de moins d'un an, le résultat est bon. Exemple de résultat : "2 mois 20 jours". Par contre, si cette date est de plus d'une année antérieure, le résultat obtenu est "Faux"

La formule =DATEDIF(F23;F1;"y")&" an "&DATEDIF(F23;F1;"ym")&" mois "&DATEDIF(F23;F1;"md")&" jours") me donne le résultat escompté "1 an 2 mois 20 jours".

Alors, quelqu'un a-til (elle) une idée sur l'erreur dans ma formule? Merci de votre précieuse aide!

 

[tdenfert]

Re : si..si..si me donne "FAUX" et me laisse perplexe...

Bonjour,

une idée à tester peut être plus simple

=SI(MOIS.DECALER(B4;12)>C4;DATEDIF(B4;C4;"y")&" an et "&DATEDIF(B4;C4;"ym")&" mois et"&DATEDIF(B4;C4;"md")& " jours";"faux")

avec en b4 la date et en C4 aujourdhui()


edit : en relisant il faut ajouter la condition est vide

 

[kllmoon]

Re : si..si..si me donne "FAUX" et me laisse perplexe...

Ça fonctionne bien mais j'avais la grosse formule complexe pour éviter les "0 an et 0 moi et 3 jours" dans mon tableau. Avec ma formule j'ai 3 résultats possibles :

3 jours
3 mois et 3 jours
3 ans 3 mois et 3 jours ---> mais pour l'instant ça donne "FAUX"

Ta formule fonctionne impec mais me donne

0 an 0 mois et 3 jours
0 an 3 mois et 3 jours
3 an 3 mois et 3 jours

Je trouve que ça fait un peu malpropre dans mon tableau

 

[eriiic]

Re : si..si..si me donne "FAUX" et me laisse perplexe...

Bonjour,

tester :
=SI(DATEDIF($F$23;$F$1;"y");DATEDIF($F$23;$F$1;"y")&" an ";"")&SI(DATEDIF($F$23;$F$1;"ym");DATEDIF($F$23;$F$1;"ym")&" mois ";"")&SI(DATEDIF($F$23;$F$1;"md");DATEDIF($F$23;$F$1;"md")&" jours ";"")

eric

 

[kllmoon]

Re : si..si..si me donne "FAUX" et me laisse perplexe...

Merci de ta réponse, j'avais un soucis mais c'est réglé

J'ai ajouté un petit bout pour éviter d'avoir des 112 ans dans mon tableau à la place de cases vides

=SI(ESTVIDE(F3);"";SI(DATEDIF(F3;$F$1;"y");DATEDIF(F3;$F$1;"y")&" an ";"")&SI(DATEDIF(F3;$F$1;"ym");DATEDIF(F3;$F$1;"ym")&" mois ";"")&SI(DATEDIF(F3;$F$1;"md");DATEDIF(F3;$F$1;"md")&" jours ";""))