Problème input box

[boulettedu84]

Bonjours,
J'ai un petit problème avec une inputbox;
Je dois ouvrir un modèle existant pour en faire une copie et renommer la copie.

je parvient a le faire, cependant lorsque je donne un nom déja existant il se met en défaut.

voici le code que j'utilise:

Sub Rectangle6_Clic()

Nom = InputBox("Nom du client :")
If Nom = "" Then Exit Sub
Sheets("Bon d'intervention").Copy after:=Sheets(Sheets.Count)
ActiveSheet.Name = Nom


End Sub



Merci d'avance pour vos réponses

 

[Pierrot93]

Re : Problème input box

Bonjour,

il y a sans doute lieu de vérifier si la feuille existe déjà, regarde ceci si cela peut t'aider :

Option Explicit
Sub test()
Dim nom As String
nom = InputBox("Nom du client :")
If nom = "" Then Exit Sub
If Not FeuilleExiste(nom) Is Nothing Then Exit Sub
Sheets("Bon d'intervention").Copy after:=Sheets(Sheets.Count)
ActiveSheet.Name = nom
End Sub
Function FeuilleExiste(f As String) As Worksheet
On Error Resume Next
Set FeuilleExiste = Worksheets(f)
End Function

bonne journée
@+

 

[Pierrot93]

Re : Problème input box

Re,

on pourrait également le coder ainsi :

Option Explicit
Sub test()
Dim nom As String

Do
    nom = InputBox("Nom du client :")
Loop While nom = "" Or Not FeuilleExiste(nom) Is Nothing

Sheets("Bon d'intervention").Copy after:=Sheets(Sheets.Count)
ActiveSheet.Name = nom
End Sub
Function FeuilleExiste(f As String) As Worksheet
On Error Resume Next
Set FeuilleExiste = Worksheets(f)
End Function

A voir comment tu vois la chose....

 

[boulettedu84]

Re : Problème input box

erf,
merci d'avoir répondu si rapidement, mais je ne parvient pas à faire fonctionner votre code:s

voici un petit test qui pourra vous faire comprendre ce que je veux faire.

 

[Pierrot93]

Re : Problème input box

Re,

ton fichier en retour :

 

[boulettedu84]

Re : Problème input box

Cela marche parfaitement merci beaucoup !

 

[boulettedu84]

Re : Problème input box

Désolé mais je me demandais s'il était possible d'apporter un petit plus:
Serait il possible que lorsqu'on appui sur annuler ou sur la croix cela ferme la boîte de dialogue ?

 

[Pierrot93]

Re : Problème input box

Re,

modifie comme suit :

Sub Rectangle1_Clic()
Dim nom As String
Do
    nom = Application.InputBox("Nom du client :", , nom)
    If nom = "Faux" Then Exit Sub
Loop While nom = "" Or Not FeuilleExiste(nom) Is Nothing
Sheets("Bon d'intervention").Copy after:=Sheets(Sheets.Count)
ActiveSheet.Name = nom
End Sub
Function FeuilleExiste(f As String) As Worksheet
On Error Resume Next
Set FeuilleExiste = Worksheets(f)
End Function

bon après midi
@+