Macro IF (Copier coller conditionel)

[bloomby]

Bonjour à tous,

Voici ce qu'il y a dans mon fichier excel
il y a 2 pages.

1) Classement
2) Resultat

Je désir créer une macro qui va faire un copier coller...

(IF) SI
Dans la page classement
SI la cellule F1 = 722
Faire un copier des Cellules F1 B1 & C1 

Et coller dans la page Resultat
dans les cellules A1 B1 & C1

De plus, il faudrait que cette macro puisse faire le tri pour les lignes de 1 à 50

Vous trouverez ci-joint un exemple du résultat mais il me manque maintenant une macro pour optimiser mon travail

merci à tous !!!!

 

[Robert]

Re : Macro IF (Copier coller conditionel)

Bonsoir le fil, bonsoir le forum,

Peut-être comme ça :

Sub Macro1()
Dim cel As Range 'déclare la variable cel (CELlule)
Dim li As Integer 'déclare la variable li (LIgne)
Dim dest As Range 'déclare la variable dest (cellule de DESTination)
 
'boucle sur toutes les cellules éditées cel de la colonne F de l'onglet "Classement"
For Each cel In Sheets("Classement").Range("F1:F" & Sheets("Classement").Cells(Application.Rows.Count, 6).End(xlUp).Row)
    If cel.Value = 722 Then 'condition : si la valeur de la cellule est 722
        li = cel.Row 'définit la ligne li
        With Sheets("Resultat") 'prend en compte l'onglet "Résultat"
            'définit la cellule de destination dest
            Set dest = IIf(.Range("A1") = "", .Range("A1"), .Cells(Application.Rows.Count, 1).End(xlUp).Offset(1, 0))
        End With 'fin de la prise en compte de ...
        With Sheets("Classement") 'prend en compte l'onglet "Classement"
            dest.Value = .Cells(li, 6) 'place dans dest la valeur de la colonne F
            dest.Offset(0, 1) = .Cells(li, 2) 'place dans dest décalé d'une colonne la valeur de la colonne B
            dest.Offset(0, 2) = .Cells(li, 3) 'place dans dest décalé de deux colonnes la valeur de la colonne C
        End With 'fin de la prise en compte de ...
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle
End Sub

Pour le tri il faudrait que tu précises quel onglet tu veux trier et quel est le critère et l'odre de tri...