Help sur graphique - manque pas grand chose

[BAT]

Bonjour à tous,
Grosse demande sur un graphique à réaliser. C'est exactement celui qui se trouve en Pice jointe sauf que je n'arrive pas à faire apparaître le nom de la "série" sur les points du graphique.
Je dois probablement mal m'y prendre.
J'ai mis un exemple de ce qui est attendu. Je pense que nous sommes pas loin mais bon !!!
Merci par avance pour votre aide précieuse.

 

[job75]

Re : Help sur graphique - manque pas grand chose

Bonjour BAT,

Je pense que nous sommes pas loin mais bon !!!

Si, on en est loin, car il faut du VBA...

La macro doit passer en revue chaque point de chacune des 2 séries :

1) créer son étiquette de donnée (DataLabel en VBA) et y mettre le texte correspondant du tableau

2) colorer le point Edit : a priori pas nécessaire, il l'est déjà, c'est la couleur de la série.

Cherchez sur le forum, il y a pas mal d'exemples de ce genre.

Perso, pas le temps de m'en occuper, désolé.

A+

 

[job75]

Re : Help sur graphique - manque pas grand chose

Re,

Bon j'ai pris quand même 5 minutes...

Voyez ces 2 macros dans le fichier joint :

Sub AfficherEtiquettes()
Dim s As Series, i As Integer
With ActiveSheet.ChartObjects(1).Chart
  .ApplyDataLabels Type:=xlDataLabelsShowValue
  For Each s In .SeriesCollection
    For i = 1 To s.Points.Count
      s.Points(i).DataLabel.Text = [A1].Offset(i)
    Next
  Next
End With
End Sub

Sub MasquerEtiquettes()
ActiveSheet.ChartObjects(1).Chart.ApplyDataLabels _
  Type:=xlDataLabelsShowNone
End Sub

A+

 

[job75]

Re : Help sur graphique - manque pas grand chose

Re,

Une amélioration avec un seul bouton et cette macro dans le code de la feuille :

Private Sub CommandButton1_Click()
With CommandButton1
  If .Caption Like "Afficher*" Then
    AfficherEtiquettes
    .Caption = "Masquer Etiquettes"
  Else
    MasquerEtiquettes
    .Caption = "Afficher Etiquettes"
  End If
End With
End Sub

A+

 

[BAT]

Re : Help sur graphique - manque pas grand chose

Génial,
Un très grand merci à toi d'avoir pris le temps.
j'aurais vraiment pensé pouvoir faire un graphique sans VBA ! En même temps ça me rassure !
encore merci et bon dimanche à toi

 

[CB60]

Re : Help sur graphique - manque pas grand chose

Bonjour
Job j'ai bien aimé ta macro, je me permet un petit changement qui peut etre interessant pour le choix des infos à afficher.

Sub AfficherEtiquettes()
Dim s As Series, i As Integer
Dim choix As Range
With ActiveSheet.ChartObjects(1).Chart
.ApplyDataLabels Type:=xlDataLabelsShowValue
For Each s In .SeriesCollection
Set choix = Application.InputBox(prompt:=" Sélectionner la premiere étiquette ", Type:=8)
For i = 1 To s.Points.Count
s.Points(i).DataLabel.Text = [choix].Offset(i - 1)
Next
Next
End With
End Sub

Je me la mets en réserve!!!

 

[job75]

Re : Help sur graphique - manque pas grand chose

Bonjour Bruno, le fil, le forum,

Oui, on peut paramétrer ce que l'on veut, par exemple ici le n° de série.

Bonne journée.

A+

 

[CB60]

Re : Help sur graphique - manque pas grand chose

Bonjour à tous
Merci Job, je la mets en réserve aussi.