Recherchev par le bas

[naknak]

Bonjour,

Ma question concerne un sujet déjà traité dans différents forums mais je n'arrive pas à adapter les solutions à mon cas.
Je suis en stage et dans le cadre de mes missions je dois réaliser un tableau me permettant de piloter le nombre de kms parcourus par le parc automobile.
Pour cela, j'ai une base constituée par des immatriculations de véhicules et l'index kilométrique correspondant. Ainsi, à chaque nouvelle saisie, je voudrais faire une recherchev par le bas de façon à obtenir l'avant dernier index kilométrique correspondant à l'immatriculation.
En faisant le nouvel index kilométrique - l'ancien index, je voudrais obtenir le nombre de kilomètres parcourus.
Lorsque je fais une recherchev "de base", excel prend en compte la première valeur (E2) correspondante en partant du haut du tableau.
Je mets en PJ un petit exemple excel.
Je voudrais calculer en F8 le nombre de kms parcourus par le véhicule en fonction de l'index kilométrique saisie en E5 et non en E2.

Je vous remercie d'avance pour votre aide.

Cordialement

 

[R@chid]

Re : Recherchev par le bas

Bonsoir @ tous,
Bienvenue sur XLD,
J'ai pas bien compris, en F2,

=MAX(SI(A$2:A$8=A2;E$2:E$8))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

[Victor21]

Re : Recherchev par le bas

Bonsoir, naknak, bonsoir, R@chid

Pas compris la même chose. Je propose en F2, à recopier vers le bas :

=SI(NB.SI(A$1:A1;A2)>0;E2-MAX(SI(A1:A$2=A2;E1:E$2));"Premier index")

Formule matricielle
à valider par Ctrl+Maj+Entrée

 

[Modeste]

Re : Recherchev par le bas

Bonsoir naknak et bienvenue à toi,
Salut Rachid , Patrick

J'ai compris encore autre chose: en F8

=INDEX($E$1:$E$8;PETITE.VALEUR(SI($A$2:$A$8=A8;LIGNE($A$2:$A$8));NB.SI($A$2:$A$8;A8)-1))

Formule matricielle également ... voir les commentaires des amis, pour la validation

Là-dessus, je m'en vais tailler le bout de gras avec un autre ami: Morphée

 

[mapomme]

Re : Recherchev par le bas

Bonsoir naknak, R@chid, Victor21, Modeste,

Bienvenue sur XLS ,

Uniquement pour le fun, une formule matricielle (à valider par Ctrl+Maj+Entrée) qui devrait fonctionner même si les index kilométriques pour un même véhicule sont saisis dans le désordre (pas forcément en ordre croissant)

Ne disposant que d'Excel 2003, la formule "2007 et plus" n'est pas vérifiée et a été mis dans le fichier "à l'aveugle"
Formule matricielle 2003:

=SI(ESTERREUR(SOMME(GRANDE.VALEUR(SI($A$2:$A$9999=A2;SI($E$2:$E$9999<=E2;$E$2:$E$9999));{1;2})*{1;-1}));"init";SOMME(GRANDE.VALEUR(SI($A$2:$A$9999=A2;SI($E$2:$E$9999<=E2;$E$2:$E$9999));{1;2})*{1;-1}))

Formule matricielle 2007+:

=SIERREUR(SOMME(GRANDE.VALEUR(SI($A$2:$A$9999=A2;SI($E$2:$E$9999<=E2;$E$2:$E$9999));{1;2})*{1;-1});"init")