Recherche du nom et extraire sa valeur

[SSI83000]

bonjour à tous j’espère que le forum se porte bien

j'ai un petit problème j'ai essayer de créer une macro comme un grand mais je suis confronté à un petit probleme

je recherche donc une macro qui puisse recherche les nom en feuille 2 et rapatrier ce dernier dans la colonne valeur de la feuille 1 et cela si possible avec une macro


j'ai essayer sa

Sub Valeur()
With Sheets("Avril")
'For a = 4 To 100
For x = 3 To 100
If .Cells(x, 34) = Sheets("Garde").Cells(x, 14) Then Sheets("Garde").Cells(x, 24) = .Cells(x, 33)
'If .Cells(a, X) = "For" And .Cells(a, 33) = "Matin" Then Sheets("For").Cells(a, X) = .Cells(a, X)
Next
'Next
End With
End Sub

merci d'avance de votre aide

 

[mutzik]

Re : Recherche du nom et extraire sa valeur

bonjour,

et pourquoi pas une simple formule:
en B2 de la feuil 1
=RECHERCHEV(A2;Feuil2!$B$3:$C$15;2;FAUX)
et tirer vers le bas

 

[jp14]

Re : Recherche du nom et extraire sa valeur

Bonjour

Ci dessous une recherche par macro

Option Explicit
Sub travdem()
Dim Cellule1 As Range, Plg1 As Range
Dim Nomfeuille1 As String, Col1 As String
Dim Nomfeuille2 As String, Col2 As String
Dim MonTab As Variant, Compt1 As Long
'parametre
Nomfeuille1 = "Feuil1"
Col1 = "a"
Nomfeuille2 = "Feuil2"
Col2 = "B"

'code
With Sheets("Feuil2")
Set Plg1 = .Range(Col2 & "2:C" & .Range(Col2 & .Rows.Count).End(xlUp).Row)
MonTab = Plg1.Value
End With

With Sheets("Feuil1")
For Each Cellule1 In .Range(Col1 & "2:" & Col1 & .Range(Col1 & .Rows.Count).End(xlUp).Row)
    For Compt1 = LBound(MonTab, 1) To UBound(MonTab, 1)
        If MonTab(Compt1, 1) = Cellule1 Then
            If MonTab(Compt1, 2) <> "" Then
                Cellule1.Offset(0, 1) = MonTab(Compt1, 2)
            End If
            Exit For
        End If
    Next Compt1
Next Cellule1

End With
End Sub

A tester et à modifier

Bonne journée

JP

 

[SSI83000]

Re : Recherche du nom et extraire sa valeur

Bonjour mutzik bonjour jp14

merci à vous pour votre aide

Jp14 ta solution est parfaite j'ai pût l'adapter comme je voulait à mon projet et sa marche c'est genial
mutzik je souhaitait pas une formule car on ne peu pas modifier le nom de la page comme on veut car j'ai plusieurs BDD différent et suivant la date présent dans une cellule la formule toi s'adapter merci tout de même pour ton idée.

bonne journée à vous