XL 2013 Index decaler?

[E5kobar]

Bonjour,

J'ai plusieurs articles qui ont tous un stock différent à un instant T. Je connais mes prévisions de vente (N-1) à la semaine.

J'aimerais savoir si il est possible de déterminer jusqu'où mon stock peut m'amener (identifier le numéro de semaine) et connaitre ainsi ma deadline pour recevoir la marchandise sans créer de rupture.

L'idée et de ne pas avoir à ajouter d'autres colonnes.

Est ce possible de retranscrire le résultat sans passer par du "Si"?

Je sèche...

Merci pour votre aide

PS : attendu joint

 

[R@chid]

Bonjour
Une formule matricielle, en M4 :

=INDEX(D$3:L$3;EQUIV(VRAI;SOUS.TOTAL(9;DECALER(D4;;;;LIGNE($1:$9)))>=C4;0))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas (si besoin est)

Cordialement

 

[E5kobar]

Merciiiiiii !!!!!!!!

 

[E5kobar]

R@chid,

Voici mon problème suivant en deux points :

Je vais avoir un souci si je suis en S34 et que c'est la fin de mon tableau et que la suite continue en colonne D.

y'a t'il un moyen de faire la même chose en intégrant dans la formule (NO.semaine(aujourd'hui()) ainsi on part de la semaine actuelle.

 

[R@chid]

Re,
aujourd'hui nous sommes en semaine 45 alors ça devrait te renvoyer 47 plutôt.
Voir PJ


Cordialement

 

[E5kobar]

R@chid

Merci pour cette solution, cependant, je constate que lorsque je mets un chiffre important, le résultat s'affiche en erreur. Mais sinon c'est ça!

Merci d'avance,

 

[R@chid]

Re,

=SIERREUR(INDEX(Plg_Sem;EQUIV(VRAI;SOUS.TOTAL(9;DECALER(Plg_Calcul;;;;LIGNE($1:$21)))>=C4;0));"Tu peux mettre ce que tu veux")

@ valider toujours par Ctrl+Shift+Enter

Cordialement

 

[E5kobar]

@R@chid

Je n'arrive pas à faire fonctionner cette formule :

Dans l'idée, j'ai modifié le classeur en intégrant les semaines 1 à 52 dans l'ordre,

1Er exemple :

Nous sommes en S45 mon stock est de 70, donc de semaine 45 à 51 il y a 72 demandes => ok ça marche, ça m’indique bien rupture en S51


2eme exemple :

Nous sommes en S45 mon stock est de 80, donc de semaine 45 à 52 il y a 74 demandes donc je dois donc cumuler S45/S52 et continuer de vérifier de S1 à S(x) et ainsi afficher le numéro de semaine de la rupture "x" (ici dans cet exemple semaine 1).

Lorsque j’indique un stock à 80, voici ce que m’affiche excel : « mess box : ref circulaires »

Merci d'avance pour votre aide,

 

[R@chid]

Re,
par formule c'est un peu compliqué à recommencer depuis le début, il faut plus de formules imbriquées pour y arriver.
Je vais voir si l'on pourrait le faire

 

[R@chid]

Re,

voir PJ si cela te convient.


Cordialement

 

[E5kobar]

Trop fort @R@chid !

Merci !!!

 

[E5kobar]

@R@chid

J'aimerais si possible indiquer que si le stock couvre plus des 52 semaines (1an) ça m'indique "couvre plus d'un an de prévisions" est ce possible? (si somme previsions de semaine 1:semaine 52 ; couvre plus d'un an de prev ; la formule )

j'ai essayé avec la formule ci dessous mais ça ne passe pas :

=SI(SOMME(Tableau2[@[1]:[52]]>=[@[Stock instant T]]);"Couvre plus d'un an de prévision";SI(C4>SOMME(Plg_Calcul);INDEX(Plg_Sem2;EQUIV(VRAI;SOUS.TOTAL(9;DECALER(Plg_Calcul2;;;;LIGNE(INDIRECT("1:"&COLONNES(Plg_Sem2)))))>=C4-SOMME(Plg_Calcul);0));INDEX(Plg_Sem;EQUIV(VRAI;SOUS.TOTAL(9;DECALER(Plg_Calcul;;;;LIGNE(INDIRECT("1:"&COLONNES(Plg_Sem)))))>=C4;0))))

Merci d'avance

 

[R@chid]

Bonjour,
en BD4 :

=SI(C4>SOMME(Plg_Calcul2);"Couvre plus d'un an de prévision";SI(C4>SOMME(Plg_Calcul);INDEX(Plg_Sem2;EQUIV(VRAI;SOUS.TOTAL(9;DECALER(Plg_Calcul2;;;;LIGNE(INDIRECT("1:"&COLONNES(Plg_Sem2)))))>=C4-SOMME(Plg_Calcul);0));INDEX(Plg_Sem;EQUIV(VRAI;SOUS.TOTAL(9;DECALER(Plg_Calcul;;;;LIGNE(INDIRECT("1:"&COLONNES(Plg_Sem)))))>=C4;0))))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

Cordialement

 

[E5kobar]

@R@chid

Vous êtes un boss!

Merci!!!