Nombre de jours d'un meme mois

[serir]

Bonjour ,

J'aimerai savoir comment calculer automatiquement le nombre de jours d'un même mois et ce sans compter les doublons.

Merci beaucoup

 

[CHALET53]

Re : Nombre de jours d'un meme mois

Bonjour

En VBA

Rajoût d'une entête à la colonne

a+

 

[CISCO]

Re : Nombre de jours d'un meme mois

Bonsoir

Tu peux aussi faire avec

ENT(SOMME(SIERREUR((1/((MOIS(A$1:A$31)=MOIS(C3))*(NB.SI(A$1:A$31;A$1:A$31))));10^(-10))))

en matriciel (à valider avec CTRL+ maj tempo+entrer) en mettant de vraies dates en C3, C4 et ainsi de suite, au format personnalisé mmmm.

 

[job75]

Re : Nombre de jours d'un meme mois

Bonjour serir, salut CHALET53,

Si les dates sont triées, formule en D3 à tirer vers le bas :

=SOMMEPROD((MOIS(A$1:A$31)=MOIS("1"&C3))*(A$1:A$31<>A$2:A$32))

Edit : salut CISCO

A+

 

[job75]

Re : Nombre de jours d'un meme mois

Re,

Si les dates ne sont pas triées, toujours en D3 :

=SOMMEPROD((MOIS(A$1:A$31)=MOIS(1&C3))*(LIGNE(A$1:A$31)=EQUIV(A$1:A$31;A$1:A$31;0)))

Nota : les deux formules sont pour le fichier du post #1 (il n'y a pas de titre en A1).

A+

 

[R@chid]

Re : Nombre de jours d'un meme mois

Bonsoir @ tous,
en D3,

=NB(1/FREQUENCE(SI(MOIS(A$1:A$31)=MOIS(1&C3);A$1:A$31);A$1:A$31))

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
@ + +

 

[R@chid]

Re : Nombre de jours d'un meme mois

Re,
Une autre si tu as des milliers de valeurs dans la colonne A,
- Sélectionner la plage D3: D5
- Coller cette formule dans la barre de formule
- Valider par Ctrl+Maj+Entree

=FREQUENCE(SI(FREQUENCE(A1:A31;A1:A31);EQUIV(MOIS(A1:A31);MOIS(1&C3:C5);0));LIGNE(1:3))

@ + +

 

[Regueiro]

Re : Nombre de jours d'un meme mois

Bonsoir à Tous
Je vois que les meilleurs Formulistes sont sur le coup.
CISCO, R@CHID, JOB75, CHALET53

Une idem R@achid plus courte.

=NB(1/FREQUENCE(SI(MOIS(Liste)=MOIS(1&C3);Liste);Liste))

Valider par Ctrl+Maj+Entree

Liste =

=DECALER(Feuil1!$A$1;0;0;NBVAL(Feuil1!$A:$A))

A+
Bonnes Fêtes à Tous

 

[job75]

Re : Nombre de jours d'un meme mois

Re, salut R@chid, Regueiro,

S'il y a un titre en A1 la formule du post #5 doit être modifiée :

=SOMMEPROD((MOIS(A$2:A$32)=MOIS(1&C3))*(LIGNE(A$2:A$32)=EQUIV(A$2:A$32;A$1:A$32;0)))

Edit : avec ceci plus de problème :

=SOMMEPROD((MOIS(A$2:A$32)=MOIS(1&C3))*(LIGNE(A$2:A$32)=1+EQUIV(A$2:A$32;A:A;0)))

Fichier joint.

A+