Recherchev

[karimal]

Bonjour à tous,
Jé vous explique: Je prepare un tableau pour le travail d'inventaire, j'ai d'un coté la liste complete des articles et d'un autre, la liste des articles existants avec deux categories de prix.
je voudrais "copier" ces prix dans la liste complete et là où il n'y a pas de prix on aura 0 ou rien. J'ai pensé à la formule Recherchev mais je sais pas trop comment l'utiliser. je vous ai joint un echantillon de ma liste.
Merci d'avance!!!!!!!!!!!!!!!!!!!!!!!!!
Karimal

 

[Brigitte]

Re : Recherchev

Bonjour,

Ci-joint... avec estna... pour afficher "rien" lorsque le résultat n'est pas trouvé.

Si tu voulais 0, il faut taper 0 à la place de "".

=SI(ESTNA(INDEX($F$2:$F$86;EQUIV(A2;$E$2:$E$86;0)));"";INDEX($F$2:$F$86;EQUIV(A2;$E$2:$E$86;0)))
=SI(ESTNA(INDEX($F$2:$F$86;EQUIV(A2;$E$2:$E$86;0)));0;INDEX($F$2:$F$86;EQUIV(A2;$E$2:$E$86;0)))

Suggestion : nommer tes plages en A, F et G.

 

[abcd]

Re : Recherchev

Bonjour,

B2 : =SI(NB.SI($E:$E;$A2)=0;0;RECHERCHEV($A2;$E:F;COLONNE();0))
à copier vers la droite et vers le bas.

abcd

 

[Brigitte]

Re : Recherchev

Bonjour,

C'est trop fort abcd...

Pourrais tu m'expliquer en revanche... si je veux mettre tes formules dans le tableau mais en colonnes à droite du tableau (i et j), ca ne marche pas, pourtant j'ai changé le nom de la colonne dans ta formule...

Et aussi comment la formule trouve le résultat juste avec colonne() sans que le numéro soit noté ?

Merci à toi.

 

[karimal]

Re : Recherchev

Merci Brigitte je viens d'essayer ta formule, mais je vais qd meme essayer celle de abcd pour voir comment il a utilisé recherchev
Merci les amis!!

 

[karimal]

Re : Recherchev

Super! merci

 

[abcd]

Re : Recherchev

Bonjour Brigitte,

En colonne B la formule doit renvoyer la valeur de la deuxième colonne de la plage $E:F.
La colonne B vaut 2, il faut donc écrire COLONNE().
En étirant vers la droite (colonne C) la formule doit renvoyer la valeur de la troisième colonne de la plage $E:G, et comme la colonne C vaut 3 ...

La colonne I vaut 9.
Pour obtenir 2 il faut écrire COLONNE()-7
En I2 : =SI(NB.SI($E:$E;$A2)=0;0;RECHERCHEV($A2;$E:F;COLONNE()-7;0))

J'espère m'être fait comprendre.

abcd

 

[abcd]

Re : Recherchev

Re Brigitte,

Tu peux également remplacer COLONNE() par COLONNES($1:2) qui renvoie également 2
Cette fonction s'incrémente en l'étirant vers la droite : COLONNES($1:3)

La formule devient donc :
=SI(NB.SI($E:$E;$A2)=0;0;RECHERCHEV($A2;$E:F;COLONNES($1:2);0))
et peut être placée dans n'importe quelle colonne sans devoir l'adapter.

abcd

 

[Brigitte]

Re : Recherchev

Bonsoir,

J'étais en big réunion... Merci abcd, c'est énorme tes formules, chaque fois. Je suis zébaubie... Pas sûr que j'arrive à replacer cela, mais c'est tellement beau de voir des formules simplifiées. Je vais décortiquer à nouveau.

Merci mille fois de ce que tu nous apportes. Je ne sais comment tu fais, mais en tout cas, c'est vraiment riche d'enseignement.

Bonne soirée.