Hauteur ligne dans macro

[VINCEGR]

Bonjour le forum,

j'utilise une macro qui fonctionne correctement dont voici ci-dessous le détail :

Option Explicit



Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Dim zoneFournisseurs As Range, nomFourn() As String, iFourn As Long, searchC As Range, memAdr As String, iL As Long

'ne pas traiter les onglets GENERAL et Liste
If Sh.Name = "GENERAL" Or Sh.Name = "Listes" Or Sh.Name = "modele" Or Sh.Name = "logo" Then Exit Sub

'récupérer le nom de l'onglet composé de noms de fournisseurs (1 ou plusieurs
' séparés par un tiret "-") dans un tableau
nomFourn = Split(Sh.Name, "-")

On Error Resume Next

Sh.Unprotect
'effacer les données
Sh.Range("2:" & Sh.Rows.Count).Clear
iL = 1

'récupérer la "zone fournisseur" de l'onglet général (colonne e)
With ThisWorkbook.Sheets("GENERAL")
Set zoneFournisseurs = .Range("e1", .Range("e" & .Rows.Count).End(xlUp))
End With

'boucler sur chaque fournisseur (nom de l'onglet)
For iFourn = LBound(nomFourn) To UBound(nomFourn)
'rechercher dans la zoneFournisseurs
Set searchC = zoneFournisseurs.Find(nomFourn(iFourn), , xlValues, xlWhole)
'si une cellule est trouvée
If Not searchC Is Nothing Then
memAdr = searchC.Address
Do
iL = iL + 1
searchC.EntireRow.Copy Sh.Range("A" & iL)
Set searchC = zoneFournisseurs.FindNext(searchC)
Loop Until memAdr = searchC.Address
End If
Next iFourn

'trier les données par date
Sh.Range("A2:y" & iL).Sort Sh.Range("A2"), xlAscending

'ajouter la ligne "total"
If iL > 1 Then
Sh.Range("A" & iL + 1) = "Total"
Sh.Range("C" & iL + 1) = iL - 1
Sh.Range("F" & iL + 1) = iL - 1
Sh.Range("x" & iL + 1) = WorksheetFunction.Sum(Sh.Range("x2:x" & iL))
Sh.Range("w" & iL + 1) = WorksheetFunction.Sum(Sh.Range("w2:w" & iL))
Sh.Range("y" & iL + 1) = WorksheetFunction.Sum(Sh.Range("y2:y" & iL))

With Sh.Range("A" & iL + 1 & ":y" & iL + 1)
.Font.Bold = True
.Borders(xlEdgeLeft).LineStyle = xlContinuous
.Borders(xlEdgeTop).LineStyle = xlContinuous
.Borders(xlEdgeBottom).LineStyle = xlContinuous
.Borders(xlEdgeRight).LineStyle = xlContinuous
.Borders(xlInsideVertical).LineStyle = xlContinuous
.Interior.Color = RGB(1, 200, 255)
End With
Sh.Range("x" & iL + 1).NumberFormat = "_($* #,##0.00_);_($* (#,##0.00);_($* ""-""??_);_(@_)"
Sh.Range("y" & iL + 1).NumberFormat = "_($* #,##0.00_);_($* (#,##0.00);_($* ""-""??_);_(@_)"
Sh.Range("w" & iL + 1).NumberFormat = "_($* #,##0.00_);_($* (#,##0.00);_($* ""-""??_);_(@_)"
End If
Sh.Protect , , , , , , True, True, , , , , , True, True
End Sub

la seule chose qui m'ennuie c'est la hauteur de ligne que je modifie lors d'une création de feuille et qui ne reste pas bloquée lorsque je reviens dessus.

Comment modifier la macro pour avoir une hauteur de ligne à 35 dans les feuilles créées.

merci pour votre aide
@+

 

[Pierrot93]

Re : Hauteur ligne dans macro

Bonjour,

essaye cette ligne de code, s'appliquera à la feuille active :

    Cells.RowHeight = 35

bonne journée
@+

 

[VINCEGR]

Re : Hauteur ligne dans macro

Bonjour Pierrot93,

merci c'est parfait

a bientot