Imbriquer plus de 7 fct Si dans Excel 2003

[jl456]

Bonjour,

Vous trouverez en PJ mon exemple.
Le but est le suivant:
Je recherche dans une plage de données la valeur la plus proche de 225 (en plus ou en moins).
Une fois la valeur trouvée, je souhaite pouvoir afficher dans la colonne d'à coté la concéténation de 3 cellules de la meme colonne que la valeur trouvée.

Or j'ai 8 colonnes pour le moment, peut etre plus par la suite donc je ne peux pas utiliser la fct SI.

Avez-vous une idée?

Merci d'avance pour votre aide.

 

[mercant76]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

bonjour,

ci dessous une astuce de HBENALIA : concaténer les SI :

=CONCATENER(SI(E5=1;B1;"");SI(E5=2;B2;"");SI(E5=3;B3;"");SI(E5=4;B4;"");SI(E5=5;B5;"");SI(E5=6;B6;"");SI(E5=7;B7;"");SI(E5=8;B8;"");SI(E5=9;B9;"");SI(E5=10;B10;"");SI(E5=11;B11;"");SI(E5=12;B12;"");SI(E5=13;B13;"");SI(E5=14;B13;"");SI(E5=15;B15;"")).

à adapter à ton besoin.

@+

 

[spidernono]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

Bonjour,

Pour information, dés que ça dépasse plusieurs conditions, j'utilise la fonction choisir, qui me paraît plus souple...

Après question de choix ^^

 

[Tibo]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

reBonjour jl,

Un essai avec une formule matricielle en D4 :

=INDEX(F4:M4;EQUIV(MIN(ABS(F4:M4-$D$3));ABS(F4:M4-$D$3);0))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas

@+

 

[jl456]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

reBonjour Tibo,

Merci bcq, cette formule remplace bien celle que j'ai utilisé en colonne D.
Maintenant comment puis-je concaténer en colonne E les informations en ligne 1,2,3 de la colonne de la valeur trouvée ?
D'ailleurs, si c'est possible de ne faire qu'une seule formule et non deux ça serait encore mieux.

Merci d'avance.

 

[JCGL]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

Bonjour à tous,

Tibo : puis-je me permettre ?

En E4 et vers le bas :

=INDEX($F$3:$M$3;EQUIV(D4;F4:M4;))

Cellule au format :

"Ref Longeur"Standard

A++
A+ à tous

 

[jl456]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

reBonjour à tous,

Merci JCGL pour ton aide.
Par contre cela ne marche pas tout à fait car si en ligne 1 "ref" est fixe
En ligne 2, il peut y avoir soit "longueur" soit "largeur" selon la colonne.
Idem en ligne 3, cela change selon la colonne.

Merci d'avance pour votre aide.

 

[Tibo]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

re,

Aucun souci, mon cher Jean-Claude, tes interventions sont toujours les bienvenues.

Je n'avais tout simplement pas fait attention au fait qu'il y avait des formules également en colonne E.

Disons que je n'avais pas lu complètement le message initial ...

Bonne soirée à tous

@+

 

[JCGL]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

Bonjour à tous,

Merci Tibo de ta grande mansuétude

Peux-tu essayer en E4 et vers le bas :

=INDEX($F$2:$M$2;EQUIV(D4;F4:M4;))&" "&INDEX($F$3:$M$3;EQUIV(D4;F4:M4;))

Sans le format personnalisé

A++
A+ à tous

 

[jl456]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

re,

Merci beaucoup Jean-Claude, ta formule marche parfaitement !
C'est très gentil à vous tous de m'avoir aidé!

Y a t-il moyen de rassembler ensemble les formules des colonnes D et E ? Ça c'est juste pour faire joli et consommer moins de colonne.

A+
JL

 

[JCGL]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

Bonjour à tous,

Pas trouver mieux qu'un :

=TEXTE(E4;"0.00")&" soit  "&F4

en D4 et vers le bas et les colonnes E et F masquées...

Le "patron" des formules étant sur la discussion, tu devrais avoir une réponse sans colonnes masquées...

A+ à tous

 

[Tibo]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

re,

C'est effectivement gérable sans colonne supplémentaire, mais ça donne simplement une formule matricielle un peu longue et surtout moins lisible :

=INDEX(G4:N4;EQUIV(MIN(ABS(G4:N4-$E$3));ABS(G4:N4-$E$3);0))&" soit "&INDEX(
$G$2:$N$2;EQUIV(INDEX(G4:N4;EQUIV(MIN(ABS(G4:N4-$E$3));ABS(G4:N4-$E$3);0));
G4:N4;))&" "&INDEX($G$3:$N$3;EQUIV(INDEX(G4:N4;EQUIV(MIN(ABS(G4:N4-$E$3));
ABS(G4:N4-$E$3);0));G4:N4;))

Matricielle, donc CTRL + MAJ + ENTREE

Attention aux matricielles, sur des fichiers de grande taille, ça peut provoquer un certain temps de recalcul, voire un temps certain...

@+

 

[jl456]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

re

Merci Tibo c'est exactement ce qu'il me fallait !!!

Je vous remercie tous les deux pour votre aide et vous souhaite une bonne fin de soirée.

@+
JL

 

[ROGER2327]

Re : Imbriquer plus de 7 fct Si dans Excel 2003

Bonsoir à tous

À essayer :

[COLOR="DarkSlateGray"][B]=INDEX($F$1:$M$1&$F$2:$M$2&$F$3:$M$3;1;EQUIV(D4;$F4:$M4;0)*COLONNE($A$1:$I$1))[/B][/COLOR]

en E4. (À valider matriciellement.)​

ROGER2327
#3461

22 Floréal An CCXVIII
2010-W19-2T20:39:31Z