NB.SI avec filtre automatique

[gysmo057]

Bonjour,

j'ai déjà fait pas mal de recherche concernant ce sujet mais je ne comprend pas toutes les réponses. Alors je me permet de rouvrir un sujet avec mon exemple concret.

En effet dans le tableau ci-joint je souhaite dans la feuille "suivi" faire un filtre en colonne N (jusque là pas de problème).

Dans la feuille synthèse, je souhaite connaître la nombre de chaque valeur de la colonne G. J'ai donc utilisé NB.SI mais cette fonction ne prend pas en compte le filtre automatique que je mets en place.

Pouvez-vous m'aider ?

Merci par avance.

 

[BOISGONTIER]

Re : NB.SI avec filtre automatique

Bonjour,

=SOMMEPROD((SOUS.TOTAL(3;DECALER(SUIVI!$G$2;LIGNE(2:1000)-2;0)))*(SUIVI!$G$2:$G$1000=B3))

JB

 

[gysmo057]

Re : NB.SI avec filtre automatique

Merci beaucoup.

Je ne suis pas près d'oublier cette formule.

Bien Cordialement

 

[JeanMarie]

Re : NB.SI avec filtre automatique

Bonjour, Gysmo, JB

Une autre proposition d'une formule matricielle à Valider par Ctrl+Shift+Entrer
Pour représentation horizontale

=TRANSPOSE(FREQUENCE(SI(SOUS.TOTAL(3;DECALER(SUIVI!G$1;LIGNE(1:68);));SI(ESTNA(EQUIV(SUIVI!G$2:G$69;$B$3:$K$3;0));"";EQUIV(SUIVI!G$2:G$69;$B$3:$K$3;0)));LIGNE(A1:A10)))

Pour une représentation verticale

=FREQUENCE(SI(SOUS.TOTAL(3;DECALER(SUIVI!G$1;LIGNE(1:68);));SI(ESTNA(EQUIV(SUIVI!G$2:G$69;$B$3:$K$3;0));"";EQUIV(SUIVI!G$2:G$69;$B$3:$K$3;0)));LIGNE(A1:A10))

Attention pour la mise en oeuvre, cette formule retournant la liste des 10 compteurs, il faut sélectionner une plage de 10 cellules, coller la formule dans la zone de saisie dans la barre d'outils formule, et valider par les touches Ctrl+Shift+Entrer.

Concernant la formule indiquée par JB, elle peut être simplifiée

=SOMMEPROD((SOUS.TOTAL(3;DECALER(SUIVI!$G$1;LIGNE(1:999);0)))*(SUIVI!$G$2:$G$1000=B3))

on évite 9990 soustractions à chaque recalcul de la feuille.

@+Jean-Marie

 

[gysmo057]

Re : NB.SI avec filtre automatique

Impeccable.
merci beaucoup JeanMarie.

Cordialement

 

[Nehko]

Re : NB.SI avec filtre automatique

Bonjour,
J'étais à la recherche de ce type de formule.
J'ai testé celle de BGJ, aucun souci hormis que c'est extremement lent lorsqu'on doit repeter la même opération sur 300 autres critères, et un nombre de ligne total de 80 000.

J'ai finalement changé de méthode pour arriver à mes fins, mais si vous avez des idées pour améliorer les performances, ca m'interesse.

Cordialement,
Emmanuel