Mot de passe

[Hervé]

Coucou les copains ^^

tiens, j'en profite d'etre de passage pour poser une question.

connaitriez vous une solution rapide pour affecter un mot de passe (a l'ouverture) à environ 500 fichiers répartis sur 8 repertoires ?

d'avance merci

 

[job75]

Re : Mot de passe

Bonjour Hervé, le forum,

Ma foi [Edit : sans s pour les puristes] ta question ne me paraît pas très claire

Mais je suppose que tu ouvres tous ces fichiers en exécutant 2 boucles, la 1ère pour les répertoires, la 2ème pour les fichiers.

Alors dans la 2ème boucle, pour chaque fichier ouvert :

- S'il s'agit de créer une macro Workbook_Open dans ThisWorkbook (un code avec une InputBox pour le mot de passe), ce n'est pas vraiment ma tasse de thé et il y a des exemples sur le forum

- S'il s'agit pour ouvrir le fichier d'entrer toujours le même mot de passe (par exemple "toto"), alors ce code :

SendKeys "toto~"

Tout ça me paraît trop simple...

A+

 

[Hervé]

Re : Mot de passe

coucou job

non non, je veux mettre un mot de passe aux 500 fichiers ^^

il me faut proteger tout les fichiers excel se trouvant dans des sous répertoire.

J'ai la flemme de les ouvrir un par un, j'ai la flemme de faire une macro pour ca (si c'est possible par macro d'ailleurs)

je me demandais donc si il existait pas un petit soft qui serait moins flemmard que moi

a plus

 

[job75]

Re : Mot de passe

Re,

C'est donc ma 1ère hypothèse qui était bonne, mais si l'on n'ouvre pas les fichiers et si l'on n'y écrit pas le code, j'en resterai assis s'il y a une solution

Mais peut-être que MdF ou JB...

A+

 

[kiki29]

Re : Mot de passe

Salut, je n'ai pas trouvé de soft faisant cela, par contre en adaptant par exemple Lien supprimé
( en remplaçant la création de liens par le chemin complet du fichier )
Ensuite grace au macro recorder on obtient qqch comme

Sub Mdp()
    Workbooks.Open Filename:="C:\Transfert\MDP\Test.xls"
    ActiveWorkbook.SetPasswordEncryptionOptions PasswordEncryptionProvider:= _
        "Microsoft Strong Cryptographic Provider", PasswordEncryptionAlgorithm:="RC4", _
        PasswordEncryptionKeyLength:=128, PasswordEncryptionFileProperties:=True
    
    ActiveWorkbook.SaveAs Filename:="C:\Transfert\MDP\Test_Mdp.xls", FileFormat:= _
        xlNormal, Password:="Azerty", WriteResPassword:="", _
        ReadOnlyRecommended:=False, CreateBackup:=False
    ActiveWindow.Close
End Sub

Ce qui ne devrait pas te poser de problemes majeurs pour balayer la liste obtenue via le 1er fichier modifié
en adaptant la macro obtenue plus haut

PS : au final et rapidement qqch qui devrait te convenir

 

[job75]

Re : Mot de passe

Re, bonjour kiki29,

Oui, il y a la solution du mot de passe dans Enregistrer sous.

Alors en ouvrant les fichiers un par un, le code est assez simple. Ma solution :

Sub ProtegeFichiers()
Dim Dossier(), i As Byte, chemin$, nomfich$
Application.ScreenUpdating = False
Application.DisplayAlerts = False
On Error Resume Next 'au cas où des fichiers sont déjà protégés
Dossier = Array("Dossier1", "Dossier2")
For i = 0 To UBound(Dossier)
  chemin = ThisWorkbook.Path & "\" & Dossier(i) & "\"
  nomfich = Dir(chemin & "*.xls") '1er fichier du dossier
  While nomfich <> ""
    SendKeys "{ESC}" 'ferme la boîte de dialogue du mot de passe quand le fichier est protégé
    Workbooks.Open chemin & nomfich
    If Err = 0 Then 'si le fichier n'est pas protégé
      Workbooks(nomfich).SaveAs chemin & nomfich, Password:="toto" 'la fenêtre du fichier peut être masquée
      Workbooks(nomfich).Close
    End If
    Err = 0
    nomfich = Dir 'fichier suivant du dossier
  Wend
Next
End Sub

Pour tester, j'ai mis des fichiers non protégés dans les répertoires nommés Dossier1 et Dossier2, qui doivent être des sous-répertoires de celui du fichier où est la macro.

Edit : si un fichier porte le même nom que celui où est la macro, il ne peut pas être ouvert, donc protégé.

A+

 

[Hervé]

Re : Mot de passe

salut

merci pour vos codes.

j'ai honte de demander du code alors que je suis capable de le pondre

en faite j'ai pas aussi honte que ca, j'ai juste plus envie de coder quoique ce soit

a plus