Questionnaire Excel qui permet de rédiger un fichier Word

[BurgerZoZ]

Bonjour à tous,
Je dois mener un projet professionnel qui me pose beaucoup de problèmes et d'interrogations !
Voici en quoi consiste ce projet :
Le projet consiste en la création d’un document Word qui est la synthèse de plusieurs documents Word d’une page.
Ce document Word final sera établi au moyen d’un questionnaire Excel :

Exemple :

Êtes-vous dans le cas 1 : oui/non
Êtes-vous dans le cas 2 : oui/non
Êtes-vous dans le cas 3 : oui/non
Êtes-vous dans le cas 4 : oui/non
Etc…

Le cas 1, 2, 3 etc… sont des fichiers Word simples déjà établis. (Des fiches en quelque sorte).

A la fin du questionnaire, l’utilisateur doit obtenir un document Word dans lequel les fichiers Word simples (cas 1, cas 4 par exemple) sont insérés les uns après les autres.

Au final, je dois me retrouver avec un questionnaire Excel, une base de données de plusieurs fichiers Word, un dossier dans lequel vont s’enregistrer mes documents Word finaux.

Voila grosso modo ma problématique.
Je ne suis absolument pas un spécialiste du Excel.
Pour le moment je souhaite savoir si cela est réalisable et si des projets sur la même thématique ont été réalisés !

Merci !

 

[job75]

Re : Questionnaire Excel qui permet de rédiger un fichier Word

Bonjour BurgerZoZ, bienvenue sur XLD,

Voyez les fichiers joints avec cette macro dans le fichier Excel (Alt+F11) :

Sub RecapWord()
'---cocher la référence Microsoft Word xx.x Object Library---
Dim Appli As Word.Application, recap As Word.Document
Dim c As Range, cas As Word.Document, txt As String
On Error Resume Next
Set Appli = GetObject(, "Word.Application")
Set recap = Appli.Documents("Recap.doc")
If recap Is Nothing Then MsgBox "Ouvrez 'Recap.doc' !": Exit Sub
recap.Range(0, recap.Characters.Count).Delete 'RAZ
For Each c In Range("C3", [C65536].End(xlUp)) 'plage à adapter
  Set cas = Nothing
  If c <> "" And c(1, 2) = "Oui" Then
    Set cas = Appli.Documents(c & ".doc")
    If cas Is Nothing Then MsgBox "Ouvrez '" & c & ".doc' !": Exit Sub
    txt = txt & cas.Range(0, cas.Characters.Count) & vbLf & vbLf
  End If
Next
recap.Range(0, 0).Text = txt
End Sub

Il faut que les documents Word définis par les listes de validation soient ouverts.

A+

 

[job75]

Re : Questionnaire Excel qui permet de rédiger un fichier Word

Re,

Dans cette version (2) le code est dans une macro Worksheet_Change :

Private Sub Worksheet_Change(ByVal Target As Range)
'---cocher la référence Microsoft Word xx.x Object Library---
Dim r As Range, Appli As Word.Application, recap As Word.Document
Dim flag1 As Boolean, flag2 As Boolean, cas As Word.Document, txt$
Set r = Range("C3:D" & [C65536].End(xlUp).Row) 'plage à adapter
If Intersect(Target, r) Is Nothing Then Exit Sub
On Error Resume Next
Set Appli = GetObject(, "Word.Application")
Set recap = Appli.Documents("Recap.doc")
If recap Is Nothing Then MsgBox "Ouvrez 'Recap.doc' !": flag1 = True
recap.Range(0, recap.Characters.Count).Delete 'RAZ
For Each r In r.Columns(1).Cells
  flag2 = False
  Set cas = Nothing
  If r <> "" And r(1, 2) = "Oui" Then
    Set cas = Appli.Documents(r & ".doc")
    If cas Is Nothing Then MsgBox "Ouvrez '" & r & ".doc' !": flag2 = True
    txt = txt & cas.Range(0, cas.Characters.Count) & vbLf & vbLf
  End If
  If flag1 Or flag2 Then
    Application.EnableEvents = False
    r(1, 2) = ""
    Application.EnableEvents = True
  End If
Next
recap.Range(0, 0).Text = txt
End Sub

A+

 

[BurgerZoZ]

Re : Questionnaire Excel qui permet de rédiger un fichier Word

Bonjour, merci beaucoup pour ces précieuses info mais la macro me met un bug sur : Appli As Word.Application

 

[job75]

Re : Questionnaire Excel qui permet de rédiger un fichier Word

Re,

Il faut lire tout ce que j'écris :

'---cocher la référence Microsoft Word xx.x Object Library---

Dans VBA (Alt+F11) menu Outils => Références et cherchez puis cochez la référence indiquée.

Décochez aussi les références indiquées MANQUANTES.

A+

 

[chris]

Re : Questionnaire Excel qui permet de rédiger un fichier Word

Bonjour
Coucou Job75

Cet exemple sans macros pourrait t'inspirer https://www.excel-downloads.com/thr...-dun-choix-de-plusieurs-fichiers-word.178205/