Rassembler les parties de mots dans une cellule unique

[EXCELIOR]

Bonsoir les experts,

Je me prends la tête depuis peu à vouloir réunir en une seule cellule (avec les fonctions concatener, gauche, droite), les infos issus de plusieurs autres cellules (même feuille) mais sans succes. Alors je viens à vous.

VOICI:
En A1 : j'ai le mot Homme (et parfois Femme)
En A2 : j'ai une date au format 08/10/1986
En A3 : j'ai encore une date (même format (ex: 01/09/2010)
en A4 : j'ai un prénom (ex: Nana)

j'aimerai obtenir (et là c'est le souci) en A5 un résultat de ce type : H86-J0109*NA

Et en plus des -* et un J supplémentaire, vous remarquerez que le tous est en Majuscule.

Pour moi c'est assez chaud, un coup de main s'il vous plaît !

 

[JHA]

Re : Rassembler les parties de mots dans une cellule unique

Bonsoir à tous,

A essayer en "A5"

=MAJUSCULE(GAUCHE(A1;1))&DROITE(TEXTE(ANNEE(A2);0);2)&" - J"&TEXTE(JOUR(A3);"00")&TEXTE(MOIS(A3);"00")&"*"&MAJUSCULE(GAUCHE(A4;2))

JHA

 

[JCGL]

Re : Rassembler les parties de mots dans une cellule unique

Bonjour à tous,

Peux-tu essayer :

=GAUCHE(A1;1)&DROITE(ANNEE(A2);2)&"-J"&TEXTE(A3;"jjmm")&"-"&GAUCHE(A4;2)

A+ à tous

Edition : Salut JHA

 

[chris]

Re : Rassembler les parties de mots dans une cellule unique

Bonjour
Coucou JHA, JCGL

=MAJUSCULE(GAUCHE(A1;1)&TEXTE(A2;"aa")&"-J"&TEXTE(A3;"jjmm")&"*"&GAUCHE(A4;2))

 

[Regueiro]

Re : Rassembler les parties de mots dans une cellule unique

Bonsoir à Tous
Ma petite contribution

=MAJUSCULE(CONCATENER(GAUCHE(A1;1);DROITE(TEXTE(A2;"aa");2);"-J";GAUCHE(TEXTE(A3;"jjmm");5);"*"&(GAUCHE(A4;2))))

ou

=MAJUSCULE(GAUCHE(A1;1)&DROITE(TEXTE(A2;"aa");2)&"-J"&GAUCHE(TEXTE(A3;"jjmm");5)&"*"&(GAUCHE(A4;2)))

A+

 

[EXCELIOR]

Re : Rassembler les parties de mots dans une cellule unique

Merci à vous tous pour votre aide,

à JCGL: ton code ( =GAUCHE(A1;1)&DROITE(ANNEE(A2);2)&"-J"&TEXTE(A3;"jjmm")&"-"&GAUCHE(A4;2) ) ne permet pas le majuscule.

 

[JCGL]

Re : Rassembler les parties de mots dans une cellule unique

Bonjour à tous,
Salut Chris,

Alors essaye :

=MAJUSCULE(GAUCHE(A1;1)&DROITE(ANNEE(A2);2)&"-J"&TEXTE(A3;"jjmm")&"-"&GAUCHE(A4;2))

A+ à tous

 

[Modeste geedee]

Re : Rassembler les parties de mots dans une cellule unique

Bonsour® à tous


Récap

 

[Regueiro]

Re : Rassembler les parties de mots dans une cellule unique

Bonsoir à Tous
Modeste une petite question.
Quelle fonction utilisez-vous pour compter le nombre de caractère dans la Formule.
FormuleAffiche() et ensuite Nbrcar() ??

Merci pour votre réponse.
A.

 

[Modeste geedee]

Re : Rassembler les parties de mots dans une cellule unique

Bonsour®

Bonsoir à Tous
Modeste une petite question.
Quelle fonction utilisez-vous pour compter le nombre de caractère dans la Formule.
FormuleAffiche() et ensuite Nbrcar() ??

Merci pour votre réponse.
A.

il s'agit d'une fonction personnalisée :

Function FormuleAffiche(target)
FormuleAffiche="'"&Target.formulaLocal
End function

concernant le nombre de caractères
Fonction standard
NBCAR(ref)

 

[Regueiro]

Re : Rassembler les parties de mots dans une cellule unique

Bonsoir à Tous
Merci Modeste
j'ai trouver sur mon nouvel Excel 2013 une fonction similaire :
=FORMULERTEXTE
et je fais le tout dans une cellule : =NBCAR(FORMULETEXTE(E4))

?? Comment peux-t'on trouver le code qu'il y a derrière ces nouvelles fonctions ?
Bonne soirée
a+

 

[JCGL]

Re : Rassembler les parties de mots dans une cellule unique

Bonjour à tous,

C'est une fonction native d'XL 2013.

A+ à tous