[Résolu] Somme sur valeur non numérique

[tite schtroumpfette]

Bonjour à tous !

Une fois de plus je iens vers vous... Je suis sûre que la solution est super simple mais je me casse la tête dessus depuis 1h.

Voici ma feuille de calcul en pièce jointe.

Dans la colonne 9 les utilisateurs sélectionnent s'ils sont concernés ou non par les critères de la colonne 2.

Je voudrais qu'en fonction du nombre de "oui" (pour l'instant 1 mais ça peut changer), il s'affiche 7 dans la case cotation.

Je suis passée par un calcul intermédiaire en colonne 15, et c'est là que ça coince.
Pour chaque critère, il s'affiche 1 si la cas oui est cochée.

La fontion somme dans la case cotation ne fonctionne pas.
C'est probablement du au fait que les valeurs de ma colonne 15 ne sont as reconnues comme numériques (j'ai testé =ESTNUM).
Cependant le format est bien "nombre".
Qu'est-ce que j'ai loupé ??

Je ne voudrais utiliser que des fonctions simples afin de maitriser des modifs ultérieures du document.

 

[Guest]

Re : Somme sur valeur non numérique

bonjour,

tu peux enlever les guillemets "1"; "0" de tes fonctions en colonne O =Si(I2="OUI";1;0)
ou mettre la formule: =(I2="OUI")*1

A+

 

[Excel-lent]

Re : Somme sur valeur non numérique

Bonjour Tite schtroumpfette, Hasco,

Si j'ai bien compris, tu veux une formule simple qui compte le nombre de "OUI" dans la colonne 9?

Bonne nouvelle, tu n'as pas besoin de passer par une colonne intermédiaire.

Si dans "outils"/"option"/ onglet "général" la case "Style de référence L1C1 est coché :
-> voici la formule à écrire colonne 9 ligne 21 :

=NB.SI(L(-19)C:L(-2)C;"OUI")

Si dans "outils"/"option"/ onglet "général" la case "Style de référence L1C1 est décoché :
-> voici la formule à écrire cellule [I21]:

=NB.SI(I2:I19;"OUI")

Bonne après midi

 

[Excel-lent]

Re : Somme sur valeur non numérique

Re,

Après relecture, si j'ai bien lu cette fois ci, tu veux :
Lorsqu'il y a au moins une réponse "OUI" écrire "7" dans la case cotation?

Il te suffit d'utiliser la même fonction : NB.SI()

Si dans "outils"/"option"/ onglet "général" la case "Style de référence L1C1 est décoché :
-> voici la formule à écrire cellule [I21]:

=SI(NB.SI(I2:I19;"OUI")>=1;7;"")

Comme tu le vois, il suffit juste d'imbriquer la fonction donnée précédement dans une fonction SI()

Si tu trouve cela compliqué et souhaite plus d'explication, n'hésite pas

A+

 

[tite schtroumpfette]

Re : Somme sur valeur non numérique

Excellent Hasco ça marche !!!!

Excel-lent :
En fait je voudrais qu'il écrive 1 sinon, donc je vais remplacer les derniers guillemets par 1 (si j'ai bien compris) : SI(NB.SI(I2:I19;"OUI")>=1;7;1)

La formule voudrait donc dire :
Compter le nombre de "oui" dans le champ I2 à I19, si ce nombre est supérieur ou égal à 1, mettre 7, sinon 1.


Et si je voulais pousser le vice à écrire ça :
Compter le nombre de "oui" dans le champ I2 à I19,
- si ce nombre est inférieur ou égal à 1, mettre 1,

- si ce nombre est supérieur à 1, mettre 5,

- sinon mettre 7.

Ca deviendrait alors ça (youpi ça marche) :
=SI(NB.SI(L(-19)C:L(-2)C;"OUI")<=1;1;SI(NB.SI(L(-19)C:L(-2)C;"OUI")>1;5;7))

 

[tite schtroumpfette]

Re : Somme sur valeur non numérique

Après discussion avec un collègue il se pourraient qu'on change encore de calcul.
Il y aurait maintenant des conditions différentes selon les lignes.

Je sèche je vous envoie le nouveau fichier...

Il faudrait que cela donne le résultat suivant :
- si une case orange est "oui" : indiquer 7
sinon, si pas de case orange :
- si une case jaune est "oui" : indiquer 5
sinon, si pas de case jaune :
(autres choix, soit : si une case verte est "oui", ou si tout est "non") : indiquer 1

Je ne sais pas comment faire le calcul avec non pas une plage mais des cases isolées.Une solution qui ne m'oblige pas à réorganiser les lignes ? Je préfèrerais classer par thème et non par type d'enjeu.

SI(NB.SI(cases orange;"OUI")=1;7;SI(NB.SI(cases jaunes;"OUI")=1;5;1))

Peut-être avec BDSOMME ? Je cherche mais je ne maitrise pas la formule. Si vous avez une idée avant moi ?

 

[Guest]

Re : Somme sur valeur non numérique

Re,

vois si ça convient:

=MAX((SOMMEPROD((L3C8:L23C8="fort")*(L3C9:L23C9="OUI"))>=1)*7;(SOMMEPROD((L3C8:L23C8="moyen")*(L3C9:L23C9="OUI"))>=1)*5;1)

A+

 

[tite schtroumpfette]

Re : Somme sur valeur non numérique

GENIAL

Par contre je ne comprend pas.
Je vois que sommeprod additionne les critères "oui" et "enjeux forts" puis "oui" et "enjeux moyens"Mais je ne comprend pas l'imbrication avec la fonction max et les signes <= et les virgules.

Tu m'explique vite fait ??


=MAX((SOMMEPROD((L(-22)C(7):L(-2)C(7)="fort")*(L(-22)C:L(-2)C="OUI"))>=1)*7;(SOMMEPROD((L3C8:L23C8="moyen")*(L3C9:L23C9="OUI"))>=1)*5;1)

 

[Guest]

Re : Somme sur valeur non numérique

Bonjour,

Il faut regarder l'aide excel sur les fonctions.
Où tu verras que Max(Arg1,Arg2,Arg3.......)

Tu as un sommeprod qui donnera 1 (ou plus) Fort oui
En comparant la valeur renvoyer par le somme prod à une autre valeur on obtient Vrai (1) ou Faux(0)

Vrai *7 = 7
Faux * 7 = 0

Il faut que le résultat de sommeprod soit au moins égal à 1 pour renvoyer 7


Pour le deuxième sommeprod c'est pareil mais multiplier par 5 pour quand 1 ou plus sont
moyen et oui

Donc au final on peut avoir
Max(7;5;1) = 7
Max(0;5;1) = 5
Max(0;0;1) = 1


A+

 

[tite schtroumpfette]

Re : Somme sur valeur non numérique

Bonjour,

Merci beaucoup c'est très clair.
Il y a juste un truc que je ne comprend pas (le "il note 1")
Je pensais que SOMMEPROD fait la somme, donc s'il y a 2 cases moyen il doit les additionner, mais le résultat est toujours 1 ?

Max indique le plus grand des 3 nombres :

Les 3 nombres indiqués sont :
- SOMMEPROD(($S$168:$S$188="fort")*($L$168:$L$188="OUI"))>=1)*7
C'est à dire s'il y a plus d'une combinaison de cases "fort" et "oui" il note 1 et multiplie par 7

- (SOMMEPROD(($S$168:$S$188="moyen")*($L$168:$L$188="OUI"))>=1)*5
C'est à dire s'il y a plus d'une combinaison de cases "moyen" et "oui" il note 1 et multiplie par 5

- 1

 

[Guest]

Re : Somme sur valeur non numérique

Re,

Pour excel VRAI = 1 et Faux =0
Sommeprod renvoie la somme de produit(s)
ici la somme des produits de $S$168:$S$188="fort" et $L$168:$L$188="OUI"
pour chaque cellule des plages il va comparer la valeur à fort ou à oui et renvoyer des 1 (Vrai) ou 0 (faux)
ensuite il multiplie ces 1 ou 0 et en renvoie la somme

Cette somme peut-être 0 ou 2 ou 6 ou plus (pour l'exemple prenons 6 puis 0)
Ensuite cette somme est comparée à 1
6=>1 ? -> Vrai
Vrai *7 = 7 (dans le cas moyen se sera multiplié par 5)

0=>1 ? -> Faux
Faux * 7 = 0

On aura donc en final
pour fort: 0 ou 7
pour moyen 0 ou 5
dans les autres cas se sera toujours 1 (pas de fort, pas de moyen)

Donc Max renverra la plus grande ce ces valeurs avec au minimum 1 si aucun fort trouvé ou aucun moyen.

A+