Sauvegarde d'un fichier

[GADENSEB]

Re Bonjour,
Pour le fichier joint je souhaiterais créer une procédure (via un bouton) pour enregistrer ce fichier :

- Dans un dossier "OLD" présent dans le mm dossier que le fichier en question
- Cette version devra (dans le dossier "OLD") se s'appeler NOTE DIAG DLA - Version X"
- Sachant que dans le dossier OLD, il peut se trouver d'autre version du fichier et donc le "X" devra s'incrémenter 1 puis 2 puis 3......

donc au final il faut :

Dossier :
- NOTE DLA DIAG enregister au plus récent
Dossier / OLD
- NOTE DLA DIAG - Version X

Est-ce clair ?

Je ne sais pas par où commencer le code !


Merci

Bonne aprem

Seb

 

[DoubleZero]

Re : Sauvegarde d'un fichier

Bonjour, GADENSEB, le Forum,

Une suggestion, ici.

A bientôt 🙂

 

[GADENSEB]

Re : Sauvegarde d'un fichier

Je pars là dessus

Sub SAUVEGARDE_Cliquer()

  répertoire = ActiveWorkbook.Path & "\ OLD"
  nomFichier = "NOTE DIAG DLA"
  nf = Dir(répertoire & "\" & nomFichier & "*")
  n = 0
  Do While nf <> ""
    n = n + 1
    nf = Dir
  Loop
  ActiveWorkbook.SaveAs Filename:=répertoire & "\" & nomFichier & " - V" & n + 1


End Sub

Comment inclure :

Si le dossier OLD éxiste alors j'incrémente le N° de fichier ?
Si le dossier OLD n'éxiste pas alors je le créer et j'incrémente le n° de fichier ?

Je veux aussi que le fichier d'origine (sans numéro de version) reste ouvert
là dans cette macro le fichier sans numéro de version se ferme et c'est celui avec un numéro de version qui est à l'écran !

Merci

Bonne journée

Seb

 

[GADENSEB]

Re : Sauvegarde d'un fichier

hello,
Je fais remonter le topic.

qqn aurait une idée ?

Bonne journée

Seb

 

[camarchepas]

Re : Sauvegarde d'un fichier

Bonjour Double zéro, GADENSEB

Voici une possibilité

Sub SAUVEGARDE_Cliquer()
Dim Répertoire As String, Nf As String, NomFichier As String
Dim N As Long
 
 Répertoire = ActiveWorkbook.Path & "\ OLD"

'Si le dossier OLD n'éxiste pas alors je le créer
 If Dir(Répertoire, vbDirectory) = "" Then MkDir (Répertoire)

'et j'incrémente le n° de fichier pour les 2 cas
  NomFichier = "NOTE DIAG DLA"
  Nf = Dir(Répertoire & "\" & NomFichier & "*" & ".xlsm")
  N = 0
  Do While Nf <> ""
    N = N + 1
    Nf = Dir
  Loop
  
'Sauvegarde une copie du fichier et ne touche donc pas au fichier en cours
  ActiveWorkbook.SaveCopyAs Filename:=Répertoire & "\" & NomFichier & " - V" & N + 1 & ".xlsm"

End Sub

 

[GADENSEB]

Re : Sauvegarde d'un fichier

Perfecto c'est ce que je chercher !

Merci

Bonne aprem

 

[GADENSEB]

Re : Sauvegarde d'un fichier

Par contre, je me disais :

est-ce que
NomFichier = "NOTE DIAG DLA"

Peut etre remplacé par le nom du fichier qui ne sera pas tjrs "NOTE DIAG DLA"

Bonne aprem

 

[camarchepas]

Re : Sauvegarde d'un fichier

Veux-tu une boite de dialogue pour saisir le nom du fichier ?

Ou la boite ouvrir un fichier pour le sélectionner directement dans le dossier ?

Sinon si cela n'est pas fréquent tu peux te contenter de modifier le code ....

 

[GADENSEB]

Re : Sauvegarde d'un fichier

Ben en fait je voudrais que

NomFichier = "NOTE DIAG DLA"

prenne le nom du fichier automatiquement (pas de boite de dialogue ou autre)
A la place de "NOTE DIAG DLA" je peux avoir BIBI ou BOBO ou BABA .....

 

[camarchepas]

Re : Sauvegarde d'un fichier

Si tu créer une variable public dans le module standard , tu peux ensuite l'utiliser

Dans le module standard
public NomFichierPublic as string

lors de ton traitement , tu renseignera cette variable


et donc dans le module de sortie

Nomfichier = NomFichierPublic

 

[GADENSEB]

Re : Sauvegarde d'un fichier

heuuuu je dois louper une étape car l'incrémentation du numéro de version se fait bien mais je n'ai plus de nom de fichier ......

 

[camarchepas]

Re : Sauvegarde d'un fichier

En un peu plus détaillé
la macro démo renseigne le nom à utiliser

public Nom as string
Sub démo()
Nom =  "Machin"
End Sub


Sub SAUVEGARDE_Cliquer()
Dim Répertoire As String, Nf As String, NomFichier As String
Dim N As Long
 
 Répertoire = ActiveWorkbook.Path & "\ OLD"

'Si le dossier OLD n'éxiste pas alors je le créer
 If Dir(Répertoire, vbDirectory) = "" Then MkDir (Répertoire)

'et j'incrémente le n° de fichier pour les 2 cas
  NomFichier = Nom '"NOTE DIAG DLA"
  Nf = Dir(Répertoire & "\" & NomFichier & "*" & ".xlsm")
  N = 0
  Do While Nf <> ""
    N = N + 1
    Nf = Dir
  Loop
 
'Sauvegarde une copie du fichier et ne touche donc pas au fichier en cours
  ActiveWorkbook.SaveCopyAs Filename:=Répertoire & "\" & NomFichier & " - V" & N + 1 & ".xlsm"

End Sub

 

[GADENSEB]

Re : Sauvegarde d'un fichier

Ben pour moi le nom serait le nom effectif du fichier .xlsm

 

[camarchepas]

Re : Sauvegarde d'un fichier

Ok,

le besoin se précise ,

comme cela peut être

Sub SAUVEGARDE_Cliquer()
Dim Répertoire As String, Nf As String, NomFichier As String
Dim N As Long
 
 Répertoire = ActiveWorkbook.Path & "\ OLD"

'Si le dossier OLD n'éxiste pas alors je le créer
 If Dir(Répertoire, vbDirectory) = "" Then MkDir (Répertoire)

'et j'incrémente le n° de fichier pour les 2 cas
  NomFichier = replace(activeworkbook.name,".xlsm","")
  Nf = Dir(Répertoire & "\" & NomFichier & "*" & ".xlsm")
  N = 0
  Do While Nf <> ""
    N = N + 1
    Nf = Dir
  Loop
 
'Sauvegarde une copie du fichier et ne touche donc pas au fichier en cours
  ActiveWorkbook.SaveCopyAs Filename:=Répertoire & "\" & NomFichier & " - V" & N + 1 & ".xlsm"

End Sub

 

[GADENSEB]

Re : Sauvegarde d'un fichier

J'ai trouvé :

NomFichier = ThisWorkbook.Name


Merciiiiiiiiii