Formule compliquée (impossible ?) pour lier deux tableaux ...

[F22Raptor]

Hello,
Difficile d'expliquer dans le titre mon problème !
Le fichier joint sera plus parlant.

En gros :
Sept commerciaux peuvent être en déplacement dans une liste de pays
Chacun d'entre eux est rattaché à une équipe (il y a 3 équipes) - cf. O29

Je remplis ce tableau avec un formulaire : 7 cases à cocher à chaque nouveau voyage, pour chacun des commerciaux.
Et par un petit code, à la validation du formulaire, il vérifie à quelle équipe un commercial coché appartient, et il coche automatiquement son équipe (colonnes J à L)
Ca marche TRES BIEN !!!

MAIS …
Régulièrement, on fait une erreur, on oublie par exemple qu'Arthur était présent en Espagne le 5/4
On corrige donc en cochant à la main Arthur en C7 … mais comme les colonnes TEAM sont masquées, on ne coche pas son équipe TEAM3 en L7
Du coup, les stats qui tournent par ailleurs (nombre d'occurrences par équipe) sont fausses

CONCLUSION :
Je voudrais éviter une édition par une boîte macro, qui repropose la saisie, et refait les coches par TEAM.
Pour cela, il faudrait que les coches J3:L8 soient faites par une formule se basant sur la liste des commerciaux et équipes (O29).
J'ai tous les éléments, mais je ne suis pas certain que ça puisse se faire par une formule (qui réagisse donc automatiquement en fonction des coches
en C3:I8) … Qu'en pensez-vous ?

 

[Caillou]

Re : Formule compliquée (impossible ?) pour lier deux tableaux ...

Bonjour,

Essayes cette formule en J3 (à recopier jusqu'en L8)

=SI(SOMMEPROD(($C3:$I3="X")*1;(TRANSPOSE($O$3:$O$9)=$C$2:$I$2)*1;(TRANSPOSE($P$3:$P$9)=J$2)*1);"X";"")

Formule matricielle : Valider par Shift + Ctrl + Entrée
il y a peut-être plus simple, j'y suis arrivé en tâtonnant !

Caillou

 

[Modeste]

Re : Formule compliquée (impossible ?) pour lier deux tableaux ...

Bonjour F22Raptor, Caillou,

Un "poil plus court", mais en formule matricielle aussi:

=SI(SOMME(($C3:$I3="X")*($C$2:$I$2=$O$3:$O$9)*($P$3:$P$9=J$2))=0;"";"X")

... Donc valider à l'aide de Ctrl+Shift+Enter également (prudence sur les gros volumes!)

[Edit:] salut mon bon Jocelyn ... trois propositions ... c'est de la gourmandise!

 

[Jocelyn]

Re : Formule compliquée (impossible ?) pour lier deux tableaux ...

Bonjour le Forum,
Bonjour F22Raptor, Caillou,

Une autre solution avec cette formule à la base pas besoin de validation matricielle

=SOMMEPROD(($C3:$I3="x")*(ESTNUM(EQUIV($C$2:$I$2&J$2;$O$3:$O$9&$P$3:$P$9;0)))*1)

dans le fichier joint cette formule est le 2 ème tableau et donne le nombre de personne dans chaque team étant cochée dans le tableau C:I

ensuite en modifiant la formule de cette façon

=REPT("x";SOMMEPROD(($C3:$I3="x")*(ESTNUM(EQUIV($C$2:$I$2&J$2;$O$3:$O$9&$P$3:$P$9;0)))*1))

dans le fichier joint cette formule est le 1 er tableau et donne autant de X par team que de personne cochée

ou alors voir dans le tableau 3

=SI(SOMMEPROD(($C3:$I3="x")*(ESTNUM(EQUIV($C$2:$I$2&J$2;$O$3:$O$9&$P$3:$P$9;0)))*1);"x";"")

Qui met un X si au moins 1 personne est cochée sur la team

Voila regardes et dis nous

Cordialement

EDIT : Oup's Bonjour l'ami modeste , désolé pour la collision mais bien content de te croiser

 

[F22Raptor]

Re : Formule compliquée (impossible ?) pour lier deux tableaux ...

Bo, je vais vous le dire clairement, les mecs, vous m'impressionnez !
Je touche à peu près correctement ma bille sur Excel, en formule et en VBA, mais produire des choses aussi efficaces avec des formules aussi courtes, je dis bravo.

En un mot comme en cent, JE VOUS AIME !