Formule avec des SI

[panda]

Bonjour à vous tous
Je joins mon fichier pour que ce soit plus simple à expliquer.

En fait je pensais que la limite d'excel est de 7 SI imbriqués. Or, dans mon fichier joint la formule d'un collègue (certes imbuvable ... la formule pas le collègue) fonctionne :

=SI(C7="janvier";B3)+SI(C7="Fevrier";B3+C3)+SI(C7="Mars";+C3+D3)+SI(C7="avril";B3+C3+D3+E3)+SI(C7="mai";B3+C3+D3+E3+F3)+SI(C7="juin";B3+C3+D3+E3+F3+G3)+SI(C7="juillet";B3+C3+D3+E3+F3+G3+H3)+SI(C7="aout";B3+C3+D3+E3+F3+G3+H3+I3)+SI(C7="Sept.";B3+C3+D3+E3+F3+G3+H3+I3+J3)+SI(C7="OCT.";B3+C3+D3+E3+F3+G3+H3+I3+J3+K3)+SI(C7="nov.";B3+C3+D3+E3+F3+G3+H3+I3+J3+K3+L3)+SI(C7="déc.";B3+C3+D3+E3+F3+G3+H3+I3+J3+K3+L3+M3)

1/ Donc je me demande pourquoi ?
2/ Ne pourrait-on pas la simplifier ?

Merci pour votre aide toujours efficace

 

[Tibo]

Re : Formule avec des SI

Bonjour,

Un essai avec cette formule :

=SOMME((DECALER($B$3;0;0;;EQUIV(C7;$B$2:$M$2;0))))

Nécessite impérativement que les mois soient orthographiés de la même façon que sur la ligne 2

Je te laisse tester

@+

 

[Habitude]

Re : Formule avec des SI

=SOMME(CHOISIR(EQUIV(C7;B2:M2;0);B3;B3:C3;B33;B3:E3;B3:F3;B3:G3;B3:H3;B3:I3;B3:J3;B3:K3;B3:L3;B3:M3))

Choisir permet de choisir les zone à additionner.

Ou

=SOMME(DECALER(B3;0;0;1;EQUIV(C7;B2:M2;0)))

Decaler permet le cumulatif.


Tibo à raison. Par contre tu peux faire une liste de validation avec la ligne 2 en référence.

 

[hoerwind]

Re : Formule avec des SI

Bonjour,

La formule fonctionne parce que les SI ne sont pas imbriqués, mais additionnés.

Une proposition de simplification :

=SOMME(DECALER(A3;;;;EQUIV(C7;A2:M2;0)))

 

[panda]

Re : Formule avec des SI

Bonjour,

La formule fonctionne parce que les SI ne sont pas imbriqués, mais additionnés.

Une proposition de simplification :

=SOMME(DECALER(A3;;;;EQUIV(C7;A2:M2;0)))

Bravo ! Oui cela marche parfaitement
Quelle rapidité
Par contre je ne sais pas du tout comment expliquer tout ça ...

Merci encore!

 

[hoerwind]

Re : Formule avec des SI

Re,

La fonction DECALER permet définir une plage
DECALER(réf;lignes;colonnes;hauteur;largeur)

On décale à partir de A3 (réf); de 0 lignes (vide); de 0 colonnes (vide), d'une hauteur nulle (vide) et d'une largeur équivalente à la position de C7 dans A2:M2, le 0 final spécifie que la valeur trouvée doit être identique à la valeur cherchée.
De cette plage on fait le somme.

J'espère avoir été clair.

 

[panda]

Re : Formule avec des SI

Merci bcp pour vos explications très claires me semble-t-il.

Je vous souhaite à tous une excellente journée et à bientôt

Re,

La fonction DECALER permet définir une plage
DECALER(réf;lignes;colonnes;hauteur;largeur)

On décale à partir de A3 (réf); de 0 lignes (vide); de 0 colonnes (vide), d'une hauteur nulle (vide) et d'une largeur équivalente à la position de C7 dans A2:M2, le 0 final spécifie que la valeur trouvée doit être identique à la valeur cherchée.
De cette plage on fait le somme.

J'espère avoir été clair.