nombre de cellules prises en compte dans un calcul selon plusieurs critères

[moutchec]

bonjour à tous,
je cherche une formule pour afficher le nombre de cellules prises en compte dans un calcul effectué sur une autre feuille selon plusieurs critères ( 1 ou 2)
dans l exemple en annexe, je calcule dans la cellule "J2" de la "feuil2" les poids moyens dans la "feuille 1-1" selon que le numéro d article commence par 200, 201 ou 202.
dans la cellule "I2" de la 'feuil2" j'aimerais trouver une formule qui puisse indiquer le nombre de cellules prises en compte dans ce calcul afin de pouvoir calculer le poids moyen.
peut-être aussi que je m'y prends mal tout simplement...
aidez moi s'il vous plait
merci d'avance.

 

[ROGER2327]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Bonjour moutchec.

S'il s'agit de trouver le nombre de lignes de la feuille 1-1 dont la valeur en colonne A commence par 200 :​

=SOMMEPROD(--(GAUCHE('1-1'!$A$2:$A$57;3)="200"))

S'il s'agit d'autre chose, je n'ai pas compris.​

Bonne journée.


ℝOGER2327
#7527

Lundi 23 Phalle 141 (*Saint Lazare, gare - fête Suprême Quarte)
16 Fructidor An CCXXII, 5,9661h - citron
2014-W36-2T14:19:07Z

 

[Dugenou]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Bonjour,
si c'est seulement en fonction du code de l'article (dommage pour une fois que ce code soit un chiffre) et que tous les codes articles ont 5 chiffres :
=NB.SI.ENS('1-1'!$A$4:$A$57;">="&20000;'1-1'!$A$4:$A$57;"<"&20100)
te donne le nombre d'articles et
=SOMME.SI.ENS('1-1'!$G$4:$G$57;'1-1'!$A$4:$A$57;">="&20000;'1-1'!$A$4:$A$57;"<"&20100) te donne la somme des poids moyens. Attention quand tu fais la moyenne des poids moyens tu ne tiens pas compte des quantités produites...
Si, en plus, il faut tenir compte de la semaine comme c'est écrit dans ton fichier, il faudrait avoir une colonne de plus dans les données avec le N° de semaine (calculé aisément à partir de la date)

Cordialement

Edit : bonjour maitre Roger : pourrais tu m'expliquer rapidement pourquoi le -- en début de sommeprod ?

 

[ROGER2327]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Re...

(...)
Edit : bonjour maitre Roger : pourrais tu m'expliquer rapidement pourquoi le -- en début de sommeprod ?

SOMMEPROD

a besoin d'argument(s) numérique(s).

Or,

(GAUCHE('1-1'!$A$2:$A$57;3)="200")

renvoie le vecteur

{FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;FAUX;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX;FAUX}

qui n'est pas numérique.

Il faut donc rendre ce vecteur numérique :

{0;0;1;0;0;0;0;1;1;1;1;1;1;1;0;0;0;0;1;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0;0}

Plusieurs solutions sont possibles :

=SOMMEPROD(0+(GAUCHE('1-1'!$A$2:$A$57;3)="200"))

=SOMMEPROD(1*(GAUCHE('1-1'!$A$2:$A$57;3)="200"))

=-SOMMEPROD(-(GAUCHE('1-1'!$A$2:$A$57;3)="200"))

=SOMMEPROD(--(GAUCHE('1-1'!$A$2:$A$57;3)="200"))

Bonne soirée.


ℝOGER2327
#7528

Lundi 23 Phalle 141 (*Saint Lazare, gare - fête Suprême Quarte)
16 Fructidor An CCXXII, 6,1364h - citron
2014-W36-2T14:43:39Z

 

[Dugenou]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

raaaaaaah merci Maître !
je suis plutôt partisan du *1 qui me semble plus facile à comprendre.
Je me coucherai moins sot ce soir !

 

[ROGER2327]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Re...

raaaaaaah merci Maître !
je suis plutôt partisan du *1 qui me semble plus facile à comprendre.
Je me coucherai moins sot ce soir !

C'est mieux, avec un "M" majuscule. Ce timide :

​

Edit : bonjour maitre Roger (...)

a failli me vexer.

La prochaine fois, j'aimerais bien "Maître", si ce n'est pas trop demander.​

Bonne soirée.


ℝOGER2327
#7529

Lundi 23 Phalle 141 (*Saint Lazare, gare - fête Suprême Quarte)
16 Fructidor An CCXXII, 6,2662h - citron
2014-W36-2T15:02:20Z

 

[moutchec]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Bonjour moutchec.

S'il s'agit de trouver le nombre de lignes de la feuille 1-1 dont la valeur en colonne A commence par 200 :​

=SOMMEPROD(--(GAUCHE('1-1'!$A$2:$A$57;3)="200"))

S'il s'agit d'autre chose, je n'ai pas compris.​

Bonne journée.


ℝOGER2327
#7527

Lundi 23 Phalle 141 (*Saint Lazare, gare - fête Suprême Quarte)
16 Fructidor An CCXXII, 5,9661h - citron
2014-W36-2T14:19:07Z

re, à la base, le poids moyen par lot est dejâ calculé en tenant compte de la quantité produite de ce lot, je pensais donc qu'il suffirait d'additionner tous ces poids par sorte (trois premiers chiffres 200, 201 ou 202) et diviser par le nombre darticles pris en compte. pensez-vous que je me trompe?

Merci à tous pour vos réponses.

 

[Dugenou]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Bonjour moutchec, bonjour Maître
si tu as produit 10 objets d'un poids moyen de 1kg et 100 objets d'un poids moyen de 10 kg, la moyenne n'est pas de 5.5 kg
donc tu dois tenir compte du nb d'objets produits pour pondérer ta moyenne : idéalement tu multiplie chaque poids moyen par le nb d'objets correspondants puis tu divise la somme par le nombre total d'objets.
Cordialement

 

[moutchec]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

bonjour,
bien raisonné, je vais essayer de l'appliquer en tenant compte aussi du fait que le feuille 1-1 n'est qu'un résumé de la ligne 1 en semaine 1 et qu'il y aura donc dans le classeur 52 feuilles (1-->52) pour cette ligne, de même pour les ligne 2, 3 et 4.
je revois donc ma stratégie et je reviens demander de l'aide si je bloque.
deja, merci.
bien à vous.

 

[moutchec]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

bonjour à tous
pour avoir mon poids moyen par nature (commençant par 200,201 ou 202) et par semaine j'ai voulu dans un premier temps ramener sur la feuille "report" les productions des articles commençant par 200 (par ex) dans la colonne "C", puis le poids moyen dans la colonne "D", ensuite sur la feuille "poids moyens" j'aurais fait (C4*D4)+(C5*D5) etc le tout divisé par la somme C4:C10.
je ne suis pas arrivé à surmonter cette première étape,
aidez moi s'il vous plait.
fichier excel en PJ
merci.

 

[Dugenou]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Bonjour,
Quand tu fais référence à une autre feuille, le nom de la feuille est entouré de simples quotes :

='1-1'!F9:F200

donc dans le indirect il faut aussi ajouter ces simples quotes

INDIRECT("'"&$G$1&"-"&A5&"'!F9:F200")

j'ai donc copié "'"&$G$1&"-"&A5&"' et je l'ai collé partout dans tes formules en remplacement de $G$1&"-"&A5&"

ça semble fonctionner
Cordialement

 

[moutchec]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

je remarque que le tri se fait sans tenir compte de la colonne "A". normalement ne doivent être reportés que les chiffres de la colonne "F" de la feuille "1-1" qui ont un numéro d'article en colonne "A".

 

[Dugenou]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Re,
DECALER($E$4;ENT((LIGNES($4:5)-1)/10)*10+1 : enlever le +1

soit

=SIERREUR(INDEX(INDIRECT("'"&$G$1&"-"&A4&"'!F9:F200");PETITE.VALEUR(SI(INDIRECT("'"&$G$1&"-"&A4&"'!A9:A200")=DECALER($E$4;ENT((LIGNES($4:4)-1)/10)*10;);LIGNE(INDIRECT("1:"&LIGNES(INDIRECT("'"&$G$1&"-"&A4&"'!A9:A200")))));MOD(LIGNES($4:4)-1;10)+1));"")

Cordialement

 

[moutchec]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

SINCERES REMERCIEMENTS, je continue....

 

[moutchec]

Re : nombre de cellules prises en compte dans un calcul selon plusieurs critères

Bonjour, comment modifier cette formule en utilisant la fonction GAUCHE (200 en E4 au lieu de 200200) pour que les lignes dont les valeurs commencent par 200 soient prises en compte?

Re,
DECALER($E$4;ENT((LIGNES($4:5)-1)/10)*10+1 : enlever le +1

soit

=SIERREUR(INDEX(INDIRECT("'"&$G$1&"-"&A4&"'!F9:F200");PETITE.VALEUR(SI(INDIRECT("'"&$G$1&"-"&A4&"'!A9:A200")=DECALER($E$4;ENT((LIGNES($4:4)-1)/10)*10;);LIGNE(INDIRECT("1:"&LIGNES(INDIRECT("'"&$G$1&"-"&A4&"'!A9:A200")))));MOD(LIGNES($4:4)-1;10)+1));"")

Cordialement