Macro Copier Coller

[Anto35200]

Bonjour à tous,

J’ai 2 fichiers :
- Extraction Relevé de compte
- Synthèse relevé de compte

Le 1er fichier « Extraction Relevé de compte », est une extraction quotidienne du solde bancaire d’un compte.
J’ai créé une macro pour copier le SOLDE BANCAIRE (cellule B2), vers le 2è fichier « Synthèse relevé de compte ».
Mon gros problème, c’est que dans le fichier « Synthèse de compte », la macro ne copie ce solde toujours à la même ligne.

Comment dire à la macro, qu’elle doit copier ce solde en fonction de la date du jour.
Le solde bancaire du 07/08 doit être copié à la ligne du 07/08, le lendemain le solde du 08/08 à la ligne du 08/08,…

J’espère avoir été suffisamment été clair dans mes explications, et vous remercie d'avance de votre aide.

 

[Yaloo]

Re : Macro Copier Coller

Bonjour plimosin, le forum,

Avec cette macro :

Sub Copier_Extraction()
'
' Copier_Extraction Macro
'
Dim d As Range, wk As Workbook
Set d = [A2]
Set wk = Workbooks.Open("\\192.168.4.1\tresorerie\Antoine.TUY\PROJETS\Synthèse relevé de compte.xls")
If Not IsError(Application.Match(d, wk.Sheets(1).Columns(1), 0)) Then
  wk.Sheets(1).Cells(Application.Match(d, wk.Sheets(1).Columns(1), 0), 2) = d(1, 2)
End If
End Sub

A+

Martial

 

[Anto35200]

Re : Macro Copier Coller

Ok, çà marche !

Juste une autre requête, est-il possible dans une macro de Copier- Coller le solde bancaire avec la DATE du fichier « Extraction solde bancaire » vers le fichier « Synthèse relevé de compte » à la ligne suivante ? C’est-à-dire, que le solde doit être copié ligne après ligne au quotidien :
dans « Extraction Relevé de compte », copié (A2:B2) vers « Synthèse relevé de compte » en (A7 :B7),
le lendemain, du fichier « Extraction relevé de compte » copié (A2:B2) vers « Synthèse relevé de compte » en (A8 :B8),…

Encore merci à toi Martial.

 

[Yaloo]

Re : Macro Copier Coller

Oui, avec ceci

Sub Copier_Extraction()
Dim d As Range, wk As Workbook
Set d = [A2:b2]
Set wk = Workbooks.Open("\\192.168.4.1\tresorerie\Antoine.TUY\PROJETS\Synthèse relevé de compte.xls")
wk.Sheets(1).[A65536].End(3)(2).Resize(, 2) = d.Value
End Sub

A+

 

[Anto35200]

Re : Macro Copier Coller

Ok, c'est impeccable, mais je voudrai comprendre ce code Vba

wk.Sheets(1).[A65536]

 

[Anto35200]

Re : Macro Copier Coller

Je ne comprends pas non plus ce code

End(3)(2).Resize(, 2) = d.Value

merci de ton aide

 

[Yaloo]

Re : Macro Copier Coller

Re,

mais je voudrai comprendre ce code Vba

Ca c'est bien, voici le code avec les explications :

Sub Copier_Extraction()
'Définition des variables : d sera des cellules et wk un classeur
Dim d As Range, wk As Workbook
'Attribution des cellules à d,
Set d = [A2:B2]
'Ouverture et attribution à la variable wk du classeur destination
Set wk = Workbooks.Open("\\192.168.4.1\tresorerie\Antoine.TUY\PROJETS\Synthèse relevé de compte.xls")
'wk.Sheets(1) :Dans le classeur wk dans la feuille 1
'[A65536].end(3)(2) : trouve la première cellule vide de la colonne A
'Resize(,2) : "sélectionne" les 2 colonnes à partir de la cellule précédement trouvée
'Ces cellules "sélectionnées" prenne la valeur de d définit plus haut.
 wk.Sheets(1).[A65536].End(3)(2).Resize(, 2) = d.Value
End Sub

En espérant t'avoir aidé à comprendre