XL 2010 [RESOLU] Copier collé d'un fichier fermé quelconque

[Meosus]

Bonjour a tous,

Je viens vers vous car je sèche.
Je cherche a partir d'un code VBA a allez chercher un fichier excel (Extraction d'un appareil de mesure) et y copié toute les cellules à partir de la cellule A10.

Range("A10").Select
Range(Selection, Selection.End(xlToRight)).Select
Range(Selection, Selection.End(xlDown)).Select

La ou je sèche c'est sur le faite d'ouvrir une fenêtre pour aller sélectionner mon fichier Excel.

Je n'ai trouver que des astuces pour ouvrir un fichier déjà référencer dans la macro, hors ce fichier peux être n'importe ou (Sur le pc, sur un serveur, ...).

Le plus simple serait d'aller même chercher les valeurs sans l'ouvrir.

Dans l'attente d'une réponse, merci d'avance à celui qui répondra.

Meosus

 

[Chris401]

Bonsoir

Questions :
1 - Les données à copier se trouvent-elles dans une feuille particulière (si oui, quel est son nom) ou n' y a-t-il qu'une feuille ?
2 - Est-ce que les cellules à copier sont des résultats de formules ou des constantes ?
3 - A partir de quelle cellule veux-tu coller ? A1 ?

 

[Meosus]

Bonsoir,
Merci pour ces questions pertinentes, j'indiquerais ces donnés directement la prochaine fois!

Alors réponse 1:
Oui dans la premiere feuille du classeur nommée "extraction_mesure"

Réponse 2:
Les résultats sont des valeurs constante, pour information ce sont des valeurs prise à un instant "t"

Réponse 3:
Les cellules copié seront à coller dans la feuille 2 nommé "rapport_extraction" de mon tableau rapport à partir de la cellule A5

Merci d'avance.
Ci besoin je peux joindre les deux fichiers excel!

 

[Chris401]

Essaye avec ce code :

Sub Importe()
Application.ScreenUpdating = False
Dim Fichier As Variant

'Recherche du fichier
Fichier = Application.GetOpenFilename("Tous les fichiers (*.*),*.*")
   
If Fichier <> False Then 'Si on n'a pas cliqué sur "Annuler"
    Workbooks.Open Filename:=Fichier 'Ouverture du fichier
    NomFichier = Dir(Fichier) 'Nom du fichier sans le chemin

        With Workbooks(NomFichier) 'Avec le fichier que l'on vient d'ouvrir
            Set f = Sheets("extraction_mesure") 'Détermination de la feuille à traiter
           
                'Sélection de la plage à copier
                f.Range("A10").Select
                f.Range(Selection, Selection.End(xlToRight)).Select
                f.Range(Selection, Selection.End(xlDown)).Select
               
                'Copie de la sélection dans le fichier actuel
                Selection.Copy ThisWorkbook.Sheets("rapport_extraction").Range("A5")
               
                .Close 'Fermeture du fichier ayant servi à la copie
        End With
End If
End Sub

 

[Meosus]

Salut Chris401,

Merci de ta réponse, exactement ce que je cherchais! Je l'ai readapter un petit peu mais nikel!

Merci