*Résolu*Userform ajout même avec ligne TOTAUX

[Xoomer]

Bonjour à tous,

j'ai un Userform qui fonctionne presque à la perfection, sauf que quand je clique sur valider, et que dans mon tableau il la ligne TOTAUX, il mets les données en bas de mon tableau et non dans le tableau, y aurait-il un moyen en gardant la ligne TOTAUX actif que les données aillent bien dans le tableau? si j'enleve la fonction Ligne TOTAUX le tout fonctionne.

j'insère ici mon fichier test.

merci de votre aide!

 

[Paf]

Re : Userform ajout même avec ligne TOTAUX

Bonjour

modifier la partie écriture dans Private Sub CommandButton1_Click() de la Userform1

With Worksheets("Données")
   DerLigne = .Range("C65000").End(xlUp).Row - 1
   .Rows(DerLigne).Insert Shift:=xlUp
   .[A:AS].Rows(DerLigne).Value2 = V2
End With

Il y a certainement une méthode moins barbare en utilisant des instructions propres aux Tableaux (XL >= 2007)

A+

 

[Speel]

Re : Userform ajout même avec ligne TOTAUX

Bonsoir,

regardes là : Ce lien n'existe plus

 

[Xoomer]

Re : Userform ajout même avec ligne TOTAUX

Merci Paf, ca fonctionne nickel!

 

[Xoomer]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

Bonjour Paf,

j'ai réouvert (*Réouvert*Userform ajout même avec ligne TOTAUX), car ca fonctionne pas tout a fait, il ajoute bien la ligne avant, mais parcontre il enleve mes calcul dans les cellules. est-ce que tu comprends ce que je veux dire ?

 

[Regueiro]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

Bonsoir Le Forum, Xoomer.
Voici un code qui insère une ligne avant les sous-totaux
et garde les formules.

Il faut l'adapter à ton problème.

Sub insertionligne()
Dim LR As ListRow
Dim LSTOB As ListObject
Dim F As Worksheet

Set F = Sheets("SORTIE MATIERE")
Set LSTOB = F.ListObjects("Tableau3")

  With LSTOB.TotalsRowRange.Select
    Set LR = Selection.ListObject.ListRows.Add(AlwaysInsert:=True)
    
    End With
    
End Sub

A1

 

[Xoomer]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

ouf je suis perdu là,

si mon code est le suivant:
Private Sub CommandButton1_Click()
Dim V2(1 To 1, 1 To 7), DerLigne As Long
On Error GoTo Erreur
V2(1, 1) = Me.ComboBox1.Text
V2(1, 2) = Me.MonthView1.Value
V2(1, 3) = CCur(Me.TextBox1.Text)
V2(1, 4) = CCur(Me.TextBox2.Text)
V2(1, 5) = Me.MonthView2.Value
V2(1, 7) = Me.TextBox3.Text



With Worksheets("Données")
DerLigne = .Range("C65000").End(xlUp).Row + 1
.[A:G].Rows(DerLigne).Value2 = V2
End With
Exit Sub
Erreur: MsgBox Err.Description
End Sub

Comment je fait alors? Est-ce que il faut que remplace en commencant : With Worsheets("Données") et le reste?

merci pour ton aide!

 

[Paf]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

Bonjour à tous

le code remanié:

Private Sub CommandButton1_Click()
 Dim ListObj As ListObject, LR As ListRow

 On Error GoTo Erreur

 Set ListObj = Worksheets("Données").ListObjects("Tableau1")
 Set LR = ListObj.ListRows.Add

 LR.Range.Cells(1, 1) = Me.ComboBox1.Text
 LR.Range.Cells(1, 2) = Me.MonthView1.Value
 LR.Range.Cells(1, 3) = CCur(Me.TextBox1.Text)
 LR.Range.Cells(1, 4) = CCur(Me.TextBox2.Text)
 LR.Range.Cells(1, 5) = Me.MonthView2.Value
 LR.Range.Cells(1, 7) = CCur(Me.TextBox3.Text)

 Exit Sub
 Erreur: MsgBox Err.Description
End Sub

Bonne suite

 

[Regueiro]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

Bonsoir le Forum, Paf, Xoomer
PAF m'a devancer ?
Car je ne peux malheureusement pas ouvrir le fichier de XOOMER


Je pense à cause du MONTVIEW ?
A+

 

[Xoomer]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

Bonsoir Paff,

je vais essayer ton code, et te donné des nouvelles sous peu.

 

[Xoomer]

Re : *Réouvert*Userform ajout même avec ligne TOTAUX

Ca marche, pour l'instant, donc je fait mes testet vous reviens avec la mention ***résolu***

merci