Nombre d'occurrences

[landsat]

Bonjour a toutes et a tous

Je souhaite votre aide si possible pour resoudre cette demande .
a partir d'une liste de chiffres a 4 decimales , je voudrais en fonction de plages parametrables si possibles ,calculer le nombre d'occurrences pour chacune des plages.

un petit fichier ci-joint avec details de ma requete.

d'avance merci de votre bienveillance

Landsat

 

[Tibo]

Re : Nombre d'occurrences

Bonjour,

Pas certain d'avoir compris ta demande, un essai avec cette formule en D2 :

=SOMMEPROD((DROITE($B$2:$B$861;2)*1>=MIN(F2;H2))*(DROITE($B$2:$B$861;2)*1<=
MAX(F2;H2)))

à recopier vers le bas

@+

 

[landsat]

Re : Nombre d'occurrences

Tibo

Merci pour ta reponse aussi rapide , que je ne peux tester car mon excel est en anglais, donc il se melange les pinceaux entre ", :;" desole ... mais si tu colles la formule dans fichier excel alors la quand je l'ouvre excel va "traduire" ta formule .

Merci encore pour ta rapidite

Landsat

 

[landsat]

Re : Nombre d'occurrences

Tibo

Merci milles fois... j'ai reussi a traduire ta formule ... ca marche parfaitement ...


Landsat

 

[landsat]

Re : Nombre d'occurrences

RE-bonjour a tous et a toutes

je reviens vers vous , ce matin Tibo a resolu mon petit probleme , et je reviens vers vous pour une autre requete sur le meme fichier.

j'ai un fichier dans lequel je calcul le nombre d'occurrences dans une colone, mais afin d'afiner mes recherches je souhaite savoir si il est possible de faire le meme calcul mais cette fois-ci en integrant une plage horraire parametrable dans la formule de calcul.

dans le fichier joint j'ai mis les details de ma requete, mais si ce n'etait pas clair pour vous je suis a votre disposition.

Merci par avance de votre bienveillance

Landsat

 

[Tibo]

Re : Nombre d'occurrences

re,

Peut-être avec ceci en G2 :

=SOMMEPROD((($D$2:$D$546)*1>=MIN(H2;I2))*(($D$2:$D$546)*1<=MAX(H2:I2))*
($C$2:$C$546>=$H$24)*($C$2:$C$546<=$I$24))

à recopier vers le bas

Je te laisse tester

@+

 

[landsat]

Re : Nombre d'occurrences

Tibo

alors la chapeau bas ,quelle maitrise... suis impressione par ta maitrise...
ca marche parfaitement bien ...

merci encore pour ta promptitude et ton efficacite

Landsat

 

[landsat]

Re : Nombre d'occurrences

Tibo

sur la base du meme fichier , ta formule marche parfaitement , merci , et on travaillant sur mes donnees , et en reflechissant , j'ai meme essaye mais sans succes , est-il possible de calculer la moyennes des donnees qui correspondent au total des donnees de la plage horaire.

avec ta formule sur 546 donnees en colone D ,246 au total correspondent a la plage horaire , c'est parfait , mais ma nouvelle et derniere requete serai de calculer la moyenne de ces 246 donnees qui sont en colone D

J'ai l'impression d'abuser ... mais alors aujourd'hui j'ai fait un grand pas

Landsat

 

[Tibo]

Re : Nombre d'occurrences

re,

Sous réserve d'avoir compris la notion de moyenne sur ton tableau, un essai avec une formule matricielle :

en F2 :

=SI(SOMME((($D$2:$D$546)*1>=MIN(H2;I2))*(($D$2:$D$546)*1<=MAX(H2:I2))*
($C$2:$C$546>=$H$24)*($C$2:$C$546<=$I$24))=0;"";MOYENNE(SI(((($D$2:$D$546)*1>=
MIN(H2;I2))*(($D$2:$D$546)*1<=MAX(H2:I2))*($C$2:$C$546>=$H$24)*($C$2:$C$546<=
$I$24));$D$2:$D$546)))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

La première partie de la formule est destinée à empêcher l'affichage du #DIV/0! lorsqu'il n'y a aucune valeur qui répond aux différents critères.

A savoir que la formule basée sur SOMMEPROD est également une formule matricielle, mais qui ne demande qu'une simple validation par ENTREE

Je te laisse tester

@+

 

[landsat]

Re : Nombre d'occurrences

Tibo

Je suis desole , mais je pense que ma requete n'a pas ete tres claire.
la premiere formule que tu m'as donnee correspond exactement a ce que je cherche. je ne cherche pas a la remplacer.

ce que je cherche maintenant c'est a mettre dans la cellule rouge)

la cellule jaune me donne le total du nombre d'occurrences en fontion de mes parametres , je souhaite savoir si il est possible de calculer la moyenne de ces occurrences.
en jaune j'ai 260 occurrences qui proviennent da la colone D (36 12 15 etc..)donc en fait je cherche a faire la moyenne simple des ces 260 occurrences.

Je suis reconnaissant du temps que tu consacres a cette requete .

Landsat

 

[Tibo]

Re : Nombre d'occurrences

Bonjour,

Dans ce cas, peut-être avec cette formule :

=MOYENNE(SI(($B$2:$B$550>=G24)*($B$2:$B$550<=H24);$C$2:$C$550))

Formule matricielle à valider par CTRL + MAJ + ENTREE

Je te laisse tester

@+

 

[landsat]

Re : Nombre d'occurrences

Tibo

Parfait ... ca marche a merveille , merci beaucoup pour ton aide precieuse..

Landsat

 

[landsat]

Re : Nombre d'occurrences

Tibo

Merci encore c'est genial..... au fait ton travail est a Pekin... je pense que c'est la premiere fois que ton expertise se retrouve aussi loin ..... alors merci de ton aide precieuse..

De Pekin

Landsat

 

[Tibo]

Re : Nombre d'occurrences

re,

Dans la mesure où tu as Excel 2007, il est possible d'utiliser la fonction MOYENNE.SI.ENS :

=MOYENNE.SI.ENS($C$2:$C$550;$B$2:$B$550;">="&G25;$B$2:$B$550;"<="&H25)

Avantage : simple validation par ENTREE

Inconvénient : Fonction apparue avec Excel 2007 et donc non compatible si on veut utiliser le fichier avec une version antérieure.

Ce qui me fait préférer la version proposée tout à l'heure

Sinon, que fais-tu si loin de la France ?

@+

 

[landsat]

Re : Nombre d'occurrences

Tibo

J'ai excel 2007 , donc ta revision de formule est parfaite.
Je suis en asie depuis 20 ans Taiwan ,Hong Kong et maintenant Pekin depuis 8 ans. Je suis dans la grande distribution , j'ai bosse longtemps pour carrefour , mais depuis 8 ans a mon compte...

Landsat