Formule =NB.SI.ENS avec conditions ET et OU

[loulouange]

Bonjour,

Cela fait un moment que je cherche la formule qui me permettre de compter les lignes selon deux conditions mais pas mohyen.

Jusqu'ici j'ai pu mettre les formule avec plus conditions "ET", mais je n'arrive pas à introduire le "OU" , je me permets de ovus la mettre ci dessous afin que vous puissiez me dire mon erreur.


=NB.SI.ENS(ET('BASE DE SAISIES'!$F$8:$F$52;"H");NB.SI.ENS(OU('BASE DE SAISIES'!$U$8:$U$52;"Terminé";'BASE DE SAISIES'!$U$8:$U$52;"Non terminé"))


Je vous remercie pour votre aide.

 

[GIBI]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour,

Si avec Nb.si tu ne peux pas faire ce que tu veux, utilise plutôt sommeprod qui est plus lisible

si j'ai compris ce que tu veux faire
si colonne F = "h" alors
si colonne u = "Terminé" ou colonne u alors
je le compte
fin si
finsi

=SOMMEPROD(('BASE DE SAISIES'!$F$8:$F$52 ="H")*(('BASE DE SAISIES'!$U$8:$U$52="Terminé")+('BASE DE SAISIES'!$U$8:$U$52="Non terminé"))*1)


sinon tu peux écrire

=NB.SI.ENS('BASE DE SAISIES'!$F$8:$F$52;"H";'BASE DE SAISIES'!$U$8:$U$52;"Terminé") +
NB.SI.ENS('BASE DE SAISIES'!$F$8:$F$52;"H";'BASE DE SAISIES'!$U$8:$U$52;"Non terminé"))


GIBI

 

[loulouange]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Merci GIBI ! ça fonctionne impec !! Je pensais qu'il fallait utiliser le OU, c'est bon à savoir.

Je regardes tes formules précieusement.

Bonne journée.

 

[chris]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour à tous

On peut aussi utiliser "*terminé" qui compte Terminé et non terminé s'il n'y a pas de cas comme "presque terminé"...

 

[loulouange]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour,

Chris, j'ai essayé avec ta méthode mais je dois mal la reproduire car ça ne marche pas, voici ce que j'ai mis :

=NB.SI.ENS('BASE DE SAISIES'!$F$8:$F$52;"H";'BASE DE SAISIES'!$AJ$7:$AJ$51;"*terminé")

PS : la colonne n'est plus U mais AJ

 

[chris]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour

La syntaxe est bonne mais y a t'il bien un accent sur les mots terminé dans la colonne AJ ?

 

[loulouange]

Re : Formule =NB.SI.ENS avec conditions ET et OU

oui il y a bien l'accent pour les deux.

en tout cas merci pour ton intervention.

 

[chris]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour

Tes plages ne sont pas parallèles : F8:F52 et AJ7:AJ51 ce qui peut fausser le résultat.

Sinon précise ce qui ne marche pas : erreur, calcul faux...

 

[loulouange]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonsoir Chris,

Je viens de vérifier et j'ai remis tout en parallèle et là ça fonctionne, autant pour moi désolée pour l'erreur.

C'est une astuce à connaitre encore merci

 

[loulouange]

Re : Formule =NB.SI.ENS avec conditions ET et OU

bonjour,

je suis désolée de vous solliciter à nouveau mais je n'arrive pas à trouver une formule plus complexe, je ne comprends pas bien l'histoire des parenthèses, s'il y en a trop ou pas assez.

Je voudrais sélectionner les personnes selon :

- le sexe
- faisant partie de la catégorie 'Actifs non indépendants (salariés)'
- dans la tranche d'age '25 à 44 ans'
- qui englobe les personnes qui sont 'En cours' et celles dont le bilan est 'terminé' ou 'non terminé".


=SOMMEPROD(('BASE DE SAISIES'!$G$7:$G$51 ;"H")+('BASE DE SAISIES'!$I$7:$I$51; "Actifs non indépendants (salariés)")+('BASE DE SAISIES'!$H$7:$H$51 ;"25 à 44 ans")*(( 'BASE DE SAISIES'!$D$7:$D$51; "*terminé")+('BASE DE SAISIES'!$D$7:$D$51="En cours"))*1)

merci infiniment pour votre aide.

 

[chris]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour

Dans SOMMEPROD le + correspond à OU, donc des alternatives.

Si je comprends bien ta question, il faut mettre * à la place des + ou utiliser NB.SI.ENS

 

[Monique]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour à vous deux,

Et mettre = à la place de ;

Un essai :

=SOMMEPROD(('Base de saisies'!$G$7:$G$51="H")*('Base de saisies'!$I$7:$I$51="Actifs non indépendants (salariés)")*('Base de saisies'!$H$7:$H$51="25 à 44 ans")*(( 'Base de saisies'!$D$7:$D$51="terminé")+('Base de saisies'!$D$7:$D$51="En cours")))

 

[GIBI]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour,

le Et logique correspond à * (si faux = 0 si vrai = 1 ==> dés qu'il y a une condition fausse il n'y a pas de comptage)

Le ou logique peut être remplacé par une fonction + (si la valeur est soit l'une soit l'autre)

GIBI

=SOMMEPROD(('BASE DE SAISIES'!$G$7:$G$51 ="H")*('BASE DE SAISIES'!$I$7:$I$51= "Actifs non indépendants (salariés)")*('BASE DE SAISIES'!$H$7:$H$51 ="25 à 44 ans")*(( 'BASE DE SAISIES'!$D$7:$D$51= "*terminé")+('BASE DE SAISIES'!$D$7:$D$51="En cours"))*1)

 

[loulouange]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonsoir,

Merci d'avoir pris le temps de vous pencher sur mon problème.

Chris : ok je comprends mieux l'histoire des + et * c'est beaucoup plus clair à présent.

GIBI : J'ai essayé ta formule mais j'ai un message d'erreur, je te mets la capture d'écran, là je ne vois pas d'ou cela peut venir ?

Monique : J'ai essayé la tienne et j'ai eu un bon début !! j'ai remarqué que là tu mettais des = au lieu des ;

pour en revenir à ta formule, le résultat ne correspondant pas au nombre réel, j'ai fait des tests et au départ j'avais vu que tu n'avais pas mis * devant "terminé" donc je l'ai rajouté mais cela n'a rien fait.

alors j'ai remis les deux conditions "bilan terminé" et "bilan non terminé" et là miracle ça fonctionne !!!

je vous mets la formule ci dessous :

mais j'ai un message d'erreur, je te mets la capture d'écran, là je ne vois pas d'ou cela peut venir ?

=SOMMEPROD(('BASE DE SAISIES'!$G$7:$G$51="H")*('BASE DE SAISIES'!$I$7:$I$51="Actifs non indépendants (salariés)")*('BASE DE SAISIES'!$H$7:$H$51="25 à 44 ans")*(( 'BASE DE SAISIES'!$D$7:$D$51="Bilan terminé")+( 'BASE DE SAISIES'!$D$7:$D$51="Bilan non terminé")+('BASE DE SAISIES'!$D$7:$D$51="En cours")))

Je suis vraiment contente d'avoir enfin trouvé et cela grâce à vous, mille merci encore !!

 

[Monique]

Re : Formule =NB.SI.ENS avec conditions ET et OU

Bonjour,

Pas d'erreur en copiant ta formule à partir du forum
A partir de ton image, on ne peut pas faire grand chose

Dans le fichier joint, tu as la formule de ton message et une autre en prime