[Résolue] Rotation hebdo de 5 équipes vs n° de semaine.

[Victor21]

Bonjour à tous

Tite question - une fois n'est pas coutume

5 équipes : A, B, C, D, E, rotation des équipes chaque semaine.
Point de départ semaine 1 de 2012 avec l'équipe C (colonne R du fichier joint).

La ligne 3 calcule le n° de semaine en extrayant la date en ligne 2 :

=ENT(MOD(ENT((DATE(STXT(R$2;1;4);STXT(R$2;5;2);STXT(R$2;7;2))-2)/7)+3/5;52+5/28))+1

La ligne 4 détermine l'équipe en place. Pour les colonne R à AK, pas de pb :

=SI(S2="";"";CHOISIR(EQUIV(MOD(S3;5);{1;2;3;4;0};0);"C";"D";"E";"A";"B"))

Mais je suis obligé de tricher entre les colonnes C à Q :

=SI(Q2="";"";CHOISIR(EQUIV(MOD(Q3+3;5);{1;2;3;4;0};0);"C";"D";"E";"A";"B"))

et à partir de la colonne AL :

=SI(AL2="";"";CHOISIR(EQUIV(MOD(AL3+2;5);{1;2;3;4;0};0);"C";"D";"E";"A";"B"))

Quelle formule unique puis-je utiliser en ligne 4, en évitant un test genre

=si(stxt(c2;1;4)= ?

Merci d'avance pour vos suggestions

 

[CISCO]

Re : [Résolue] Rotation hebdo de 5 équipes vs n° de semaine.

Bonjour

Bien vu, David84. Il était évident qu'il y avait une solution sans passer par le n° de la semaine, mais en utilisant DATE et l'info en ligne 2. Encore fallait-il la trouver (par exemple le -2 dans le ENT).

A y être, il me semble un peu dommage de passer par EQUIV(MOD( ....;5);{4;0;1;2;3}...

Il me semble que l'on peut faire plus simplement avec :

=SI(C2<>"";CHOISIR(MOD(ENT((DATE(STXT(C$2;1;4);STXT(C$2;5;2);STXT(C$2;7;2))-2)/7)-2;5)+1;"A";"B";"C";"D";"E");"")

ou encore avec

=SI(C2<>"";CHOISIR(MOD(ENT((DATE(STXT(C$2;1;4);STXT(C$2;5;2);STXT(C$2;7;2))-2)/7);5)+1;"D";"E";"A";"B";"C");"")

@ plus

 

[david84]

Re : [Résolue] Rotation hebdo de 5 équipes vs n° de semaine.

Re
bien vu Cisco.
En reprenant ton calcul du Mod, l'on peut même passer par CAR au lieu de CHOISIR et raccourcir encore :

=SI(C2<>"";CAR(64+MOD(ENT((DATE(STXT(C2;1;4);STXT(C2;5;2);STXT(C2;7;2))-2)/7)-2;5)+1);"")

A+

 

[Victor21]

Re : [Résolue] Rotation hebdo de 5 équipes vs n° de semaine.

Re, CISCO, David

Trop forts

 

[Grand Chaman Excel]

Re : [Résolue] Rotation hebdo de 5 équipes vs n° de semaine.

Wow! Très fort en effet.

Tant qu'à raccourcir... il y a un raison pour le CAR(64 + MOD(...) + 1) ?
Pourquoi pas simplement CAR(65 + MOD(...)) ?

=SI(C2<>"";CAR(65+MOD(ENT((DATE(STXT(C2;1;4);STXT(C2;5;2);STXT(C2;7;2))-2)/7)-2;5));"")

A+

 

[CISCO]

Re : [Résolue] Rotation hebdo de 5 équipes vs n° de semaine.

Bonsoir à tous, bonsoir david84, Grand Chaman Excel et Victor21

Je n'avais vraiment pas pensé à cette astuce, passer par CAR au lieu de CHOISIR... Bien vu David84. Et autant mettre 65 plutot que 64 +....+1.

@ plus