Nombre de jours entre 2 dates

[tzai]

Bonjour,

Je cherche à calculer le nombre de jours qu'il y a entre 2 dates.
Par exemple date a : 12 janvier 2007
date b : 8 février 2009
Résultat : XX jours

Comment faire cela ?

Merci

 

[PascalXLD]

Re : Nombre de jours entre 2 dates

Bonjour

Tu as la fonction DATEDIF qui fait cela tout seul

 

[PascalXLD]

Re : Nombre de jours entre 2 dates

re

pour ton cas cela donne

=DATEDIF(A1;B1;"d")

 

[AMAROLO]

Re : Nombre de jours entre 2 dates

Bonjour,

Je cherche à calculer le nombre de jours qu'il y a entre 2 dates.
Par exemple date a : 12 janvier 2007
date b : 8 février 2009
Résultat : XX jours

Comment faire cela ?

Merci

Bonjour,
La formule est la suivante : DATEDIF(A1;A2;"d")

Première date en A1 et seconde date en A2

Bon courage.

 

[tzai]

Re : Nombre de jours entre 2 dates

Merci.

Maintenant si je veux que ce nombre de jours soit converti en XX annéé XX mois XX jours ?

 

[AMAROLO]

Re : Nombre de jours entre 2 dates

Pour les années, tu mets "y" à la place de "d" et pour les mois "m".

 

[abcd]

Re : Nombre de jours entre 2 dates

Bonjour,

Pour le nombre de jours :
=B1-A1
cellule au format Standard ou Nombre

Pour le nombre d'années, mois et jours :
=TEXTE(B1-A1;"a")&" années "&TEXTE(B1-A1;"m")&" mois et "&TEXTE(B1-A1;"j")&" jours"

abcd

 

[tzai]

Re : Nombre de jours entre 2 dates

D'accord, mais pour afficher année, mois, jours dans la même cellule ?

Je dois écrire la fonction comme cela DATEDIF (A1;A2;"y", "m", "d") ???

EDIT : Le message précédant répond à ma requête mais la formule demande d'être adaptée selon les versions.

=TEXTE(B1-A1;"y")&" années "&TEXTE(B1-A1;"m")&" mois et "&TEXTE(B1-A1;"d")&" jours"

Merci à tous

 

[CMoa]

Re : Nombre de jours entre 2 dates

Bonjour a tous
Vois si ceci te vas.
@+

 

[abcd]

Re : Nombre de jours entre 2 dates

Bonjour tzai,

J'ai testé ma formule avant de la mettre sous mon message et je puis t'assurer qu'il n'y a pas "quelques erreurs" comme tu le prétends.

J'obtiens bien : 02 années 1 mois et 27 jours
Par contre, ta formule me renvoie : y années 1 mois et d jours.

Avant d'accuser quelqu'un, ne pourrais-tu imaginer que nous travaillons peut-être sur des versions différentes d'Excel, ou que nos paramètres régionaux ne sont pas définis de manière identique.

A l'avenir, soit plus prudent dans tes affirmations, et plus spécialement vis-à-vis de quelqu'un qui consacre bénévolement une partie de son temps libre à te venir en aide.

abcd

 

[tzai]

Re : Nombre de jours entre 2 dates

abcd, je suis confus et je te présente mes excuses en espèrant que tu les accepteras.

J'ai remarqué que dans ta formule par défaut elle affiche 00 années 01 mois et 0 jours, même sans date ou avec des dates inférieurs à 1 mois d'intervalle.

D'où peut venir cet affichage curieux ? J'ai pas dit erreur hein

Merci

 

[tzai]

Re : Nombre de jours entre 2 dates

Pas d'avis sur ma requête ?

merci

 

[bqtr]

Re : Nombre de jours entre 2 dates

Bonjour à tous,

Essaye avec ceci:

=DATEDIF(A1;B1;"y")&SI(DATEDIF(A1;B1;"y")>1;" ans, ";" an, ")&DATEDIF(A1;B1;"ym")&" mois, "&DATEDIF(A1;B1;"md")&SI(DATEDIF(A1;B1;"md")>1;" jours";" jour")

Il faut entrer une date en A1 inférieure ou égale à la date en B1 sinon tu auras une erreur.

A+

 

[abcd]

Re : Nombre de jours entre 2 dates

Bonjour,

Je n'avais pas vu ta réponse, excuse-moi donc du retard de ma réponse, et pas besoin de t'excuser, ma petite remarque était tout amicale.

Pour ce qui est de la formule, effectivement si la cellule est vide, elle devrait renvoyer 0 ans 0 mois 0 jours, car Excel considère une cellule vide comme étant égale à 0.
Pourquoi renvoie-t-elle 1 mois, je n'en ai pas la moindre idée.
C'est une question qui a déjà été abordée sur ce forum, mais sans explication concrète (tu vois que je suis prudent, je ne dis pas que c'est un "bug").
Tout comme pour le 29/02/1900, qu'Excel consdère comme une date valable, alors que l'année 1900 n'est pas bissextile, et que cette "anomalie" n'a pas été corrigée sous la version 2007, alors qu'elle n'existe pas sous d'autres tableurs.

Si il y a des cellules vides, il serait à conseiller de faire précéder la formule d'un test, du type :
=SI(ou(A1="";A1=0);la formule).

Tant qu'on y est, il est aussi possible, toujours sous la même formule, de supprimer le "s" des années et des jours si ceux-ci sont égaux à 1, et même de supprimer ans, mois et jours si ceux-ci sont égaux à 0.
Si tu ne vois comment faire et que cela t'intéresse, fais signe, je t'établirai un petit exemple.

abcd

 

[ROGER2327]

Re : Nombre de jours entre 2 dates

Bonjour à tous,

Ce sujet revient souvent et les réponses sont toujours les mêmes. La mienne est la formule

=SOMME(ENT((ANNEE(A3)-ENT((MOD(MOIS(A3)+9;12))/10))/{400;100;4;1})*{1;-1;1;365})+ARRONDI(30.6*(MOD(MOIS(A3)+9;12));0)+JOUR(A3)-SOMME(ENT((ANNEE(A2)-ENT((MOD(MOIS(A2)+9;12))/10))/{400;100;4;1})*{1;-1;1;365})-ARRONDI(30.6*(MOD(MOIS(A2)+9;12));0)-JOUR(A2)

qui donne la différence en jour entre deux dates placées en A3 et A2 (i.e. A3-A2). C'est un peu lourd, mais les résultats obtenus sont satisfaisants dès lors que le format de la cellule contenant la formule est Standard ou Nombre. Elle fonctionne que la date en A3 soit postérieure ou antérieure à la date en A2. Par expérience, je me méfie de la fonction DATEDIF(A3;A2;"d") qui donne un résultat quelquefois fantaisiste.
À la vérité, dans ces histoires de date, la plus grande méfiance s'impose. Par exemple, la plupart des gens vous diront que, si on décide de numéroter jour 1 le premier janvier 1900, le 10 février 2009 porte le numéro 39854. Ils ne font que répéter l' affirmation de Microsoft sans la vérifier. Or, c'est parfaitement faux : en réalité, c'est le 11 février 2009 qui porte le numéro 39854.
À y regarder de plus près, la numérotation des jours à compter du premier janvier 1900, compté 1, n'est exacte que pour les mois de janvier et février 1900. Au-delà, elle est fausse.

Pour résumer, dans Excel, le décompte des jours se fait :

• à partir du premier janvier 1900 (compté1) pour les mois de janvier et février 1900 ;
• à partir du 31 décembre 1899 (compté 1) pour toutes les dates postérieures au 28 février 1900.

​

Pourquoi faire simple, si on peut faire compliqué ?​

Bon courage !
ROGER2327