Imprimer plusieurs zones d'une feuille via spin button

[glm]

Bonsoir
j'ai besoin de vous. Je cherche à imprimer 2 zones non collés en même temps.
j'ai une zone "fixe" qui sera tout le temps imprimer comme des titres et une zone "modulable"
La zone "modulable" comprend 13 zones différentes et suivant un spinbutton et un textbox. Je veux
imprimer la zone correspondante.
J'ai nommé pour l'exemple 3 zones: cycle1, cycle2 et cycle3. Au final, il y aura 13 zones.
voir le fichier joint
j'espère que j'ai été clair
Merci pour votre aide
Gilles

 

[PMO2]

Re : Imprimer plusieurs zones d'une feuille via spin button

Bonjour,

Essayez de remplacer votre code par le code suivant

'###########################
'### Constante à adapter ###
Const PlageArea As String = "D1:AE46" 'à adapter (1ère plage du PrintArea)
'###########################

Private Sub SB_cycle_Change()
TB_cycle.Value = SB_cycle.Value
End Sub

Private Sub UserForm_Initialize()
TB_cycle.Enabled = False 'clic sur le champ impossible
TB_cycle.Value = 1
SB_cycle.Value = 1
SB_cycle.Min = 1
SB_cycle.Max = 13
End Sub

Private Sub Impression_Click()
Dim R As Range
'--- On décale les colonnes de la plage en fonction de SB_cycle ---
'--- A NOTER : plus besoin de Nom dans l'espace de Noms         ---
Set R = ActiveSheet.Range(PlageArea)
Set R = R.Offset(0, R.Columns.Count * (SB_cycle - 1))
'---
Unload Me
'---
With ActiveSheet
  '--- Réglage de la page à imprimer ---
  With .PageSetup
    .PrintArea = R.Address          'L'adresse de la bonne plage est transmise
    .PrintTitleColumns = "$A1:$C46" 'L'addresse des titres/colonnes à répéter
    .CenterHorizontally = True
    .CenterVertically = True
    .Orientation = xlLandscape
    .Zoom = 66
'    .PrintHeadings = False
  End With
  '---
  .PrintPreview
  .PageSetup.PrintArea = False
End With
End Sub

 

[glm]

Re : Imprimer plusieurs zones d'une feuille via spin button

Bonsoir
désolé pour ma réponse tardive
je viens de tester et cela fonctionne à merveille
Je suis toujours autant impressionner
Merci beaucoup