XL 2010 Redimensionner une image

[Magic_Doctor]

Bonjour,

Le problème est le suivant :
Je clique sur un bouton et apparaissent :
- une image qui occupe une partie de l'écran
- un bouton qui, lorsque je clique dessus, commande le redimensionnement de l'image afin qu'elle occupe pratiquement tout l'écran. Si je reclique sur ce bouton, l'image reprend ses dimensions antérieures.
Je ne parviens pas à redimensionner cette image. J'ai bien essayé avec l'enregistreur de macro mais sans succès.
Comment s'y prendre ?

 

[job75]

Bonjour Magic_Doctor, le forum,

Vois si ceci te convient :

Sub Image()
Dim test As Boolean
With ThisWorkbook.Names
    .Add "X", 190
    .Add "Y", 80
    .Add "W", 260
    .Add "H", 120
End With
With ActiveSheet.DrawingObjects("Bouton")
    test = .Text = "Grand"
    .Text = IIf(test, "Petit", "Grand")
End With
Application.DisplayFullScreen = test
With ActiveSheet.Shapes("Mon_Image")
    .Left = IIf(test, 0, [X])
    .Top = IIf(test, 0, [Y])
    .Width = IIf(test, Application.Width, [W])
    .Height = IIf(test, Application.Height, [H])
End With
End Sub

Bonne journée.

 

[patricktoulon]

bonsoir @job75
on peut simplifier

Option Explicit

Sub Image()
    With ActiveSheet.Shapes("Mon_Image")
        Application.DisplayFullScreen = .Width = 260
        .Left = IIf(.Left = 190, 0, 190)
        .Top = IIf(.Top = 80, 0, 80)
        .Width = IIf(.Width = 260, Application.Width, 260)
        .Height = IIf(.Height = 120, Application.Height, 120)
    End With
End Sub

 

[job75]

Bonsoir patricktoulon,

Je préfère cette amélioration qui mémorise les dernières position et dimensions, fichier (2) :

Sub Image()
Dim test As Boolean, im As Shape
With ActiveSheet.DrawingObjects("Bouton")
    test = .Text = "Grande"
    .Text = IIf(test, "Petite", "Grande")
End With
Set im = ActiveSheet.Shapes("Mon_Image")
If test Then
    With ThisWorkbook.Names
        .Add "X", im.Left 'mémorise la dernière position
        .Add "Y", im.Top
        .Add "W", im.Width 'mémorise les dernières dimensions
        .Add "H", im.Height
    End With
End If
Application.DisplayFullScreen = test
With im
    .Left = IIf(test, 0, [X])
    .Top = IIf(test, 0, [Y])
    .Width = IIf(test, Application.Width, [W])
    .Height = IIf(test, Application.Height, [H])
End With
End Sub

A+

 

[patricktoulon]

bonjour a tous
@job75
je préfère de loin celle ci qui mémorise les dimension réelles reste plus qu'a en faire une fonction utilisable pour x image

 

[Magic_Doctor]

Bonsoir,

Désolé de ne pas avoir pu vous répondre plus tôt.

Merci job & patricktoulon de m'avoir résolu ce problème. Ça marche maintenant très bien !

 

[nigoexcel]

Bonjour

Je recherche la même chose. Par contre j'ai plusieurs photos. il existe une possibilité de macro sans en créer à chaque fois ? Merci

 

[job75]

Bonjour nigoexcel, bienvenue sur XLD,

Créez votre propre discussion.

Celle-ci vise à agrandir une image, cela n'aurait pas de sens d'en agrandir 2 ou plus.

A+

 

[patricktoulon]

re
bonjour

ben comme je l'ai dit il faut la transformer en fonction comune argumentée et s'en servir dans une sub bouclant sur tes image

 

[nigoexcel]

re
bonjour

ben comme je l'ai dit il faut la transformer en fonction comune argumentée et s'en servir dans une sub bouclant sur tes image

ok donc il faut créer à chaque fois une macro

 

[nigoexcel]

Bonjour nigoexcel, bienvenue sur XLD,

Créez votre propre discussion.

Celle-ci vise à agrandir une image, cela n'aurait pas de sens d'en agrandir 2 ou plus.

A+

trop sympa la réponse !!! mais bon il faut lire tous les échanges !!!

 

[patricktoulon]

non
ouvre ta propre discussion et dans l'apres midi je te montrerais
là je part en exterieur