Imbrication SI ET OU

[Claude72]

Bonjour à tous,

Je suis en train de créer une appli Excel 2000 (Tennis Roland GARROS).
J'ai du mal à trouver la bonne formule de SI, ET, OU.
J'ai 5 colonnes C,D,E,F,G pour les scores et une colonne H où l'on met "A" en cas d'abandon.
Si un score est > à l'autre, mais s'il y a abandon en cours de set, c'est le score < qui est qualifié...
Voir classeur Excel 2000 joint.
Merci par avance
Claude

 

[13GIBE59]

Re : Imbrication SI ET OU

Bonjour Claude.

je pense que la formule que tu cherches en I2 est celle-Ci :

=SI(ET(SOMME(C2:G2)>SOMME(C3:G3);H2="");SI(H2="A";B3;B2);"").

Cela dit, n'y a-t'il pas une erreur dans ton calcul ?
Tu écris : Si la somme de C2:G2 est > à la somme de C3:G3, alors il y a victoire.
Mais dans un score 6/0, 6/7, 6/7, 6/7 le premier joueur perd en marquant 24 jeux, alors que le second gagnne en marquant 21 jeux !
Le calcul est valable si le match se déroule en trois set gagnants : 6/0 , 6/7 , 6/7. Le gagnant marque 14 jeux, alors que le perdant en empoche 18...
Ou y a-t'il quelque chose qui m'échappe ?

 

[hoerwind]

Re : Imbrication SI ET OU

Bonjour, salut 13GIBE59,

Je m'étais fait la même réflexion !

Formule à essayer en I2 :

=SI(H2="A";B3;SI(H3="A";B2;SI(ET(SOMMEPROD((C2:G2>C3:G3)*1)<3;SOMMEPROD((C3:G3>C2:G2)*1)<3);"";SI(SOMMEPROD((C2:G2>C3:G3)*1)=3;B$2;B$3))))

 

[13GIBE59]

Re : Imbrication SI ET OU

Bonjour Hoerwind,

Sauf erreur de ma part, j'ai essayé ta jolie formule (j'y comprends d'ailleurs rien !!!) en I2, mais elle ne marche pas avec un score 6/3, 6/7, 6/7, qui indique comme vainqueur Nadal...

 

[mat7775]

Re : Imbrication SI ET OU

Salut tous,

Dans la mesure où on rentre de toute manière manuellement l'abandon dans la colonne H, c'est pas plus simple de rentrer dans la même colonne un code V pour le vainqueur au lieu de se triturer les méninges?

Enfin moi, je dis ça, je dis rien...

Mat

 

[hoerwind]

Re : Imbrication SI ET OU

Re,

C'est normal (et voulu !) qu'avec un score de 6/3, 6/7, 6/7 la formule proposée renvoie "" (cellule vide), puisque, pour avoir un vainqueur, il faut trois sets gagnants, et il n'y en a que deux, ou qu'un des deux joueurs ait abandonné (A en colonne H)

J'ai aussi pris la liberté de corriger ce qui me semble être une petite erreur dans l'énoncé des contraintes :
S'il y a abandon en cours de set, c'est le score < qui est qualifié
qui devrait être :
S'il y a abandon (tout court, non seulement en cours de set, mais aussi entre deux sets !) c'est le joueur n'ayant pas abandonné qui est qualifié, quelque soit le score.
Fais quelques tests et dis-nous si tu es convaincu, après je me ferai un plaisir de te décortiquer la formule.

 

[13GIBE59]

Re : Imbrication SI ET OU

C'est normal (et voulu !) qu'avec un score de 6/3, 6/7, 6/7 la formule proposée renvoie "" (cellule vide), puisque, pour avoir un vainqueur, il faut trois sets gagnants, et il n'y en a que deux, ou qu'un des deux joueurs ait abandonné (A en colonne H)

Damned ! Mais tu as raison ! Encore un truc sexiste pour hommes, les matches en 5 sets gagnants...Et pour les filles, on fait comment ?

Et qu'en pense notre ami Claude, au fait ?

 

[13GIBE59]

Re : Imbrication SI ET OU

Fais quelques tests et dis-nous si tu es convaincu, après je me ferai un plaisir de te décortiquer la formule.

Au fait, j'ai compris ta formule, même si je serais incapable de la reproduire...

Mais je ne m'explique toujours pas pourquoi =SOMMEPROD((C2:G2>C3:G3)*1) marche, alors que =SOMMEPROD((C2:G2>C3:G3)) renvoie 0...

Ca, je veux bien que tu m'expliques...

 

[hoerwind]

Re : Imbrication SI ET OU

Re,

Je n'ai pas essayé, mais normalement en modifiant dans la formule les 3 par des 2 cela devrait fonctionner.

Toujours à ta disposition pour une explication de la formule.

 

[hoerwind]

Re : Imbrication SI ET OU

Re,

C2:G2>C3:G3 renvoie VRAI ou FAUX, pour en faire la somme il faut rendre ce résultat numérique, ce qui est possible en le multipliant par 1.

 

[13GIBE59]

Re : Imbrication SI ET OU

C2:G2>C3:G3 renvoie VRAI ou FAUX, pour en faire la somme il faut rendre ce résultat numérique, ce qui est possible en le multipliant par 1.

Vu l'impact, merci beaucoup. Cela dit, chez moi, C2:G2>C3:G3 ou = C2:G2>C3:G3 me renvoie #VALEUR !

Mais je ne cherche plus à comprendre...

 

[hoerwind]

Re : Imbrication SI ET OU

Re,

SOMMEPROD est une matricielle
C'est comme si tu écris :
=(C2>C3)+(D2>D3)+(E2>E3)+(F2>F3)+(G2>G3)
ici ce sont les "+" qui transforment les VRAI en 1
ou :
=SOMME(C2>C3;D2>D3;E2>E3;F2>F3;G2>G3)

Tu peux également écrire :
=SOMMEPROD((C2:G2>C3:G3)+0)
ou :
=SOMMEPROD(--(C2:G2>C3:G3))
ou :
=SOMMEPROD((C2:G2>C3:G3)-0)
ou :
=SOMMEPROD((C2:G2>C3:G3)/1)

 

[13GIBE59]

Re : Imbrication SI ET OU

Merci beaucoup ! J'ai tout compris !
Non, je blague, je vais relire l'aide de SOMMEPROD...

A plus.

 

[hoerwind]

Re : Imbrication SI ET OU

Re,

Une formule un peu plus courte :

=SI(OU(H3="A";SOMMEPROD((C2:G2>C3:G3)*1)=3);B2;SI(OU(H2="A";SOMMEPROD((C3:G3>C2:G2)*1)=3);B3;""))

 

[Claude72]

Re : Imbrication SI ET OU

Merci hoerwind,

Ta formule est quasi parfaite. Juste une petite amélioration...
Ta formule est :
=SI(H2="A";B3;SI(H3="A";B2;SI(ET(SOMMEPROD((C2:G2>C3:G3)*1)<3;SOMMEPROD((C3:G3>C2:G2)*1)<3);"";SI(SOMMEPROD((C2:G2>C3:G3)*1)=3;B$2;B$3))))

Mais il faudrait =SI(H2="A";"") ....
En effet, si NADAL abandonne, la cellule I2 doit être à blanc. C'est la cellule I3 qui doit contenir ISNER (et/ou l'inverse).
En fait, le nom du vainqueur doit toujours être sur la même ligne (progression linéaire dans le tournoi).

Merci par avance hoerwind
Claude