Macro permettant de remplacer certain éléments

[chasseur44]

Bonjour le Forum

Je vous soumet mon problème dans le fichier joint
En fait je sais créer ma macro pour résoudre mon problème (fait d'une certaine facon) c-a-d en inserant une colonne supplémentaire et de faire une recherchev avec la formule d'erreur si#N/A, transformer après en valeur, puis remplacer ma colonne d'origine! mais je pense qu'il doit y avoir une formule bcp plus rapide avec une boucle ! et la je sèche
Merci pour votre aide

 

[Theze]

Re : Macro permettant de remplacer certain éléments

Bonjour,

Une piste :

Sub Test()

    Dim PlageDonnee As Range
    Dim PlageTable As Range
    Dim CelDonnee As Range
    Dim CelTable As Range
    Dim Adr As String
    
    'plage où sont effectuées les modifs
    With Worksheets("Données")
     
        Set PlageDonnee = .Range(.Cells(2, 4), .Cells(.Rows.Count, 4).End(xlUp))
    
    End With
    
    'plage des valeurs de modification
    With Worksheets("Table")
     
        Set PlageTable = .Range(.Cells(3, 1), .Cells(.Rows.Count, 1).End(xlUp))
    
    End With
    
    'recherche et modifs
    For Each CelTable In PlageTable
        
        Set CelDonnee = PlageDonnee.Find(CelTable.Value, , xlValues, xlWhole)
        
        If Not CelDonnee Is Nothing Then
        
            Adr = CelDonnee.Address
            
            Do
                
                CelDonnee.Offset(, 1).Value = CelTable.Offset(, 1).Value
                
                Set CelDonnee = PlageDonnee.FindNext(CelDonnee)
                
            Loop While Adr <> CelDonnee.Address
            
        End If
        
    Next CelTable

End Sub

Hervé.

 

[pierrejean]

Re : Macro permettant de remplacer certain éléments

Bonjour chasseur 44

Vois si cela te convient

Edit : Salut hervé

 

[Theze]

Re : Macro permettant de remplacer certain éléments

Salut PierreJean !

 

[chasseur44]

Re : Macro permettant de remplacer certain éléments

Merci PierreJean et Theze
Comme d'hab c'est parfait et ca répond parfaitement et c'est deja adapté dans mon outil meme si je comprends plus facilement la solution de Theze, je prends la solution de pierreJean !
Vive le forum