XL 2016 Lancement macro

[Rabeto]

Bonjour,

J'aimerai faire un macro qui se lance (faire une copie coller des données d'une feuille dont le nom est la date dans un menu déroulante)

Le nom de chaque feuille est une date, je veux que quand je choisis une date, la macro me fait une copie coller des valeurs dans la feuille dont le nom est la date.

merci

 

[sylvanu]

Bonjour Rabeto,
Le "sheets("010622").activate" peut être remplacé par :

Sheets(Replace(Replace(CStr([C1]), "/", ""), "20", "")).Select

Attention, cela suppose que la feuille existe, sinon il faut traiter le cas d'erreur.

 

[Rabeto]

merci,

Donc le code est :

Sub Copy()
Sheets(Replace(Replace(CStr([C1]), "/", ""), "20", "")).Select
Columns("A:AA").Select
Application.CutCopyMode = False
Selection.Copy
Sheets("Collage").Select
Range("G1").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Range("A1").Select
End Sub

mais ça marche pas, rien ne se passe quand je modifie la date dans C1

 

[sylvanu]

Re,
Normalement oui . Il suffit de tester.

 

[Rabeto]

Après plusieurs tentative cela ne marche pas pour la date du 02/06/2022.
Ce qui m'étonne pour les 2 autes date ça marche

 

[Deadpool_CC]

Bonjour,
si tu enleves les / en premier => 02062022
les 2 "20" seront supprimés donc c'est plus le nom de ta feuille

t'aura le même soucis pour toutes les dates tombant un 20 xxx 2022 et tous les 02 janvier à septembre

faut deu tu "calcules" plus précisement le nom de ta feuille

 

[sylvanu]

Bonsoir Rabeto, Deadpool,
Pour éviter de supprimer le 20 de 02/06/2020, il faut faire les replace à l'envers.

Sheets(Replace(Replace(CStr([C1]), "/20", "/"), "/", "")).Select

 

[soan]

il faut faire les replace à l'envers.

comme le bon Roi Dagobert, quoi...

soan

 

[Deadpool_CC]

Yes ...
Attention @Rabeto ... la formule de notre excellent @sylvanu ne fonctionne pas avec les date au format anglais donc veille à toujours avoir des format "dd/mm/aaaa"

 

[sylvanu]

donc veille à toujours avoir des format "dd/mm/aaaa"

C'est le cas de la PJ, donc pas de souci. La date est issue d'une liste déroulante.

 

[Hasco]

Bonjour,

Je vous propose cette macro qui se nomme 'Copier' parce que ce n'est pas vraiment recommandé de prendre des noms réservés par vba comme nom d'objet, de variable de procédure ou de fonction.

Sub Copier()

    Dim Nom As String
    Dim feuille As Worksheet

    Nom = Format(ThisWorkbook.Sheets("Feuil1").Range("C1"), "ddmmyy")
    
    On Error Resume Next ' Si la feuille n'existe pas la ligne suivante levera un erreur
    Set feuille = ThisWorkbook.Sheets(Nom)
    On Error GoTo 0
    
    If Not feuille Is Nothing Then
        ThisWorkbook.Sheets("Collage").Range("G1").CurrentRegion.ClearContents
        With feuille.Range("A1").CurrentRegion
            ThisWorkbook.Sheets("Collage").Range("G1").Resize(.Rows.Count, .Columns.Count).Value = .Value
        End With
        
        MsgBox "Les données de la feuille '" & Nom & "' ont été copiées dans la feuille de collage", vbInformation, "Copier données"
    Else
        MsgBox "Exécution interrompue : " & vbCrLf & _
                        "La feuille '" & Nom & "' n'existe pas dans ce classeur!", vbExclamation, "Copier données"
    End If
    
End Sub