fonction à 3 conditions

[laurent7459]

bonjour à tous,
dans une formule de calcul je souhaite introduire 3 voir 4 conditions
j'ai utilisé : =si(cellulex<=36;"a";"b") j'obtiens donc 2 résultats possible: a ou b
mais moi je souhaite obtenir 3 voir 4 résultats:
le 1er: si cellule x <=36 alors a
le 2nd: 37<cellule x<=72 alors b
le 3eme: 73<cellule x<=108 alors c
le 4eme: si cellule x> 108 alors d
est ce qu'il existe une fonction qui me permettrais d'obtenir ce résultats
d'avance je vous remercie

laurent7459

 

[Brigitte]

Re : fonction à 3 conditions

Bonsoir,

Comme ceci :

=SI(A2>108;"d";SI(A2>72;"c";SI(A2>36;"b";"a")))

Bonne soirée.

Edition :

Je mets aussi dans le fichier joint la formule de Porcinet82 en plus de la mienne/celle d'excel-lent, comme ca, Laurent, tu as le choix...

 

[Excel-lent]

Re : fonction à 3 conditions

Slt laurent7459,

En partant du principe que ta "cellulex" soit A1

=si(A1>108;"d";si(A1>=72;"c";si(A1>=36;"b";"a")))

Bon courage

 

[porcinet82]

Re : fonction à 3 conditions

Salut Laurent, Brigitte,

Moi je dirais dans l'autre sens :
=SI(B6<37;"a";SI(B6<73;"b";SI(B6<109;"c";"d")))

@+

PS : Je l'avais faite donc, tant pis Brigitte, je post quand meme

 

[Excel-lent]

Re : fonction à 3 conditions

Quelle similitude!!!

Et tout cela sans se consulter

 

[Brigitte]

Re : fonction à 3 conditions

Que fais tu des ondes xldiennes, excel-lent... ?

En tout cas, nous deux, c kif kif...

Bon j'ai mis un fichier, ca aidera peut être Laurent à voir que ca marche.

 

[porcinet82]

Re : fonction à 3 conditions

Arff, salut Excel-lent, le temps que je mette ma reponse et que je rafraichisse, et tu avais posté entre temps. Heureusement que je n'ai pas eu la meme idée que vous...

@+

PS : Quelle gentillesse cette Brigitte...

 

[Samantha]

Re : fonction à 3 conditions

Bonjour Le Forum, Les Gens, Laurent,

Bien sûr on peut imbriquer jusqu'à 8 fonctions conditionneles je crois donc y'a la marge pour ton soucis :

Essayes donc, partant du principe que ta cellule x soit A2 et que tu te trouves en B2 :

Tu peux même, si par la suite tes bases de comparaison étaient amenées à changer les coller en A1, B1, C1, ainsi pas besoin de modifier la formule surtout si tu est amené à la recopier ...

Partons donc de ce principe :
en A1 : 37
en B1 : 73
en C1 : 109

et en B2 ta formule qui compare ta valeur en A2 :

=+SI(A2="";"";SI(A2<A$1;"a";SI(A2<B$1;"b";SI(A2<C$1;"c";"d"))))

les $ servent à "fixer" la cellule à comparer en ligne 1 lors de la recopie vers le bas. Si tu veux recopier vers la droite il faut aussi mettre des $ devant la lettre afin de "fixer" la colonne.

Les guillemets permettent de donner comme résultat du texte. Sinon tu mets ta formule sans les guillemets. Quand il n'y a rien entre les guillemets ("") cela signifie que la cellule est vide.

Et voila dis nous si ça te vas

A te lire


Sam

 

[Samantha]

Re : fonction à 3 conditions

Ben le temps que je raconte mon laïus mdr x:

Enfin je me rassure comme je peux j'ai une option à laquelle vous n'avez pas songé nananèreu

Amitiés à tous.


Sam

 

[Charly2]

Re : fonction à 3 conditions

Bonjour Laurent, bonjour Brigitte, bonjour Excel-lent, bonjour Romain, bonjour Samantha,
bonjour à toutes et à tous

Tu peux également essayer cette formule qui permet de ne pas être limité par le nombre de SI :

=CAR((A1>36)+(A1>72)+(A1>108)+97)

A+

 

[Monique]

Re : fonction à 3 conditions

Bonjour,

Et aussi :

=INDEX({"a";"b";"c";"d"};EQUIV(A1;{0;36;72;108}))

=RECHERCHEV(A1;{0."a";36."b";72."c";108."d"};2)

=RECHERCHEH(A1;{0.36.72.108;"a"."b"."c"."d"};2)

Edit

J’ai raconté n’importe quoi…

=INDEX({"a";"b";"c";"d"};EQUIV(A1;{0;36,01;72,01;108,01}))

=RECHERCHEV(A1;{0."a";36,01."b";72,01."c";108,01."d"};2)

=RECHERCHEH(A1;{0.36,01.72,01.108,01;"a"."b"."c"."d"};2)

 

[andré]

Re : fonction à 3 conditions

Bonjour les ami(e)s,

Vous avez quand même l'art de compliquer les choses !

=CAR(MIN(3;ENT(A1/36))+97)

C'est tellement évident (lol).

Â+

 

[Brigitte]

Re : fonction à 3 conditions

Bonsoir,

Si Samantha, ton truc est très bien, mais j'y avais pensé. Seulement devant la demande de Laurent portant sur des "si" tout simples, me suis dit qu'il fallait faire le plus simple possible...

Je crois aussi qu'on ne peut imbriquer que 7 "SI" et pas 8 à moins que ca ait augmenté, avec la version excel 2003, pas vérifié.

Je trouve important de pas compliquer trop quand on connait pas trop le niveau du demandeur.

Mais bon, c ma philosophie... Les usines à gaz, j'aime pas ca pour moi, alors je n'en fais pas (et ne sais pas en faire) pour les autres...

Mais je ne dis pas que ton truc est une usine à gaz, ce n'est pas le cas, simplement, ca me parait compliquer les choses...

 

[Charly2]

Re : fonction à 3 conditions

re, bonsoir à Monique et Ândré,

Bonjour les ami(e)s,

Vous avez quand même l'art de compliquer les choses !

=CAR(MIN(3;ENT(A1/36))+97)

C'est tellement évident (lol).

J'avais pensé à quelquechose comme ça, mais il faut que tu modifies un peu ta formule :

=CAR(MIN(3;ENT((A1-1)/36))+97)

Voili voilou

A+

 

[Samantha]

Re : fonction à 3 conditions

Re à tous et toutes,

ABrigitte : oui je conçois que je suis parfois compliquée mais j'essaye d'être le plus complète possible (dans la mesure de mes compétences limitées) ne sachant pas dans quelle globalité s'intègre la question j'essaye d'imaginer et de simplifier les utilisations ultérieures du produit fini...

A André et à Charly : je ne connaissais pas cette fonction CAR mais je note . Cependant ce 97 il corresponds à quoi ??

Merci d'avance.


Sam