Problème de condition dans SommeProd

[Sofhy]

Bonjour à tous,

J'ai un problème dans deux formules SommeProd.

Je suis repartie des formules proposées dans les fils que j'avais ouvert ici, car mon problème actuel c'est assez semblable (j'ai un peu l'impression de poser la même la question ) : https://www.excel-downloads.com/threads/min-sur-une-plage-en-fonction-dun-critere.147351/ et https://www.excel-downloads.com/threads/nb-si-sur-deux-conditions.146560/

J'ai tenté de repartir des différentes formules en ajoutant ma condition mais ça ne fonctionne pas. Je dois avouer que je me suis bananée en essayant d'adapter les formule de Hasco et Tototiti avec "décaler" et je suis partie sur la fonction "sommeprod".

Help ...

Je vous joins mon fichier avec ma formule actuelle et mes explications,
Merci par avance,
Sofhy

 

[hbenalia]

Re : Problème de condition dans SommeProd

Bonjour le forum,


Une petite correction de la deuxième formule:

=SI(SOMMEPROD(($B$2:$K$2="Bleu")*($B3:$K3>=100%)*($A$3:$A$9=A3))=1;"Oui";"Non")

ou

=SI(SOMMEPROD(($B$2:$K$2="Bleu")*($B3:$K3>=100%)*($A$3:$A$9=A3));"Oui";"Non")

Et je ne vois pas l'intérêt de *($A$3:$A$9=A3) dans cette formule (ou même dans l'autre formule)


Cordialement

 

[Sofhy]

Re : Problème de condition dans SommeProd

Bonjour hbenalia,

[QUOTE/]=Et je ne vois pas l'intérêt de *($A$3:$A$9=A3) dans cette formule (ou même dans l'autre formule)[/QUOTE]

Maintenant que tu le dis, il n'y en a aucun, effectivement.
Merci.

 

[hbenalia]

Re : Problème de condition dans SommeProd

Bonjour à tous,

Je n'ai pas vu le problème dans la première formule que je corrige avec la formule suivante (un peu lourde):

=SI(MIN($B3:$K3)=K3;SI(SOMMEPROD(($B$2:$K$2<>"Bleu")*(PETITE.VALEUR($B3:$K3;2)>=80%));"Oui";"Non");SI(SOMMEPROD(($B$2:$K$2<>"Bleu")*(MIN($B3:$K3)>=80%));"Oui";"Non"))

Je n'ai pas trouvé mieux pour le moment...

Voir corrections des deux formules dans la pièce jointe...

Cordialement

 

[hbenalia]

Re : Problème de condition dans SommeProd

Bonjour,

Si la colonne "Bleu" est la dernière colonne du tableau (comme dans l'exemple) les formules seraient beaucoup plus simples:
Formule1 :

=SI(MIN($B3:$J3)>=80%;"Oui";"Non")

Formule2 :

=SI($K3>=100%;"Oui";"Non")

Cordialement

 

[Tibo]

Re : Problème de condition dans SommeProd

Bonjour,

Un essai pour la première formule avec une fonction matricielle en L3 :

=SI(MIN(SI($B$2:$K$2<>"Bleu";$B3:$K3))<80%;"Non";"Oui")

Matricielle à valider par CTRL + MAJ + ENTREE

A tester quand même

@+

 

[armitage92]

Re : Problème de condition dans SommeProd

Bonjour Sofhy, bonjour le fil

pour la premiere formule :

=SI(SOMMEPROD(($B$2:$K$2<>"Bleu")*(B3:K3<80%))>=1;"Non";"Oui")

Il faut la lire comme tel : si il y a une couleur autre que bleu a moins de 80%, alors le sommeprod aura une valeur, a ce moment la, mettre "Non", sinon mettre "Oui"

pour la deuxième formule :

=SI(SOMMEPROD(($B$2:$K$2="Bleu")*(B3:K3>=100%))=1;"Oui";"Non")

Il faut la lire comme tel : si il y a une couleur égal a bleu a au moins 100%, alors le sommeprod aura une valeur, a ce moment la, mettre "Oui", sinon mettre "Non"

 

[hbenalia]

Re : Problème de condition dans SommeProd

Bonjour le forum, bonjourTibo

Bonjour,

Un essai pour la première formule avec une fonction matricielle en L3 :

=SI(MIN(SI($B$2:$K$2<>"Bleu";$B3:$K3))<80%;"Non";"Oui")

Matricielle à valider par CTRL + MAJ + ENTREE

A tester quand même

@+

Merci Tibo pour cette formule très très simple... Et donc la deuxième formule serait de même (changements minimes) en N3:

=SI(MIN(SI($B$2:$K$2="Bleu";$B3:$K3))<100%;"Non";"Oui")

(formule matricielle)

Cordialement

 

[Sofhy]

Re : Problème de condition dans SommeProd

Bonjour Tibo et Armitage92,
Re Hbenalia,

J'ai testé toutes vos formules, c'est génial !
Avec en plus différentes manière de faire.

Un grand Merci ,
Bonne journée à tous,
Sophie