XL 2010 Limitation de la saisie d'une valeur

[man.jul]

Afin de limiter l'utilisation de la valeur "CAV" dans le tableau, je souhaiterais que la saisie (et le copier/coller) de cette valeur ne soit autorisée dans le tableau uniquement par la saisie d'un mot de passe ou par le biais du déverrouillage de la protection de la feuille par exemple.
J'ai interdit son utilisation par la validation des données mais par exemple est-il possible d'enlever ponctuellement cette validation afin de permettre la saisie de cette valeur?

Merci par avance

 

[Hasco]

Bonjour,

26 affichages, pas une proposition, peut-être est-ce parce que vous avez limité aussi l'utilisation de la valeur "Bonjour" ?

Cordialement

 

[job75]

Bonjour man.jul, Roblochon,

Oui l'oubli d'un petit bonjour est malheureux.

Dans le code de la feuille :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False 'désactive les évènements
For Each Target In Target.Areas 'si entrées multiples, pour avoir des cellules jointives
    If Application.CountIf(Target, "CAV") Then
        Application.Undo 'annule les modifications
        UserForm1.Show 'demande le mot de passe
        If Not Application.EnableEvents Then Application.Undo 'rétablit les modifications
        Exit For
    End If
Next
Application.EnableEvents = True 'réactive les évènements
End Sub

Dans le code de l'UserForm :

Private Sub CommandButton1_Click()
If TextBox1 <> "Manu" Then Application.EnableEvents = True 'repérage
Unload Me
End Sub

Il faudra aussi protéger l'accès au VBAProject par mot de passe.

A+

 

[man.jul]

Désolé j'étais pas bien réveillé ce matin... j'ai oublie le "Bonjour"
Merci pour cette proposition qui me convient parfaitement.

 

[job75]

Dans ce fichier (2) voici une solution intéressante avec l'instruction End :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False 'désactive les évènements
For Each Target In Target.Areas 'si entrées multiples, pour avoir des cellules jointives
    If Application.CountIf(Target, "CAV") Then
        Application.Undo 'annule les modifications
        UserForm1.Show 'demande le mot de passe
        Application.Undo 'rétablit les modifications
        Exit For
    End If
Next
Application.EnableEvents = True 'réactive les évènements
End Sub

Private Sub CommandButton1_Click()
If TextBox1 = "Manu" Then Unload Me Else Application.EnableEvents = True: End
End Sub

 

[man.jul]

Dans ce fichier (2) voici une solution intéressante avec l'instruction End :

Private Sub Worksheet_Change(ByVal Target As Range)
Application.EnableEvents = False 'désactive les évènements
For Each Target In Target.Areas 'si entrées multiples, pour avoir des cellules jointives
    If Application.CountIf(Target, "CAV") Then
        Application.Undo 'annule les modifications
        UserForm1.Show 'demande le mot de passe
        Application.Undo 'rétablit les modifications
        Exit For
    End If
Next
Application.EnableEvents = True 'réactive les évènements
End Sub

Private Sub CommandButton1_Click()
If TextBox1 = "Manu" Then Unload Me Else Application.EnableEvents = True: End
End Sub

 

[man.jul]

Bonjour

Dans le cas où je saisie la valeur CAV et que je ferme la fenêtre de saisie du mot de passe en cliquant sur la croix (sans rien saisir comme mot de passe) la valeur reste dans la saisie.
Je souhaiterais que la valeur soit effacée de la cellule si l’on ferme la fenêtre du mot de passe comme dans le cas d’une mauvaise saisie de mot de passe.
Merci bien

 

[job75]

Bonjour man.jul, le forum,

Ah oui j'avais oublié la fermeture par la croix, fichier (3) :

Private Sub CommandButton1_Click()
Unload Me
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If TextBox1 <> "Manu" Then Application.EnableEvents = True: End
End Sub

A+

 

[man.jul]

Parfait

merci bien