Incrémenter une serie avec condition

[Mimix]

Bonjour,

Je souhaiterais créée une série incrémentée de type 10FACT001, 10FACT002 etc... dans une colonne A.
Je sais qu'en inscrivant le 10FACT001 dans la cellule A2 puis avec la poignée de recopie vers le bas, le série s'incrémente automatiquement.

Cependant, j'aimerais ajouter une condition: si la cellule à droite est vide, la cellule reste vide, sinon, poursuivre la série.
Je pensais à une formule de type:
SI(B2=""; A2=""; A2=???) et si la condition est vérifiée, prendre la cellule précédente et ajouter 1 mais le problème est que j'ai un mélange de chiffres et de caractères

 

[Tibo]

Re : Incrémenter une serie avec condition

Bonjour,

Une tentative avec ce que j'ai compris :

en A2, une formule matricielle :

=SI(B2="";"";"10FACT"&TEXTE(DROITE(INDEX($A$1:A1;MAX(($A$1:A1<>"")*
LIGNE($A$1:A1)));3)+1;"000"))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

@+

 

[Chris401]

Re : Incrémenter une serie avec condition

Bonjour

en A2 : 10FACT001

Formule en A3 :

=SI(B3="";"";GAUCHE(A2;6)&TEXTE(DROITE(A2;3)+1;"000"))

Cordialement

 

[kjin]

Re : Incrémenter une serie avec condition

bonjour, salut Tibo ,

=SI($B3<>"";"10FACT"&TEXTE(NBVAL($B$2:$B3)+1;"000");"")

Enlèves le +1 si B2 est non vide
Puis tu tires vers le bas
A+
kjin

 

[Mimix]

Re : Incrémenter une serie avec condition

Merci Tibo, Chris401 et Kjin d'avoir répondu aussi rapidement parce que je tournais en rond pour un truc tout bête!

J'ai repris la formule de Kjin qui correspondait mieux au format que je recherchais.

Bonne journée à vous

 

[hoerwind]

Re : Incrémenter une serie avec condition

Bonjour, salut les autres,

Autre façon de faire
A3 : =SI(B3="";"";GAUCHE(A$2;6)&TEXTE(NB.SI(A$2:A2;"><"&"")+1;"000"))
formule à copier vers le bas.