Jours ouvrables

[JFBee]

Bonjour à tous,

J'ai élaboré un planning d'horaires pour une équipe infirmière (j'ai condensé une partie du fichier sous "tout 2004.zip"). J'essaie constamment d'améliorer celui-ci et les trucs et astuces de votre site m'y aident beaucoup. J'ai notamment découvert le fichier de gestion des plannings de Pierre WAUTIER dont je me suis déjà inspiré.

Actuellement, je me débats dans tous les sens mais sans succès pour trouver une formule qui à première vue devrait être simple !!!

Pour chaque mois, je souhaite comptabiliser le nombre de jours ouvrables en tenant compte des jours fériés légaux ou non qui sont repris sur la feuille "Matrices", de AC11 à AC25 (ne vous étonnez pas des dates, je vis en Belgique!).

En A3 de chaque feuille mensuelle, j'ai essayé plusieurs formules (à partir de NOMBRE.JOURS.OUVRES) qui fonctionnent sauf lorsque le jour férié se situe un samedi ou un dimanche (celui-ci n'est alors pas déduit... or il devrait l'être).

Grand merci d'avance à ceux qui pourront m'aider et longue vie à votre super-site.

JFBee

 

[Monique]

Bonjour,

Si les fériés tombant un samedi ou un dimance sont déduits,
il ne faut pas utiliser l'argument "jours fériés" de la fonction NB.JOURS.OUVRES

Par exemple :
le 1er du mois en E8
les jours du mois de E8 à AI8
=NB.JOURS.OUVRES(E8;FIN.MOIS(E8;0))-SOMMEPROD((E8:AI8=feries)*1)

=SOMMEPROD((E8:AI8=feries)*1)
donne le nombre de fériés du mois, qu'ils tombent ou non un dimanche.
ou bien :
=SOMMEPROD((feries>=E8)-(feries>FIN.MOIS(E8;0)))

 

[JFBee]

Bonjour Monique,

Je te remercie d'avoir si vite répondu à ma question. Ta formule marche au
top. Quelque chose me "chipote", moi qui suis débutant, pourquoi dans les
parenthèses de SOMMEPROD faut-il multiplier par 1 ? Sans ce 1, ça ne marche pas. J'ai cherché dans l'aide mais n'ai pas compris le pourquoi !!!

Encore grand merci !

Jean-François

 

[Monique]

Bonjour,

Le *1 transforme en valeur numérique le résultat E8:AI8 = feries
On peut mettre *1 ou /1 ou +0 ou -0, ça revient au même
En fait, ça transforme VRAI en 1 et FAUX en 0
Tu tapes dans une cellule =10=10 (avec les 2 signes =)
Le résultat affiché par Excel est "VRAI"
Tu tapes =(10=10)*1
Résultat = 1
=10=11 donne "FAUX"
=(10=11)*1 donne 0

Par contre, 2 ou plusieurs critères à l'intérieur de SommeProd évitent d'avoir à ajouter le *1
=(10=10)*(12=12) donne 1
Equivaut à VRAI * VRAI = 1 * 1
=(10=10)*(12=10) donne 0
Equivaut à VRAI * FAUX = 1 * 0

Dans SommeProd, le * équivaut au ET, le + équivaut au OU et le - équivaut à SAUF
=(10=10)+(12=12) donne 2

Bref, il y a un classeur "SommeProd_SumProduct II" à télécharger ici :
<http://www.excel-downloads.com/html/French/fichiers/programmation-date_maj-1.htm>
un autre dans le zip "Autres formules II" (même page)
et, tant qu'on y est, un classeur "Dates et Heures" (dont le calcul des heures de nuit)

 

[JFBee]

Merci Monique pour toutes ces précisions que je ne connaissais pas.

Encore une chose : j'ai essayé tes deux formules dans un simple fichier
que j'ai élaboré pour l'occasion et ça marchait comme je te l'ai signalé.

Par contre, quand je les ai incorporées dans mon fichier d'horaire, seule la
seconde fonctionnait. La première me renvoyait une valeur d'erreur #N/A.
Je ne comprends pas pourquoi.

Soit, la seconde fonctionne à merveille et je t'en remercie encore.

A bientôt.

PS : ça me turlupine quand même !!!

 

[Monique]

Bonjour,

J'ai fini par me décider à réouvrir ton classeur.
(garder une barre d'outils après la fermeture du classeur et même de Excel, je n'aime pas)
Si ça ne fonctionne pas dans ton classeur, c'est parce que les plages "jours du mois" et "jours fériés" sont dans le même sens.
Il faut utiliser la fonction TRANSPOSE et valider
en appuyant simultanément sur ctrl, maj et entrée.
En A5 :
=NB.JOURS.OUVRES(A1;A2)-SOMMEPROD((TRANSPOSE(A12:A42)=Jours_fériés)*1)
Une fois validé, tu auras { à gauche et } à droite de la formule, il ne faut pas les saisir.