Microsoft 365 Insérer lettre ou chiffre

[JPC33]

Bonjour. Comment insérer autant de fois X (ou autre) dans colonne A suivant valeur C1.
Ex : si C1=17 en colonne A les Cellules A1:A17 contiennent X.

 

[mapomme]

Bonsoir,

Avec O365, formule en A1 : =SUBSTITUE(SEQUENCE(C1;1;;0);1;"X")

 

[mapomme]

Re,

Si on remplace "X" par un nombre, la formule transforme ce nombre en texte .

Si on ne connait pas le type (nombre ou texte), on peut utiliser (K1 contient la valeur à afficher):

=SIERREUR(1*SUBSTITUE(SEQUENCE(C1;1;;0);1;K1);K1)

Un texte reste un texte, un nombre reste un nombre.

 

[Staple1600]

Bonsoir @mapomme


J'étais parti sur
=REPT("X";SEQUENCE(C1;1;;0))

 

[mapomme]

Bonsoir @Staple1600 ,

Ta formule est plus jolie. Mais même inconvénient que celle de ma pomme : un nombre est transformé en texte...
Continuons à chercher...

 

[Staple1600]

Re


@mapomme
Si on en croit l'air du temps, X n'est pas joli
Qu'il soit jadis un bleu cuicui ou relatif aux transports en communs (filmés en close-up)
(oui je sais elle vient de loin )

Maintenant, si on connaissait le vrai contexte, on pourrait chercher plus avant

Car si j'étais moi : je saisis mon caractère dans une jolie cellule
puis je sélectionne les cellules d'en dessous
et hop CTRL+B

 

[patricktoulon]

bonsoir
on pourrait faire l'inverse transformer une chaine en matrice
reste a maitriser les N#A
a valider en matriciel
=STXT(REPT("x";C1);LIGNE(INDIRECT("1:"&C1));1)

 

[Staple1600]

Re

[Précisions ]
A ne pas valider en matriciel pour ceux qui comme le demandeur dispose d'Office 365.

 

[patricktoulon]

purée j'ai tout essayé pour faire sauter les #N/A
bon j'ai fini par convertir les na en 0 et les substituer
c'est pas jolie mais ca match

=SUBSTITUE(SI(LIGNE()<C$1+1;STXT(REPT("x";C$1);LIGNE(INDIRECT("1:"&C$1));1););"0";"")

fonctionne en mode matriciel+entendu ou matrice de matriciel

ou mode matrice de matriciel

 

[R@chid]

Bonjour @ tous,
@mapomme

=MAKEARRAY(C1;1;LAMBDA(Ln;Cn;"X"))

On peut remplacer le "X" par une valeur numérique et elle reste numérique.

Cordialement

 

[Staple1600]

Bonjour R@chid

Encore une formule pour mon cahier à spirales.

Br@vo l'artiste

PS: Tu peux expliquer la partie LAMBDA(Ln;Cn;"X")
Dans l'aide Excel, on peut lire : Retourne un tableau calculé...en appliquant une fonction LAMBDA
Mais ici quelle est cette fonction ?
Ln L pour Ligne ?
Cn C pour Colonne ?

Parce que si j'écris : =MAKEARRAY(C1;1;LAMBDA(toto;titi;"X")), cela fonctionne aussi.

 

[mapomme]

Tu peux expliquer la partie LAMBDA(Ln;Cn;"X")

On va essayer...
La fonction (nommée LAMBDA) va être appliquée à chaque élément de la matrice créée.
Cette fonction a toujours deux paramètres : le premier est le numéro de ligne de la matrice, le second est le numéro de colonne. Le dernier paramètre est la formule qu'on applique à chaque élément de la matrice.

Exemple :

=MAKEARRAY(10;3;LAMBDA(ligne;colonne;"ligne " & ligne & " colonne " & colonne  & " de la matrice"))

Microsoft devient de plus en plus fainéant et je-m'en-foutiste avec les adaptations et traductions vers une langue autre que l'amerloque.
Il était pourtant facile de traduire makearray (par exemple CREERmatrice).
L'aide de O365 regorge de termes anglais non traduits, de formules copiées directement de l'américain (on y retrouve les virgules à la place des points-virgules). Bref Microsoft se fout de ses clients !
D'ailleurs c'est un phénomène général de traiter les modes d'emploi comme une chose inutile et coûteuse (et pas que Krosoft et pas qu'aux Amériques).

 

[Staple1600]

Bonjour @mapomme

J'avais pensé aussi utilisé MAKEARRAY mais je bloquais sur cette fonction LAMBDA
que j'interprétais comme fonction = SOMME ou NBVAL etc..

Donc je ne voyais pas quoi mettre

Tu n'es pas gentil avec Krosoft

car là, tout est est en français

Fonction MAKEARRAY - Support Microsoft

Renvoie un tableau totalisé de la ligne spécifiée et de la taille de la colonne en appliquant une fonction LAMBDA

support.microsoft.com

mais ca m'a quand même induit en erreur, car (sauf erreur), il n'y a pas de place pour le X

Syntaxe​

=MAKEARRAY(lignes, colonnes, lambda(ligne, colonne))

 

[mapomme]

car là, tout est est en français

Ah bon ?

• "makearray" c'est du français maintenant ?
• La formule suggérée contient bien des virgules à la place des points-virgules, non ?

mais ca m'a quand même induit en erreur, car (sauf erreur), il n'y a pas de place pour le X

On fait une fonction lambda qui est une constante donc indépendante des deux paramètres (mais qui sont obligatoires).

=MAKEARRAY(4; 2; LAMBDA(ligne;colonne;"x")) ou
=MAKEARRAY(4; 2; LAMBDA(lig;col;12,34)) ou
=MAKEARRAY(4; 2; LAMBDA(endive;chicon;G13))

 

[Staple1600]

Re

@mapomme
bah mon interrogation est ici
Syntaxe
=MAKEARRAY(lignes, colonnes, lambda(ligne, colonne))
Si on reprend la formule de R@chid
=MAKEARRAY(C1;1;LAMBDA(Ln;Cn;"X"))

Microsoft ne me dit pas que je peux mettre un X ou un Z

D'où le

mais ca m'a quand même induit en erreur, car (sauf erreur), il n'y a pas de place pour le X

PS: je retire que j'ai dit plus haut, il n'y a pas que du français dans l'aide en ligne !
(Je parlais de la page d'aide pas du nom de la fonction
Mais la formule ci-dessous issue la page d'aide est en anglais, d'où l'ajout de ce PS )

NB: @mapomme: Grace à nos derniers échanges et à l'exemple de Microsoft
=MAKEARRAY(D2;E2;LAMBDA(row;col;CHOISIR(ALEA.ENTRE.BORNES(1;3);"Red";"Blue";"Green")))
Je crois que je viens de comprendre le fonctionnement de LAMBDA
LAMBDA(ligne;colonne; suivi de N paramètres séparés par un ; )
C'est cela ?