pb affichage dans combobox

[pakalom]

bonsoir,

Fréquentant reguliérement ce forum pour trouver les solutions a mes problèmes. Mais là je ne trouve pas.
je voudrais enfin de compte uniquement les mois qui concerne le site A dans le combobox1 de mon userform.Sachant que j'ai mis dans ce même combobox1 une macro pour avoir uniquement a l'affichage les mois concernés.

Vous trouverez ci joint mon fichier.

Merci d'avance

 

[Compte Supprimé 979]

Re : pb affichage dans combobox

Bonjour Pakalom,

Voici le code

Private Sub UserForm_Initialize()
  Dim DLig As Long, Lig As Long, Site As String
  ' Définir le site à visulaiser
  Site = "A"
  ' Effacer la combobox avant de la remplir au cas ou
  Me.ComboBox1.Clear
  ' Avec la feuille nommée
  With Sheets("Feuil2")
    ' Trouver la dernière ligne du tableau
    DLig = .Range("A" & Rows.Count).End(xlUp).Row
    ' Pour chaque ligne de celui-ci
    For Lig = 8 To DLig
      ' SI le site correspond à celui cherché
      If .Range("C" & Lig) = Site Then
        ' Vérifier si la valeur n'existe pas déjà en lui affectant le contenu de la cellule
        Me.ComboBox1.Value = .Range("A" & Lig)
        ' si la Cbb = -1 la valeur est inexistante
        If Me.ComboBox1.ListIndex = -1 Then
          Me.ComboBox1.AddItem .Range("A" & Lig)
        End If
      End If
    Next Lig
  End With
End Sub

A+

 

[pakalom]

Re : pb affichage dans combobox

bonsoir bruno m45,

Désolé du retard, mais je te remercie de ta reponse. Ca marche ; merci merci merci

@+