XL 2016 Position d'un onglet au début da ma barre onglets

[Claudy]

Bonjour,
un classeur avec plus de 40 onglets...de mai17 à décembre21!
Via un lien, je vais directement vers n'importe quel onglet( Merci Stapple)
Je reviens vers mon onglet du mois actuel via cette macro:

Sub Aller_Vers_Mois_cejour()
Sheets((Format(Date, "mmmmyy"))).Select
Range("G150").End(xlUp)(2).Select

End Sub

Seulement mon onglet sélectionné ainsi se situe n'importe où:

ici en 4° position. Mais il pourrait se trouver en 15° position.
Comment faire pour qu'il se retrouve en 1° position comme ci dessous:

Juste après les flèches < >

Histoire de ne plus cliquer sur les flèches pour défiler.

Merci d'avance,

Claudy

 

[sylvanu]

Bonjour Claudy,
A la fin toutes les feuilles seront mélangées.
Pourquoi ne pas toutes les masquer sauf celle qui vous intéresse :

Sub Aller_Vers_Mois_cejour()
Dim Nom$: Nom = Format(Date, "mmmmyy")
Sheets(Nom).Visible = True
Sheets(Nom).Select
Range("G150").End(xlUp)(2).Select
For Each Feuille In Worksheets
    If Feuille.Name <> Nom Then
        Feuille.Visible = False
    End If
Next Feuille
End Sub

Les autres feuilles sont toujours accessibles par Onglets/Afficher.

 

[Claudy]

Bonjour,
Merci mais je ne dois pas les masquer...
Claudy

 

[sylvanu]

ou si vous y tenez :

Sub Aller_Vers_Mois_cejour()
    Sheets((Format(Date, "mmmmyy"))).Select
    Range("G150").End(xlUp)(2).Select
    Sheets(Format(Date, "mmmmyy")).Move before:=Sheets(1)
End Sub

 

[Claudy]

mais alors comme tu disais , elle vont être mélangées

Merci quand même,

Claudy

 

[sylvanu]

Avec le code du post #4 elle sera en première position, ce que vous demandiez au post #1.

 

[Claudy]

Ok,
mais j'aimerais garder aussi l'ordre chronologique
Logique non?

 

[sylvanu]

Logique non?

Non.
Si on est en Février, et qu'on le met au début, on a Février - Janvier - Mars.
"ordre chronologique" et mois courant en premier, c'est antinomique.

 

[Claudy]

Bin justement, je veux garder janvier février mars avril dans l'ordre chronologique,
mais dans mon cas janvier est en dessous des flèches, février et les autres affichés

Février est le premier visible après les flèches.
Janvier n'est pas caché

 

[sylvanu]

Les lignes pour décaler les onglets sont :

ActiveWindow.ScrollWorkbookTabs Position:=xlFirst ' Premier onglet en 1ere position'
ActiveWindow.ScrollWorkbookTabs Sheets:=1         ' Décalage à gauche'
ActiveWindow.ScrollWorkbookTabs Sheets:=-1        ' Décalage à droite'

Par contre je ne sais pas comment géré cela pour que la feuille désirée soit en première position visible.
Il y aura surement un esprit plus avisé qui va passer par là.

 

[Claudy]

Ok merci,
j'avais trouvé ça aussi avec l'enregistreur de macro...mais ce n'est pas ce que je voulais.

Il y aura surement un esprit plus avisé qui va passer par là.

Espérons
Claudy

 

[Usine à gaz]

Bonjour Claudy, Sylvanu, le Forum,

J'ai trouvé des codes qui semblent intéressants mais je n'ai pas de temps pour chercher à les adapter :

VBA: Trier les feuilles de Classeur EXCEL par ordre alphabétique

Code VBA pour trier les Feuilles d'un Classeur Excel par ordre alphabétique. Explications, VBA code prêt à l'emploi et exemples d'utilisation.

excel-malin.com

lionel

 

[Staple1600]

Bonsoir le fil

=>Claudy
J'ai pas eu de retour de ta part sur ma proposition dans ce fil que tu as initié mardi.

XL 2016 - Transformer une colonne en lien vers d'autres feuilles

Bonjour, j'ai une colonne(B2:B61) qui reprend les noms des feuilles reprises dans le même classeur. Comment transformer ces noms en lien qui me renvoie directement en cliquant dessus vers la feuille sélectionnée? Pour info, le classeur va de janvier 2017 à décembre 2021....au format...

www.excel-downloads.com

 

[patricktoulon]

bonsoir
tu a interet a ce que les mois en toute lettre ou même en abrégé soit bien orthographiés

Sub test2()
    ReDim t2(1 To Sheets.Count)
     For Each f In Worksheets
        i = i + 1
        fn = f.Name
        t2(i) = CLng(DateValue("1/" & Left(fn, Len(fn) - 2) & "/" & Right(fn, 2)))
    Next
    For i = Sheets.Count To 1 Step -1
        MsgBox Format(CDate(WorksheetFunction.Large(t2, i)), "mmmmyy")
    Next
End Sub

 

[mapomme]

Bonjour à tous ,

Une macro qui devrait faire ce que tu souhaites @Claudy . Pour la lancer, taper la combinaison de touches Ctrl+Maj+o.

La macro :

• ne change pas l'ordre des feuilles
• on saisit le mois et l'année en chiffre séparés par un caractère qui n'est pas un chiffre (on peut donc tout faire avec le pavé numérique et l’orthographe de la saisie importe peu)
• Il ne se passe rien si la saisie ne correspond à aucune feuille

nota : bien évidemment, quand on veut sélectionner un onglet situé vers la fin à droite, il se peut que l'onglet ne soit pas positionné en 1ère position à gauche puisqu' Excel est capable d'afficher de manière visible l'onglet désiré et tous les onglets à sa droite.

Le code:

Sub OngletEnPos1()
Dim MoisAn$, mois$, an$, c$, deb&, onglet$, Lindex&

   MoisAn = Trim(InputBox("Indiquez le mois et l'année en chiffres séparés par ""non chiffre"" ?:" _
      & vbLf & vbLf & "Exemple: 8 20 ou 08 2020 ou 8.20 pou 8,20 ou 8/20 pour août 2020", vbQuestion))

   For deb = 1 To Len(MoisAn)    'extraction du mois
      c = Mid(MoisAn, deb, 1)
      If c >= "0" And c <= "9" Then mois = mois & c Else Exit For
   Next deb

   For deb = Len(MoisAn) To 1 Step -1     'extraction année
      c = Mid(MoisAn, deb, 1)
      If c >= "0" And c <= "9" Then an = c & an Else Exit For
   Next deb

   onglet = Format("28" & "/" & mois & "/" & an, "mmmyy") 'nom de l'onget sous la forme MMMAA
   On Error Resume Next: Lindex = Sheets(onglet).Index: On Error GoTo 0    'index de l'onglet
   'si index inexistant donc onglet inexistant, on ne fait rien
   If Lindex = 0 Then MsgBox "La feuille '" & MoisAn & "' est inexistante!", vbCritical: Exit Sub

   Application.ScreenUpdating = False
   ActiveWindow.ScrollWorkbookTabs -Sheets.Count      'on affiche la 1ère feuille tout à droite
   ActiveWindow.ScrollWorkbookTabs Lindex             'on déplace les onglets vers la droite de ce qu'il faut
   Application.Goto Sheets(Lindex).Range("a1"), True  'on sélectionne A1 de la feuille désirée
End Sub

edit: v1a