Pb avec notification d'utilisateur

[stk]

Bonjour à tous,

Je soouhaiterais savoir s'il y a une possibilité quand un classeur excel est ouvert sur un réseau de pouvoir le déconnecter de ce classeur pour l'ouvrir soi-même en pleins droits ?

Merci à l'avance pour vos réponses.

 

[STephane]

Re : Pb avec notification d'utilisateur

bonjour,
je ne sais pas mais par contre tu peux envisager une macro qui ferme le classeur après un certain temps d'utilisation.


ci-dessous un exemple en anglais

In the ThisWorkbook module of the workbook, paste the following code:

Private Sub Workbook_Open()
'Set StartTime when the workbook is opened.
    StartTime = Timer
'Schedule a call to CheckTime in the future to check elapsed idle time.
    Application.OnTime (Now + TimeValue(TimeCheckDelay)), "CheckTime"
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
'Something changed in the workbook, so reset StartTime.
    StartTime = Timer
End Sub

In A VBA code module in the same workbook, paste this code:

Global StartTime As Single

Global Const TimeLimitInMinutes = 58   'idle time threshold
Global Const TimeCheckDelay = "00:10:00"

Sub CheckTime()
    Dim NewTime As Single
'Get the time (seconds past midnight) now.
    NewTime = Timer
'If StartTime was yesterday, add 86400 seconds to NewTime.
    If NewTime < StartTime Then
        NewTime = NewTime + 86400
    End If
'If TimeLimitInMinutes has expired since StartTime was last
'updated, close the workbook without saving changes.
    If (NewTime - StartTime) > (TimeLimitInMinutes * 60) Then
        ThisWorkbook.Saved = True
        ThisWorkbook.Close SaveChanges:=False
    Else
'Otherwise, schedule a call to CheckTime in the future to check
'again later.
        Application.OnTime (Now + TimeValue(TimeCheckDelay)), "CheckTime"
    End If
End Sub

 

[jeanpierre]

Re : Pb avec notification d'utilisateur

Bonjour stk, Stephane,

Outre la solution de Stephane que je ne puis tester (plus de réseau maintenant), quid de l'utilisateur en cours ?

Il faudrait savoir le but de ce fichier car si, avec tes pleins droits, tu stopes un travail en cours, je vois mal l'affaire.

Pourquoi ne pas créer un log que tu pourras compulser et avertir le dernier utilisateur que tu as besoin du fichier, cela lui permettra de stoper, d'enregistrer son travail et te rendre le fichier disponible....

A te lire, et bon après-midi.

Jean-Pierre