Fonction pour calculer la somme des cellules avec zéros, entre des 1

[jeuno]

Bonjour à tous,

Je fais un petit logiciel excel et j'aimerai avoir de l'aide (je m'en sort pas !!)

Je voudrai calculer (si faisabilité) des cellules avec des zéros, entre des 1. (voir exemple en copie)

Ca a l'air bizare mais c'est pour faire des stat.

En finalité je ferai des calculs pour savoir tous les combiens de cellules il sort un "1"

Merci à tous
Jeuno

 

[Victor21]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonjour, jeuno.

En attendant mieux :

 

[phlaurent55]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonjour jeuno,

une solution par macro

il est possible de le faire par formule ................. et par un autre que moi

à+
Philippe

 

[jeuno]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Merci, Merci,

Je regarde ça, je vais essayer de l'adapter ... c'est déja trés sympa.

Bonne soirée

Jeuno

 

[Tibo]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonsoir à tous,

Un essai avec une formule matricielle.

en D13 :

=SI(LIGNES($1:1)>=NB.SI($B$2:$B$41;1);NB($B$2:$B$41)-MAX(SI($B$2:$B$41=1;($B$2:$B$41=1)*LIGNE($B$2:$B$41)))+1;PETITE.VALEUR(SI($B$2:$B$41=1;($B$2:$B$41=1)*LIGNE($B$2:$B$41));LIGNES($1:2))-PETITE.VALEUR(SI($B$2:$B$41=1;($B$2:$B$41=1)*LIGNE($B$2:$B$41));LIGNES($1:1))-1)

Formule matricielle à valider par CTRL + MAJ + ENTREE

A recopier vers le bas.

Fonctionne avec l'exemple donné.

A vérifier sur d'autres cas.

@+

 

[mapomme]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonsoir jeunot,

Un essai par formule matricielle. Saisir la formule dans une cellule (validez par Ctrl+Maj+Entrée) puis recopier vers le bas jusqu'à obtenir des cellules vides.

Formule matricielle pour Excel 2007 et 2010:

=SIERREUR(INDEX(FREQUENCE(SI($B$2:$B$41=0;LIGNE($B$2:$B$41));SI($B$2:$B$41=1;LIGNE($B$2:$B$41)));LIGNE()-1);"")

Formule matricielle pour Excel 2003, 2007 et 2010:

=SI(ESTERREUR(INDEX(FREQUENCE(SI($B$2:$B$41=0;LIGNE($B$2:$B$41));SI($B$2:$B$41=1;LIGNE($B$2:$B$41)));LIGNE()-1));"";INDEX(FREQUENCE(SI($B$2:$B$41=0;LIGNE($B$2:$B$41));SI($B$2:$B$41=1;LIGNE($B$2:$B$41)));LIGNE()-1))

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

NB: la première valeur du résultat sur l'exemple est 0 puisque la première cellule de données est égale à 1 et qu'il n'y a pas deux 1 consécutifs.
Si on remplace la première valeur de données par un 0, alors la première cellule de résultat donne 8 qui est bien le nombre de 0 de la première séquence.

 

[david84]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonsoir à tous,
ci-joint deux solutions par formule.
A+

 

[mapomme]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonjour à tous,

Si on veut tenir compte des 4 possibilités de départ pour les cellules de données (0 puis 0; 0 puis 1; 1 puis 0; 1 puis 1) on peut modifier la formule matricielle:

Excel >= 2007 (matricielle) :

=SI(ET(LIGNE()=2;B2=1);"";SIERREUR(INDEX(FREQUENCE(SI($B$2:$B$41=0;LIGNE($B$2:$B$41));SI($B$2:$B$41=1;LIGNE($B$2:$B$41)));LIGNE()-1);""))

Excel >= 2003 (matricielle) :

=SI(ET(LIGNE()=2;B2=1);"";SI(ESTERREUR(INDEX(FREQUENCE(SI($B$2:$B$41=0;LIGNE($B$2:$B$41));SI($B$2:$B$41=1;LIGNE($B$2:$B$41)));LIGNE()-1));"";INDEX(FREQUENCE(SI($B$2:$B$41=0;LIGNE($B$2:$B$41));SI($B$2:$B$41=1;LIGNE($B$2:$B$41)));LIGNE()-1)))

 

[R@chid]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Bonjour @ tous,
Une autre très très petite,
selectionner une palge comme F12:F23, coller la formule,

=FREQUENCE(SI(B2:B41=0;LIGNE(B2:B41));SI(B2:B41=1;LIGNE(B2:B41)))

et valider par Ctrl+Maj+Entree

Voir PJ

Amicalement

 

[jeuno]

Re : Fonction pour calculer la somme des cellules avec zéros, entre des 1

Merci à tous pour votre aide !

A++++++++++++++
Jeuno